Dogcows Code - chaz/tar/blob - configure.ac

   1 # Configure template for GNU tar.  -*- autoconf -*-
   2
   3 # Copyright (C) 1991, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 # 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  19 # 02110-1301, USA.
  20
  21 AC_INIT([GNU tar], [1.22.90], [bug-tar@gnu.org])
  22 AC_CONFIG_SRCDIR([src/tar.c])
  23 AC_CONFIG_AUX_DIR([build-aux])
  24 AC_CONFIG_HEADERS([config.h])
  25 AC_PREREQ([2.60])
  26 AM_INIT_AUTOMAKE([1.9 gnits tar-ustar dist-bzip2 dist-shar std-options])
  27
  28 AC_PROG_CC
  29 AC_EXEEXT
  30 AC_PROG_RANLIB
  31 AC_PROG_YACC
  32 gl_EARLY
  33
  34 AC_SYS_LARGEFILE
  35 AC_ISC_POSIX
  36 AC_C_INLINE
  37
  38 AC_CHECK_HEADERS_ONCE(fcntl.h linux/fd.h memory.h net/errno.h \
  39   sgtty.h string.h stropts.h \
  40   sys/param.h sys/device.h sys/filio.h sys/gentape.h \
  41   sys/inet.h sys/io/trioctl.h \
  42   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  43   unistd.h locale.h)
  44
  45 AC_CHECK_HEADERS([sys/buf.h], [], [],
  46 [#if HAVE_SYS_PARAM_H
  47 #include <sys/param.h>
  48 #endif])
  49
  50 AC_HEADER_SYS_WAIT
  51
  52 AC_HEADER_DIRENT
  53 AC_HEADER_MAJOR
  54 AC_HEADER_STAT
  55 AC_HEADER_STDC
  56
  57 AC_MSG_CHECKING([for st_fstype string in struct stat])
  58 AC_CACHE_VAL(diff_cv_st_fstype_string,
  59   [AC_TRY_COMPILE([#include <sys/types.h>
  60 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  61    diff_cv_st_fstype_string=yes,
  62    diff_cv_st_fstype_string=no)])
  63 AC_MSG_RESULT($diff_cv_st_fstype_string)
  64 if test $diff_cv_st_fstype_string = yes; then
  65   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  66     [Define if struct stat has a char st_fstype[] member.])
  67 fi
  68
  69 AC_TYPE_SIGNAL
  70 AC_TYPE_MODE_T
  71 AC_TYPE_PID_T
  72 AC_TYPE_OFF_T
  73 AC_TYPE_SIZE_T
  74 AC_TYPE_UID_T
  75 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  76                                    [Type of major device numbers.]))
  77 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  78                                    [Type of minor device numbers.]))
  79 AC_CHECK_TYPE(dev_t, unsigned)
  80 AC_CHECK_TYPE(ino_t, unsigned)
  81
  82 gt_TYPE_SSIZE_T
  83
  84 # gnulib modules
  85 gl_INIT
  86 # paxutils modules
  87 tar_PAXUTILS
  88
  89 AC_CHECK_FUNCS(fsync getdtablesize lstat mkfifo readlink symlink setlocale utimes)
  90 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
  91 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
  92 AC_CHECK_DECLS([time],,, [#include <time.h>])
  93
  94 AC_REPLACE_FUNCS(waitpid)
  95
  96 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
  97   [if test -n "$RSH"; then
  98     tar_cv_path_RSH=$RSH
  99   else
 100     tar_cv_path_RSH=no
 101     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 102         /usr/bin/nsh /usr/bin/rcmd
 103     do
 104       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 105       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 106       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 107       if test -f $ac_file; then
 108         if (test -h $ac_file) 2>/dev/null; then
 109           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 110         else
 111           tar_cv_path_RSH=$ac_file
 112           break
 113         fi
 114       fi
 115     done
 116   fi])
 117 if test $tar_cv_path_RSH = no; then
 118   AC_CHECK_HEADERS(netdb.h)
 119 else
 120   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 121     [Define to the full path of your rsh, if any.])
 122 fi
 123
 124 TAR_COMPR_PROGRAM(compress)
 125 TAR_COMPR_PROGRAM(gzip)
 126 TAR_COMPR_PROGRAM(bzip2)
 127 TAR_COMPR_PROGRAM(lzma)
 128 TAR_COMPR_PROGRAM(lzop)
 129 TAR_COMPR_PROGRAM(xz)
 130
 131 AC_MSG_CHECKING(for default archive format)
 132
 133 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 134            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 135
 136 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 137   DEFAULT_ARCHIVE_FORMAT="GNU"
 138 fi
 139 case $DEFAULT_ARCHIVE_FORMAT in
 140   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 141   *) AC_MSG_ERROR(Invalid format name);;
 142 esac
 143 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 144   [By default produce archives of this format])
 145 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 146
 147 AC_MSG_CHECKING(for default archive)
 148
 149 AC_ARG_VAR([DEFAULT_ARCHIVE],
 150            [Set the name of the default archive (default: -)])
 151 if test -z "$DEFAULT_ARCHIVE"; then
 152   DEFAULT_ARCHIVE=-
 153 else
 154   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 155     AC_MSG_WARN(DEFAULT_ARCHIVE \`$DEFAULT_ARCHIVE' not found on this system)
 156   fi
 157   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 158   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 159   # FIXME: Rearrange, here.
 160   case $DEFAULT_ARCHIVE in
 161     *[[0-7][lmh]])
 162       AC_DEFINE(DENSITY_LETTER, 1,
 163         [Define to 1 if density may be indicated by [lmh] at end of device.])
 164       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 165       ;;
 166     *[[0-7]])
 167       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 168       ;;
 169     *)
 170       device_prefix=
 171       ;;
 172   esac
 173   case "$device_prefix" in
 174     ?*)
 175       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 176         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 177       ;;
 178   esac
 179 fi
 180 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 181   [Define to a string giving the full name of the default archive file.])
 182 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 183
 184 AC_ARG_VAR([DEFAULT_BLOCKING],
 185            [Define default blocking factor (default: 20)])
 186 AC_MSG_CHECKING(for default blocking)
 187 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 188 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 189   [Define to a number giving the default blocking size for archives.])
 190 AC_MSG_RESULT($DEFAULT_BLOCKING)
 191
 192 AC_MSG_CHECKING(for default quoting style)
 193
 194 m4_define([QUOTING_STYLES],dnl
 195           [literal|shell|shell-always|c|escape|locale|clocale])
 196 DEFAULT_QUOTING_STYLE="escape"
 197 AC_ARG_VAR([DEFAULT_QUOTING_STYLE],
 198            [Set the default quoting style. Allowed values are: ] m4_bpatsubst(QUOTING_STYLES,[|], [[, ]]) [. Default is "escape".])
 199
 200 case $DEFAULT_QUOTING_STYLE in
 201 QUOTING_STYLES) ;;
 202 *)  AC_MSG_ERROR(Invalid quoting style);;
 203 esac
 204 AC_MSG_RESULT($DEFAULT_QUOTING_STYLE)
 205 DEFAULT_QUOTING_STYLE=`echo ${DEFAULT_QUOTING_STYLE}|sed 's/-/_/g'`_quoting_style
 206 AC_DEFINE_UNQUOTED(DEFAULT_QUOTING_STYLE, $DEFAULT_QUOTING_STYLE,
 207   [Define to a default quoting style (see lib/quoteargs.c for the list)])
 208
 209 # Iconv
 210 AM_ICONV
 211 AC_CHECK_HEADERS(iconv.h)
 212 AC_CHECK_TYPE(iconv_t,:,
 213               AC_DEFINE(iconv_t, int,
 214                         [Conversion descriptor type]),
 215               [
 216 #ifdef HAVE_ICONV_H
 217 # include <iconv.h>
 218 #endif
 219 ])
 220
 221 # Gettext.
 222 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 223 AM_GNU_GETTEXT_VERSION([0.16])
 224
 225 # Initialize the test suite.
 226 AC_CONFIG_TESTDIR(tests)
 227 AC_CONFIG_FILES([tests/Makefile tests/atlocal]) # FIXME: tests/preset?
 228 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 229
 230 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 231 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 232 AC_ARG_ENABLE(backup-scripts,
 233               AC_HELP_STRING([--enable-backup-scripts],
 234                              [Create and install backup and restore scripts]),
 235               [case $enableval in
 236                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 237                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 238                     ;;
 239                esac])
 240
 241 AC_SUBST(BACKUP_SED_COND)
 242 if date +%Y-%m-%d 2>/dev/null >&2; then
 243         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 244 else
 245         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 246 fi
 247
 248 AC_OUTPUT([Makefile\
 249            doc/Makefile\
 250            gnu/Makefile\
 251            lib/Makefile\
 252            po/Makefile.in\
 253            scripts/Makefile\
 254            rmt/Makefile\
 255            src/Makefile])