Dogcows Code - chaz/tar/blob - configure.ac

   1 # Configure template for GNU tar.  -*- autoconf -*-
   2
   3 # Copyright (C) 1991, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 # 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free
   5 # Software Foundation, Inc.
   6
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3, or (at your option)
  10 # any later version.
  11
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20 # 02110-1301, USA.
  21
  22 AC_INIT([GNU tar], [1.26.90], [bug-tar@gnu.org])
  23 AC_CONFIG_SRCDIR([src/tar.c])
  24 AC_CONFIG_AUX_DIR([build-aux])
  25 AC_CONFIG_HEADERS([config.h])
  26 AC_PREREQ([2.63])
  27 AM_INIT_AUTOMAKE([1.11 gnits tar-ustar dist-bzip2 dist-xz dist-shar std-options silent-rules])
  28
  29 # Enable silent rules by default:
  30 AM_SILENT_RULES([yes])
  31
  32 AC_PROG_CC
  33 AC_EXEEXT
  34 AC_PROG_RANLIB
  35 AC_PROG_YACC
  36 gl_EARLY
  37
  38 AC_SYS_LARGEFILE
  39 AC_ISC_POSIX
  40 AC_C_INLINE
  41
  42 AC_CHECK_HEADERS_ONCE(fcntl.h linux/fd.h memory.h net/errno.h \
  43   sgtty.h string.h \
  44   sys/param.h sys/device.h sys/gentape.h \
  45   sys/inet.h sys/io/trioctl.h \
  46   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  47   unistd.h locale.h)
  48
  49 AC_CHECK_HEADERS([sys/buf.h], [], [],
  50 [#if HAVE_SYS_PARAM_H
  51 #include <sys/param.h>
  52 #endif])
  53
  54 AC_HEADER_SYS_WAIT
  55
  56 AC_HEADER_DIRENT
  57 AC_HEADER_MAJOR
  58 AC_HEADER_STAT
  59 AC_HEADER_STDC
  60
  61 AC_MSG_CHECKING([for st_fstype string in struct stat])
  62 AC_CACHE_VAL(diff_cv_st_fstype_string,
  63   [AC_TRY_COMPILE([#include <sys/types.h>
  64 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  65    diff_cv_st_fstype_string=yes,
  66    diff_cv_st_fstype_string=no)])
  67 AC_MSG_RESULT($diff_cv_st_fstype_string)
  68 if test $diff_cv_st_fstype_string = yes; then
  69   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  70     [Define if struct stat has a char st_fstype[] member.])
  71 fi
  72
  73 # even if we use gnulib's acl.h with integrated m4 file later on (used because
  74 # of very useful file_has_acl() function) we need following checks that restrict
  75 # tar to use POSIX.1e ACLs only.
  76 AC_ARG_WITH([posix-acls],
  77     AS_HELP_STRING([--without-posix-acls],
  78                    [do not use POSIX.1e access control lists]),
  79     [with_posix_acls=no])
  80 if test "x$with_posix_acls" != "xno"; then
  81   AC_CHECK_HEADERS(sys/acl.h,, [with_posix_acls=no])
  82   for tar_acl_func in acl_get_file acl_get_fd acl_set_file acl_set_fd \
  83                       acl_to_text acl_from_text; do \
  84     test "x$with_posix_acls" = xno && break
  85     AC_SEARCH_LIBS([$tar_acl_func], [acl pacl], [], [with_posix_acls=no])
  86   done
  87   if test "x$with_posix_acls" != xno; then
  88     AC_DEFINE(HAVE_POSIX_ACLS,,[Define when we have working POSIX acls])
  89   fi
  90 else
  91   # disable acls in gnulib's checks
  92   export enable_acl=no
  93 fi
  94
  95 AC_TYPE_SIGNAL
  96 AC_TYPE_MODE_T
  97 AC_TYPE_PID_T
  98 AC_TYPE_OFF_T
  99 AC_TYPE_SIZE_T
 100 AC_TYPE_UID_T
 101 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
 102                                    [Type of major device numbers.]))
 103 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
 104                                    [Type of minor device numbers.]))
 105 AC_CHECK_TYPE(dev_t, unsigned)
 106 AC_CHECK_TYPE(ino_t, unsigned)
 107
 108 gt_TYPE_SSIZE_T
 109
 110 # gnulib modules
 111 gl_INIT
 112 # paxutils modules
 113 tar_PAXUTILS
 114
 115 AC_ARG_ENABLE([gcc-warnings],
 116   [AS_HELP_STRING([--enable-gcc-warnings],
 117      [turn on many GCC warnings (for developers; best with GNU make)])],
 118   [case $enableval in
 119      yes|no) ;;
 120      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 121    esac
 122    gl_gcc_warnings=$enableval],
 123   [if test -d "$srcdir"/.git; then
 124      gl_gcc_warnings=yes
 125    else
 126      gl_gcc_warnings=no
 127    fi]
 128 )
 129
 130 if test "$gl_gcc_warnings" = yes; then
 131   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 132   AC_SUBST([WERROR_CFLAGS])
 133
 134   nw=
 135   # This, $nw, is the list of warnings we disable.
 136   nw="$nw -Wformat-nonliteral"      # warnings in Fedora 17 stdio.h
 137   nw="$nw -Wvla"                    # warnings in gettext.h
 138   nw="$nw -Wswitch-default"         # Too many warnings for now
 139   nw="$nw -Wunsafe-loop-optimizations" # It's OK to omit unsafe optimizations.
 140   nw="$nw -Winline"                 # It's OK to not inline.
 141   nw="$nw -Wstrict-overflow"        # It's OK to optimize strictly.
 142   nw="$nw -Wsuggest-attribute=pure" # Too many warnings for now.
 143
 144   gl_MANYWARN_ALL_GCC([ws])
 145   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 146   for w in $ws; do
 147     gl_WARN_ADD([$w])
 148   done
 149   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 150   gl_WARN_ADD([-Wno-type-limits])      # It's OK to optimize based on types.
 151   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 152   gl_WARN_ADD([-Wno-format-nonliteral])
 153
 154   gl_WARN_ADD([-fdiagnostics-show-option])
 155   gl_WARN_ADD([-funit-at-a-time])
 156
 157   AC_SUBST([WARN_CFLAGS])
 158
 159   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 160   AH_VERBATIM([FORTIFY_SOURCE],
 161   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 162       without upsetting glibc 2.15+. */
 163    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 164    # define _FORTIFY_SOURCE 2
 165    #endif
 166   ])
 167   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 168
 169   # Use a slightly smaller set of warning options for lib/.
 170   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 171   nw=
 172   nw="$nw -Wmissing-prototypes"
 173   nw="$nw -Wunused-macros"
 174   #
 175   # These are for argp.
 176   nw="$nw -Wmissing-field-initializers"
 177   nw="$nw -Wshadow"
 178   #
 179   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 180
 181   # This is also for argp.
 182   gl_WARN_ADD([-Wno-missing-field-initializers], [GNULIB_WARN_CFLAGS])
 183
 184   AC_SUBST([GNULIB_WARN_CFLAGS])
 185
 186   # For gnulib-tests, the set is slightly smaller still.
 187   nw=
 188   # It's not worth being this picky about test programs.
 189   nw="$nw -Wsuggest-attribute=const"
 190   gl_MANYWARN_COMPLEMENT([GNULIB_TEST_WARN_CFLAGS],
 191                          [$GNULIB_WARN_CFLAGS], [$nw])
 192   AC_SUBST([GNULIB_TEST_WARN_CFLAGS])
 193 fi
 194
 195 TAR_HEADERS_ATTR_XATTR_H
 196
 197 AC_CHECK_FUNCS_ONCE([fchmod fchown fsync lstat mkfifo readlink symlink])
 198
 199 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 200 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 201 AC_CHECK_DECLS([time],,, [#include <time.h>])
 202
 203 AC_REPLACE_FUNCS(waitpid)
 204
 205 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 206   [if test -n "$RSH"; then
 207     tar_cv_path_RSH=$RSH
 208   else
 209     tar_cv_path_RSH=no
 210     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 211         /usr/bin/nsh /usr/bin/rcmd
 212     do
 213       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 214       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 215       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 216       if test -f $ac_file; then
 217         if (test -h $ac_file) 2>/dev/null; then
 218           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 219         else
 220           tar_cv_path_RSH=$ac_file
 221           break
 222         fi
 223       fi
 224     done
 225   fi])
 226 if test $tar_cv_path_RSH = no; then
 227   AC_CHECK_HEADERS(netdb.h)
 228 else
 229   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 230     [Define to the full path of your rsh, if any.])
 231 fi
 232
 233 TAR_COMPR_PROGRAM(compress)
 234 TAR_COMPR_PROGRAM(gzip)
 235 TAR_COMPR_PROGRAM(bzip2)
 236 TAR_COMPR_PROGRAM(lzip)
 237 TAR_COMPR_PROGRAM(lzma)
 238 TAR_COMPR_PROGRAM(lzop)
 239 TAR_COMPR_PROGRAM(xz)
 240
 241 AC_MSG_CHECKING(for default archive format)
 242
 243 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 244            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 245
 246 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 247   DEFAULT_ARCHIVE_FORMAT="GNU"
 248 fi
 249 case $DEFAULT_ARCHIVE_FORMAT in
 250   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 251   *) AC_MSG_ERROR(Invalid format name);;
 252 esac
 253 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 254   [By default produce archives of this format])
 255 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 256
 257 AC_MSG_CHECKING(for default archive)
 258
 259 AC_ARG_VAR([DEFAULT_ARCHIVE],
 260            [Set the name of the default archive (default: -)])
 261 if test -z "$DEFAULT_ARCHIVE"; then
 262   DEFAULT_ARCHIVE=-
 263 else
 264   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 265     AC_MSG_WARN(DEFAULT_ARCHIVE '$DEFAULT_ARCHIVE' not found on this system)
 266   fi
 267   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 268   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 269   # FIXME: Rearrange, here.
 270   case $DEFAULT_ARCHIVE in
 271     *[[0-7][lmh]])
 272       AC_DEFINE(DENSITY_LETTER, 1,
 273         [Define to 1 if density may be indicated by [lmh] at end of device.])
 274       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 275       ;;
 276     *[[0-7]])
 277       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 278       ;;
 279     *)
 280       device_prefix=
 281       ;;
 282   esac
 283   case "$device_prefix" in
 284     ?*)
 285       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 286         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 287       ;;
 288   esac
 289 fi
 290 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 291   [Define to a string giving the full name of the default archive file.])
 292 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 293
 294 AC_ARG_VAR([DEFAULT_BLOCKING],
 295            [Define default blocking factor (default: 20)])
 296 AC_MSG_CHECKING(for default blocking)
 297 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 298 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 299   [Define to a number giving the default blocking size for archives.])
 300 AC_MSG_RESULT($DEFAULT_BLOCKING)
 301
 302 AC_MSG_CHECKING(for default quoting style)
 303
 304 m4_define([QUOTING_STYLES],dnl
 305           [literal|shell|shell-always|c|escape|locale|clocale])
 306 DEFAULT_QUOTING_STYLE="escape"
 307 AC_ARG_VAR([DEFAULT_QUOTING_STYLE],
 308            [Set the default quoting style. Allowed values are: ] m4_bpatsubst(QUOTING_STYLES,[|], [[, ]]) [. Default is "escape".])
 309
 310 case $DEFAULT_QUOTING_STYLE in
 311 QUOTING_STYLES) ;;
 312 *)  AC_MSG_ERROR(Invalid quoting style);;
 313 esac
 314 AC_MSG_RESULT($DEFAULT_QUOTING_STYLE)
 315 DEFAULT_QUOTING_STYLE=`echo ${DEFAULT_QUOTING_STYLE}|sed 's/-/_/g'`_quoting_style
 316 AC_DEFINE_UNQUOTED(DEFAULT_QUOTING_STYLE, $DEFAULT_QUOTING_STYLE,
 317   [Define to a default quoting style (see lib/quoteargs.c for the list)])
 318
 319 # Iconv
 320 AM_ICONV
 321 AC_CHECK_HEADERS(iconv.h)
 322 AC_CHECK_TYPE(iconv_t,:,
 323               AC_DEFINE(iconv_t, int,
 324                         [Conversion descriptor type]),
 325               [
 326 #ifdef HAVE_ICONV_H
 327 # include <iconv.h>
 328 #endif
 329 ])
 330
 331 # Gettext.
 332 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 333 AM_GNU_GETTEXT_VERSION([0.16])
 334
 335 # Initialize the test suite.
 336 AC_CONFIG_TESTDIR(tests)
 337 AC_CONFIG_FILES([tests/Makefile tests/atlocal]) # FIXME: tests/preset?
 338 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 339
 340 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 341 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 342 AC_ARG_ENABLE(backup-scripts,
 343               AC_HELP_STRING([--enable-backup-scripts],
 344                              [Create and install backup and restore scripts]),
 345               [case $enableval in
 346                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 347                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 348                     ;;
 349                esac])
 350
 351 AC_SUBST(BACKUP_SED_COND)
 352 if date +%Y-%m-%d 2>/dev/null >&2; then
 353         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 354 else
 355         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 356 fi
 357
 358 AC_OUTPUT([Makefile\
 359            doc/Makefile\
 360            gnu/Makefile\
 361            lib/Makefile\
 362            po/Makefile.in\
 363            scripts/Makefile\
 364            rmt/Makefile\
 365            src/Makefile])