Dogcows Code - chaz/tar/blob - configure.ac

   1 # Configure template for GNU tar.
   2
   3 # Copyright (C) 1991, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 # 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  19 # 02110-1301, USA.
  20
  21 AC_INIT([GNU tar], [1.15.91], [bug-tar@gnu.org])
  22 AC_CONFIG_SRCDIR([src/tar.c])
  23 AC_CONFIG_AUX_DIR([build-aux])
  24 AC_CONFIG_HEADERS([config.h:config.hin])
  25 AC_PREREQ([2.59])
  26 AM_INIT_AUTOMAKE([1.8 gnits dist-bzip2 dist-shar std-options])
  27
  28 gl_USE_SYSTEM_EXTENSIONS
  29 AC_PROG_CC
  30 AC_EXEEXT
  31 AC_PROG_RANLIB
  32 AC_PROG_YACC
  33 AC_SYS_LARGEFILE
  34 AC_ISC_POSIX
  35 AC_C_INLINE
  36
  37 AC_CHECK_HEADERS_ONCE(fcntl.h linux/fd.h memory.h net/errno.h \
  38   sgtty.h string.h stropts.h \
  39   sys/param.h sys/device.h sys/filio.h sys/gentape.h \
  40   sys/inet.h sys/io/trioctl.h \
  41   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  42   unistd.h locale.h)
  43
  44 AC_CHECK_HEADERS([sys/buf.h], [], [],
  45 [#if HAVE_SYS_PARAM_H
  46 #include <sys/param.h>
  47 #endif])
  48
  49 AC_HEADER_SYS_WAIT
  50 AM_STDBOOL_H
  51
  52 AC_HEADER_DIRENT
  53 AC_HEADER_MAJOR
  54 AC_HEADER_STAT
  55 AC_HEADER_STDC
  56
  57 AC_MSG_CHECKING([for st_fstype string in struct stat])
  58 AC_CACHE_VAL(diff_cv_st_fstype_string,
  59   [AC_TRY_COMPILE([#include <sys/types.h>
  60 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  61    diff_cv_st_fstype_string=yes,
  62    diff_cv_st_fstype_string=no)])
  63 AC_MSG_RESULT($diff_cv_st_fstype_string)
  64 if test $diff_cv_st_fstype_string = yes; then
  65   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  66     [Define if struct stat has a char st_fstype[] member.])
  67 fi
  68
  69 AC_TYPE_SIGNAL
  70 AC_TYPE_MODE_T
  71 AC_TYPE_PID_T
  72 AC_TYPE_OFF_T
  73 AC_TYPE_SIZE_T
  74 AC_TYPE_UID_T
  75 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  76                                    [Type of major device numbers.]))
  77 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  78                                    [Type of minor device numbers.]))
  79 AC_CHECK_TYPE(dev_t, unsigned)
  80 AC_CHECK_TYPE(ino_t, unsigned)
  81
  82 gt_TYPE_SSIZE_T
  83 gl_AC_TYPE_INTMAX_T
  84 jm_AC_TYPE_UINTMAX_T
  85
  86 # gnulib modules
  87 tar_GNULIB
  88 # paxutils modules
  89 tar_PAXUTILS
  90
  91 AC_CHECK_FUNCS(fsync lstat mkfifo readlink strerror symlink setlocale utimes)
  92 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
  93 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
  94 AC_CHECK_DECLS([time],,, [#include <time.h>])
  95
  96 AC_REPLACE_FUNCS(waitpid)
  97
  98 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
  99   [if test -n "$RSH"; then
 100     tar_cv_path_RSH=$RSH
 101   else
 102     tar_cv_path_RSH=no
 103     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 104         /usr/bin/nsh /usr/bin/rcmd
 105     do
 106       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 107       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 108       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 109       if test -f $ac_file; then
 110         if (test -h $ac_file) 2>/dev/null; then
 111           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 112         else
 113           tar_cv_path_RSH=$ac_file
 114           break
 115         fi
 116       fi
 117     done
 118   fi])
 119 if test $tar_cv_path_RSH = no; then
 120   AC_CHECK_HEADERS(netdb.h)
 121 else
 122   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 123     [Define to the full path of your rsh, if any.])
 124 fi
 125
 126 AC_MSG_CHECKING(for default archive format)
 127
 128 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 129            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 130
 131 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 132   DEFAULT_ARCHIVE_FORMAT="GNU"
 133 fi
 134 case $DEFAULT_ARCHIVE_FORMAT in
 135   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 136   *) AC_MSG_ERROR(Invalid format name);;
 137 esac
 138 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 139   [By default produce archives of this format])
 140 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 141
 142 AC_MSG_CHECKING(for default archive)
 143
 144 AC_ARG_VAR([DEFAULT_ARCHIVE],
 145            [Set the name of the default archive (default: -)])
 146 if test -z "$DEFAULT_ARCHIVE"; then
 147   DEFAULT_ARCHIVE=-
 148 else
 149   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 150     AC_MSG_WARN(DEFAULT_ARCHIVE \`$DEFAULT_ARCHIVE' not found on this system)
 151   fi
 152   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 153   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 154   # FIXME: Rearrange, here.
 155   case $DEFAULT_ARCHIVE in
 156     *[[0-7][lmh]])
 157       AC_DEFINE(DENSITY_LETTER, 1,
 158         [Define to 1 if density may be indicated by [lmh] at end of device.])
 159       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 160       ;;
 161     *[[0-7]])
 162       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 163       ;;
 164     *)
 165       device_prefix=
 166       ;;
 167   esac
 168   case "$device_prefix" in
 169     ?*)
 170       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 171         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 172       ;;
 173   esac
 174 fi
 175 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 176   [Define to a string giving the full name of the default archive file.])
 177 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 178
 179 AC_ARG_VAR([DEFAULT_BLOCKING],
 180            [Define default blocking factor (default: 20)])
 181 AC_MSG_CHECKING(for default blocking)
 182 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 183 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 184   [Define to a number giving the default blocking size for archives.])
 185 AC_MSG_RESULT($DEFAULT_BLOCKING)
 186
 187 AC_MSG_CHECKING(for default quoting style)
 188
 189 m4_define([QUOTING_STYLES],dnl
 190           [literal|shell|shell-always|c|escape|locale|clocale])
 191 DEFAULT_QUOTING_STYLE="escape"
 192 AC_ARG_VAR([DEFAULT_QUOTING_STYLE],
 193            [Set the default quoting style. Allowed values are: ] m4_bpatsubst(QUOTING_STYLES,[|], [[, ]]) [. Default is "escape".])
 194
 195 case $DEFAULT_QUOTING_STYLE in
 196 QUOTING_STYLES) ;;
 197 *)  AC_MSG_ERROR(Invalid quoting style);;
 198 esac
 199 AC_MSG_RESULT($DEFAULT_QUOTING_STYLE)
 200 DEFAULT_QUOTING_STYLE=`echo ${DEFAULT_QUOTING_STYLE}|sed 's/-/_/g'`_quoting_style
 201 AC_DEFINE_UNQUOTED(DEFAULT_QUOTING_STYLE, $DEFAULT_QUOTING_STYLE,
 202   [Define to a default quoting style (see lib/quoteargs.c for the list)])
 203
 204 # Iconv
 205 AM_ICONV
 206 AC_CHECK_HEADERS(iconv.h)
 207 AC_CHECK_TYPE(iconv_t,:,
 208               AC_DEFINE(iconv_t, int,
 209                         [Conversion descriptor type]),
 210               [
 211 #ifdef HAVE_ICONV_H
 212 # include <iconv.h>
 213 #endif
 214 ])
 215
 216 # Gettext.
 217 AM_GNU_GETTEXT([external], [need-ngettext])
 218 AM_GNU_GETTEXT_VERSION(0.12.1)
 219
 220 # Initialize the test suite.
 221 AC_CONFIG_TESTDIR(tests)
 222 AC_CONFIG_FILES([tests/Makefile tests/atlocal]) # FIXME: tests/preset?
 223 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 224
 225 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 226 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 227 AC_ARG_ENABLE(backup-scripts,
 228               AC_HELP_STRING([--enable-backup-scripts],
 229                              [Create and install backup and restore scripts]),
 230               [case $enableval in
 231                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 232                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 233                     ;;
 234                esac])
 235
 236 AC_SUBST(BACKUP_SED_COND)
 237 if date +%Y-%m-%d 2>/dev/null >&2; then
 238         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 239 else
 240         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 241 fi
 242
 243
 244 AC_OUTPUT([Makefile\
 245            doc/Makefile\
 246            lib/Makefile\
 247            po/Makefile.in\
 248            scripts/Makefile\
 249            rmt/Makefile\
 250            src/Makefile])