Dogcows Code - chaz/tar/blob - configure.ac

   1 # Configure template for GNU tar.  -*- autoconf -*-
   2
   3 # Copyright (C) 1991, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 # 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free
   5 # Software Foundation, Inc.
   6
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3, or (at your option)
  10 # any later version.
  11
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20 # 02110-1301, USA.
  21
  22 AC_INIT([GNU tar], [1.26.90], [bug-tar@gnu.org])
  23 AC_CONFIG_SRCDIR([src/tar.c])
  24 AC_CONFIG_AUX_DIR([build-aux])
  25 AC_CONFIG_HEADERS([config.h])
  26 AC_PREREQ([2.63])
  27 AM_INIT_AUTOMAKE([1.11 gnits tar-ustar dist-bzip2 dist-xz dist-shar std-options silent-rules])
  28
  29 # Enable silent rules by default:
  30 AM_SILENT_RULES([yes])
  31
  32 AC_PROG_CC
  33 AC_EXEEXT
  34 AC_PROG_RANLIB
  35 AC_PROG_YACC
  36 gl_EARLY
  37
  38 AC_SYS_LARGEFILE
  39 AC_ISC_POSIX
  40 AC_C_INLINE
  41
  42 AC_CHECK_HEADERS_ONCE(fcntl.h linux/fd.h memory.h net/errno.h \
  43   sgtty.h string.h \
  44   sys/param.h sys/device.h sys/gentape.h \
  45   sys/inet.h sys/io/trioctl.h \
  46   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  47   unistd.h locale.h)
  48
  49 AC_CHECK_HEADERS([sys/buf.h], [], [],
  50 [#if HAVE_SYS_PARAM_H
  51 #include <sys/param.h>
  52 #endif])
  53
  54 AC_HEADER_SYS_WAIT
  55
  56 AC_HEADER_DIRENT
  57 AC_HEADER_MAJOR
  58 AC_HEADER_STAT
  59 AC_HEADER_STDC
  60
  61 AC_MSG_CHECKING([for st_fstype string in struct stat])
  62 AC_CACHE_VAL(diff_cv_st_fstype_string,
  63   [AC_TRY_COMPILE([#include <sys/types.h>
  64 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  65    diff_cv_st_fstype_string=yes,
  66    diff_cv_st_fstype_string=no)])
  67 AC_MSG_RESULT($diff_cv_st_fstype_string)
  68 if test $diff_cv_st_fstype_string = yes; then
  69   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  70     [Define if struct stat has a char st_fstype[] member.])
  71 fi
  72
  73 # even if we use gnulib's acl.h with integrated m4 file later on (used because
  74 # of very useful file_has_acl() function) we need following checks that restrict
  75 # tar to use POSIX.1e ACLs only.
  76 AC_ARG_WITH([posix-acls],
  77     AS_HELP_STRING([--without-posix-acls],
  78                    [do not use POSIX.1e access control lists]),
  79     [with_posix_acls=no])
  80 if test "x$with_posix_acls" != "xno"; then
  81   AC_CHECK_HEADERS(sys/acl.h,, [with_posix_acl=no])
  82   AC_SEARCH_LIBS([acl_get_file],  [acl pacl],, [with_posix_acl=no])
  83   AC_SEARCH_LIBS([acl_get_fd],    [acl pacl],, [with_posix_acl=no])
  84   AC_SEARCH_LIBS([acl_set_file],  [acl pacl],, [with_posix_acl=no])
  85   AC_SEARCH_LIBS([acl_set_fd],    [acl pacl],, [with_posix_acl=no])
  86   AC_SEARCH_LIBS([acl_to_text],   [acl pacl],, [with_posix_acl=no])
  87   AC_SEARCH_LIBS([acl_from_text], [acl pacl],, [with_posix_acl=no])
  88   if test "x$with_posix_acls" != xno; then
  89     AC_DEFINE(HAVE_POSIX_ACLS,,[Define when we have working POSIX acls])
  90   fi
  91 else
  92   # disable acls in gnulib's checks
  93   export enable_acl=no
  94 fi
  95
  96 AC_TYPE_SIGNAL
  97 AC_TYPE_MODE_T
  98 AC_TYPE_PID_T
  99 AC_TYPE_OFF_T
 100 AC_TYPE_SIZE_T
 101 AC_TYPE_UID_T
 102 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
 103                                    [Type of major device numbers.]))
 104 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
 105                                    [Type of minor device numbers.]))
 106 AC_CHECK_TYPE(dev_t, unsigned)
 107 AC_CHECK_TYPE(ino_t, unsigned)
 108
 109 gt_TYPE_SSIZE_T
 110
 111 # gnulib modules
 112 gl_INIT
 113 # paxutils modules
 114 tar_PAXUTILS
 115
 116 TAR_HEADERS_ATTR_XATTR_H
 117
 118 AC_CHECK_FUNCS_ONCE([fchmod fchown fsync lstat mkfifo readlink symlink])
 119
 120 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 121 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 122 AC_CHECK_DECLS([time],,, [#include <time.h>])
 123
 124 AC_REPLACE_FUNCS(waitpid)
 125
 126 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 127   [if test -n "$RSH"; then
 128     tar_cv_path_RSH=$RSH
 129   else
 130     tar_cv_path_RSH=no
 131     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 132         /usr/bin/nsh /usr/bin/rcmd
 133     do
 134       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 135       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 136       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 137       if test -f $ac_file; then
 138         if (test -h $ac_file) 2>/dev/null; then
 139           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 140         else
 141           tar_cv_path_RSH=$ac_file
 142           break
 143         fi
 144       fi
 145     done
 146   fi])
 147 if test $tar_cv_path_RSH = no; then
 148   AC_CHECK_HEADERS(netdb.h)
 149 else
 150   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 151     [Define to the full path of your rsh, if any.])
 152 fi
 153
 154 TAR_COMPR_PROGRAM(compress)
 155 TAR_COMPR_PROGRAM(gzip)
 156 TAR_COMPR_PROGRAM(bzip2)
 157 TAR_COMPR_PROGRAM(lzip)
 158 TAR_COMPR_PROGRAM(lzma)
 159 TAR_COMPR_PROGRAM(lzop)
 160 TAR_COMPR_PROGRAM(xz)
 161
 162 AC_MSG_CHECKING(for default archive format)
 163
 164 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 165            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 166
 167 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 168   DEFAULT_ARCHIVE_FORMAT="GNU"
 169 fi
 170 case $DEFAULT_ARCHIVE_FORMAT in
 171   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 172   *) AC_MSG_ERROR(Invalid format name);;
 173 esac
 174 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 175   [By default produce archives of this format])
 176 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 177
 178 AC_MSG_CHECKING(for default archive)
 179
 180 AC_ARG_VAR([DEFAULT_ARCHIVE],
 181            [Set the name of the default archive (default: -)])
 182 if test -z "$DEFAULT_ARCHIVE"; then
 183   DEFAULT_ARCHIVE=-
 184 else
 185   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 186     AC_MSG_WARN(DEFAULT_ARCHIVE '$DEFAULT_ARCHIVE' not found on this system)
 187   fi
 188   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 189   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 190   # FIXME: Rearrange, here.
 191   case $DEFAULT_ARCHIVE in
 192     *[[0-7][lmh]])
 193       AC_DEFINE(DENSITY_LETTER, 1,
 194         [Define to 1 if density may be indicated by [lmh] at end of device.])
 195       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 196       ;;
 197     *[[0-7]])
 198       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 199       ;;
 200     *)
 201       device_prefix=
 202       ;;
 203   esac
 204   case "$device_prefix" in
 205     ?*)
 206       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 207         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 208       ;;
 209   esac
 210 fi
 211 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 212   [Define to a string giving the full name of the default archive file.])
 213 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 214
 215 AC_ARG_VAR([DEFAULT_BLOCKING],
 216            [Define default blocking factor (default: 20)])
 217 AC_MSG_CHECKING(for default blocking)
 218 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 219 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 220   [Define to a number giving the default blocking size for archives.])
 221 AC_MSG_RESULT($DEFAULT_BLOCKING)
 222
 223 AC_MSG_CHECKING(for default quoting style)
 224
 225 m4_define([QUOTING_STYLES],dnl
 226           [literal|shell|shell-always|c|escape|locale|clocale])
 227 DEFAULT_QUOTING_STYLE="escape"
 228 AC_ARG_VAR([DEFAULT_QUOTING_STYLE],
 229            [Set the default quoting style. Allowed values are: ] m4_bpatsubst(QUOTING_STYLES,[|], [[, ]]) [. Default is "escape".])
 230
 231 case $DEFAULT_QUOTING_STYLE in
 232 QUOTING_STYLES) ;;
 233 *)  AC_MSG_ERROR(Invalid quoting style);;
 234 esac
 235 AC_MSG_RESULT($DEFAULT_QUOTING_STYLE)
 236 DEFAULT_QUOTING_STYLE=`echo ${DEFAULT_QUOTING_STYLE}|sed 's/-/_/g'`_quoting_style
 237 AC_DEFINE_UNQUOTED(DEFAULT_QUOTING_STYLE, $DEFAULT_QUOTING_STYLE,
 238   [Define to a default quoting style (see lib/quoteargs.c for the list)])
 239
 240 # Iconv
 241 AM_ICONV
 242 AC_CHECK_HEADERS(iconv.h)
 243 AC_CHECK_TYPE(iconv_t,:,
 244               AC_DEFINE(iconv_t, int,
 245                         [Conversion descriptor type]),
 246               [
 247 #ifdef HAVE_ICONV_H
 248 # include <iconv.h>
 249 #endif
 250 ])
 251
 252 # Gettext.
 253 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 254 AM_GNU_GETTEXT_VERSION([0.16])
 255
 256 # Initialize the test suite.
 257 AC_CONFIG_TESTDIR(tests)
 258 AC_CONFIG_FILES([tests/Makefile tests/atlocal]) # FIXME: tests/preset?
 259 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 260
 261 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 262 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 263 AC_ARG_ENABLE(backup-scripts,
 264               AC_HELP_STRING([--enable-backup-scripts],
 265                              [Create and install backup and restore scripts]),
 266               [case $enableval in
 267                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 268                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 269                     ;;
 270                esac])
 271
 272 AC_SUBST(BACKUP_SED_COND)
 273 if date +%Y-%m-%d 2>/dev/null >&2; then
 274         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 275 else
 276         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 277 fi
 278
 279 AC_OUTPUT([Makefile\
 280            doc/Makefile\
 281            gnu/Makefile\
 282            lib/Makefile\
 283            po/Makefile.in\
 284            scripts/Makefile\
 285            rmt/Makefile\
 286            src/Makefile])