Dogcows Code - chaz/tar/blob - configure.ac

   1 # Configure template for GNU tar.
   2
   3 # Copyright (C) 1991, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 # 2002, 2003, 2004 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  19 # 02111-1307, USA.
  20
  21 AC_INIT([GNU tar], [1.13.93], [bug-tar@gnu.org])
  22 AC_CONFIG_SRCDIR([src/tar.c])
  23 AC_CONFIG_AUX_DIR([config])
  24 AC_CONFIG_HEADERS([config.h:config.hin])
  25 AC_PREREQ([2.59])
  26 AM_INIT_AUTOMAKE([1.8 gnits dist-bzip2 dist-shar std-options])
  27
  28 gl_USE_SYSTEM_EXTENSIONS
  29 AC_PROG_CC
  30 AC_EXEEXT
  31 AC_PROG_RANLIB
  32 AC_SYS_LARGEFILE
  33 AC_ISC_POSIX
  34 AC_C_INLINE
  35
  36 AC_CHECK_HEADERS(fcntl.h linux/fd.h memory.h net/errno.h \
  37   sgtty.h string.h \
  38   sys/buf.h sys/device.h sys/gentape.h \
  39   sys/inet.h sys/io/trioctl.h \
  40   sys/mtio.h sys/tprintf.h sys/tape.h \
  41   unistd.h)
  42
  43 AC_HEADER_SYS_WAIT
  44 AM_STDBOOL_H
  45
  46 if test $ac_cv_header_sys_mtio_h = yes; then
  47   AC_CACHE_CHECK(for remote tape header files, tar_cv_header_rmt,
  48     [AC_TRY_CPP([
  49 #if HAVE_SGTTY_H
  50 # include <sgtty.h>
  51 #endif
  52 #include <sys/socket.h>],
  53     tar_cv_header_rmt=yes, tar_cv_header_rmt=no)])
  54   test $tar_cv_header_rmt = yes && RMT='rmt$(EXEEXT)'
  55   AC_SUBST(RMT)
  56 fi
  57
  58 AC_CACHE_CHECK(which ioctl field to test for reversed bytes,
  59   tar_cv_header_mtio_check_field,
  60   [AC_EGREP_HEADER(mt_model, sys/mtio.h,
  61   tar_cv_header_mtio_check_field=mt_model,
  62   tar_cv_header_mtio_check_field=mt_type)])
  63 AC_DEFINE_UNQUOTED(MTIO_CHECK_FIELD, $tar_cv_header_mtio_check_field,
  64   [Define to mt_model (v.g., for DG/UX), else to mt_type.])
  65
  66 AC_HEADER_DIRENT
  67 AC_HEADER_MAJOR
  68 AC_HEADER_STAT
  69 AC_HEADER_STDC
  70 AC_STRUCT_ST_BLKSIZE
  71 AC_STRUCT_ST_BLOCKS
  72 AC_MSG_CHECKING([for st_fstype string in struct stat])
  73 AC_CACHE_VAL(diff_cv_st_fstype_string,
  74   [AC_TRY_COMPILE([#include <sys/types.h>
  75 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  76    diff_cv_st_fstype_string=yes,
  77    diff_cv_st_fstype_string=no)])
  78 AC_MSG_RESULT($diff_cv_st_fstype_string)
  79 if test $diff_cv_st_fstype_string = yes; then
  80   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  81     [Define if struct stat has a char st_fstype[] member.])
  82 fi
  83
  84 AC_TYPE_SIGNAL
  85 AC_TYPE_MODE_T
  86 AC_TYPE_PID_T
  87 AC_TYPE_OFF_T
  88 AC_TYPE_SIZE_T
  89 AC_TYPE_UID_T
  90 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  91                                    [Type of major device numbers.]))
  92 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  93                                    [Type of minor device numbers.]))
  94 AC_CHECK_TYPE(dev_t, unsigned)
  95 AC_CHECK_TYPE(ino_t, unsigned)
  96
  97 gt_TYPE_SSIZE_T
  98 jm_AC_TYPE_UINTMAX_T
  99
 100
 101 # gnulib modules
 102
 103 AM_FUNC_GETLINE
 104
 105 gl_BACKUPFILE
 106 gl_DIRNAME
 107 gl_ERROR
 108 gl_EXCLUDE
 109 gl_FILEBLOCKS
 110 gl_FUNC_ALLOCA
 111 gl_FUNC_FNMATCH_GNU
 112 gl_FUNC_MEMSET
 113 gl_FUNC_MKTIME
 114 gl_FUNC_RMDIR
 115 gl_FUNC_STRTOL
 116 gl_FUNC_STRTOUL
 117 gl_FUNC_STRTOIMAX
 118 gl_FUNC_STRTOUMAX
 119 gl_GETDATE
 120 gl_GETOPT
 121 gl_HASH
 122 gl_HUMAN
 123 gl_MODECHANGE
 124 gl_OBSTACK
 125 gl_PATHMAX
 126 gl_QUOTE
 127 gl_QUOTEARG
 128 gl_SAFE_READ
 129 gl_SAFE_WRITE
 130 gl_SAVE_CWD
 131 gl_SAVEDIR
 132 gl_STRCASE
 133 gl_TIME_R
 134 gl_XALLOC
 135 gl_XGETCWD
 136 gl_XSTRTOL
 137 gl_FUNC_STPCPY
 138
 139 jm_FUNC_FTRUNCATE
 140 jm_FUNC_GLIBC_UNLOCKED_IO
 141 jm_FUNC_CHOWN
 142 jm_FUNC_LCHOWN
 143 jm_FUNC_MALLOC
 144 jm_FUNC_REALLOC
 145 jm_FUNC_UTIME
 146 jm_XSTRTOUMAX
 147
 148 AC_CHECK_MEMBERS([struct stat.st_spare1, struct stat.st_atim.tv_nsec, struct stat.st_atimespec.tv_nsec, struct stat.st_atimensec], , ,
 149                  [
 150 #include <sys/types.h>
 151 #include <sys/stat.h>])
 152
 153 # Save and restore LIBS so e.g., -lrt, isn't added to it.  Otherwise, *all*
 154 # programs in the package would end up linked with that potentially-shared
 155 # library, inducing unnecessary run-time overhead.
 156
 157 # Solaris 2.5.1 needs -lposix4 to get the clock_gettime function.
 158 # Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
 159 tar_save_LIBS=$LIBS
 160   LIB_CLOCK_GETTIME=
 161   AC_SEARCH_LIBS(clock_gettime, [rt posix4])
 162   case "$ac_cv_search_clock_gettime" in
 163     -l*) LIB_CLOCK_GETTIME=$ac_cv_search_clock_gettime;;
 164   esac
 165   AC_SUBST(LIB_CLOCK_GETTIME)
 166   AC_CHECK_FUNCS(clock_gettime)
 167 LIBS=$tar_save_LIBS
 168
 169 AC_CHECK_FUNCS(fsync lstat mkfifo readlink strerror symlink setlocale utimes)
 170 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 171 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 172 AC_CHECK_DECLS([valloc])
 173
 174 # Set LIB_SETSOCKOPT to -lnsl -lsocket if necessary.
 175 tar_save_LIBS=$LIBS
 176   LIB_SETSOCKOPT=
 177   AC_SEARCH_LIBS(setsockopt, [socket], ,
 178     [AC_SEARCH_LIBS(setsockopt, [socket], , , [-lnsl])])
 179   AC_SEARCH_LIBS(setsockopt, [nsl])
 180
 181   case "$ac_cv_search_setsockopt" in
 182     -l*) LIB_SETSOCKOPT=$ac_cv_search_setsockopt
 183   esac
 184   AC_SUBST(LIB_SETSOCKOPT)
 185 LIBS=$tar_save_LIBS
 186
 187 AC_REPLACE_FUNCS(waitpid)
 188
 189 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 190   [if test -n "$RSH"; then
 191     tar_cv_path_RSH=$RSH
 192   else
 193     tar_cv_path_RSH=no
 194     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 195         /usr/bin/nsh /usr/bin/rcmd
 196     do
 197       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 198       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 199       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 200       if test -f $ac_file; then
 201         if (test -h $ac_file) 2>/dev/null; then
 202           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 203         else
 204           tar_cv_path_RSH=$ac_file
 205           break
 206         fi
 207       fi
 208     done
 209   fi])
 210 if test $tar_cv_path_RSH = no; then
 211   AC_CHECK_HEADERS(netdb.h)
 212 else
 213   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 214     [Define to the full path of your rsh, if any.])
 215 fi
 216
 217 AC_MSG_CHECKING(for default archive format)
 218
 219 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 220   DEFAULT_ARCHIVE_FORMAT="GNU"
 221 fi
 222 case $DEFAULT_ARCHIVE_FORMAT in
 223   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 224   *) AC_MSG_ERROR(Invalid format name);;
 225 esac
 226 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 227   [By default produce archives of this format])
 228 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 229
 230 AC_MSG_CHECKING(for default archive)
 231
 232 if test -z "$DEFAULT_ARCHIVE"; then
 233   DEFAULT_ARCHIVE=-
 234 else
 235   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 236     AC_MSG_WARN(DEFAULT_ARCHIVE \`$DEFAULT_ARCHIVE' not found on this system)
 237   fi
 238   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 239   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 240   # FIXME: Rearrange, here.
 241   case $DEFAULT_ARCHIVE in
 242     *[[0-7][lmh]])
 243       AC_DEFINE(DENSITY_LETTER, 1,
 244         [[Define to 1 if density may be indicated by [lmh] at end of device.]])
 245       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 246       ;;
 247     *[[0-7]])
 248       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 249       ;;
 250     *)
 251       device_prefix=
 252       ;;
 253   esac
 254   case "$device_prefix" in
 255     ?*)
 256       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 257         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 258       ;;
 259   esac
 260 fi
 261 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 262   [Define to a string giving the full name of the default archive file.])
 263 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 264
 265 AC_MSG_CHECKING(for default blocking)
 266 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 267 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 268   [Define to a number giving the default blocking size for archives.])
 269 AC_MSG_RESULT($DEFAULT_BLOCKING)
 270
 271 # Gettext.
 272 AM_GNU_GETTEXT([external], [need-ngettext])
 273 AM_GNU_GETTEXT_VERSION(0.12.1)
 274
 275 # Iconv
 276 AC_CHECK_HEADERS(iconv.h,
 277                  [AC_CHECK_TYPE(iconv_t,:,
 278                                 AC_DEFINE(iconv_t, int,
 279                                           [Conversion descriptor type]),
 280                                 [#include <iconv.h>])])
 281
 282 AC_CHECK_LIB(iconv, iconv)
 283
 284
 285 AC_OUTPUT([Makefile\
 286            doc/Makefile\
 287            lib/Makefile\
 288            po/Makefile.in\
 289            scripts/Makefile\
 290            src/Makefile\
 291            tests/Makefile\
 292            tests/preset])