Dogcows Code - chaz/tar/blob - configure.ac

   1 # Configure template for GNU tar.
   2
   3 # Copyright (C) 1991, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 # 2002, 2003, 2004 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  19 # 02111-1307, USA.
  20
  21 AC_INIT([GNU tar], [1.13.94], [bug-tar@gnu.org])
  22 AC_CONFIG_SRCDIR([src/tar.c])
  23 AC_CONFIG_AUX_DIR([config])
  24 AC_CONFIG_HEADERS([config.h:config.hin])
  25 AC_PREREQ([2.59])
  26 AM_INIT_AUTOMAKE([1.8 gnits dist-bzip2 dist-shar std-options])
  27
  28 gl_USE_SYSTEM_EXTENSIONS
  29 AC_PROG_CC
  30 AC_EXEEXT
  31 AC_PROG_RANLIB
  32 AC_SYS_LARGEFILE
  33 AC_ISC_POSIX
  34 AC_C_INLINE
  35
  36 AC_CHECK_HEADERS(fcntl.h linux/fd.h memory.h net/errno.h \
  37   sgtty.h string.h \
  38   sys/buf.h sys/device.h sys/gentape.h \
  39   sys/inet.h sys/io/trioctl.h \
  40   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  41   unistd.h)
  42
  43 AC_HEADER_SYS_WAIT
  44 AM_STDBOOL_H
  45
  46 if test $ac_cv_header_sys_mtio_h = yes; then
  47   AC_CACHE_CHECK(for remote tape header files, tar_cv_header_rmt,
  48     [AC_TRY_CPP([
  49 #if HAVE_SGTTY_H
  50 # include <sgtty.h>
  51 #endif
  52 #include <sys/socket.h>],
  53     tar_cv_header_rmt=yes, tar_cv_header_rmt=no)])
  54   test $tar_cv_header_rmt = yes && RMT='rmt$(EXEEXT)'
  55   AC_SUBST(RMT)
  56 fi
  57
  58 AC_CACHE_CHECK(which ioctl field to test for reversed bytes,
  59   tar_cv_header_mtio_check_field,
  60   [AC_EGREP_HEADER(mt_model, sys/mtio.h,
  61   tar_cv_header_mtio_check_field=mt_model,
  62   tar_cv_header_mtio_check_field=mt_type)])
  63 AC_DEFINE_UNQUOTED(MTIO_CHECK_FIELD, $tar_cv_header_mtio_check_field,
  64   [Define to mt_model (v.g., for DG/UX), else to mt_type.])
  65
  66 AC_HEADER_DIRENT
  67 AC_HEADER_MAJOR
  68 AC_HEADER_STAT
  69 AC_HEADER_STDC
  70 AC_STRUCT_ST_BLKSIZE
  71 AC_STRUCT_ST_BLOCKS
  72 AC_MSG_CHECKING([for st_fstype string in struct stat])
  73 AC_CACHE_VAL(diff_cv_st_fstype_string,
  74   [AC_TRY_COMPILE([#include <sys/types.h>
  75 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  76    diff_cv_st_fstype_string=yes,
  77    diff_cv_st_fstype_string=no)])
  78 AC_MSG_RESULT($diff_cv_st_fstype_string)
  79 if test $diff_cv_st_fstype_string = yes; then
  80   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  81     [Define if struct stat has a char st_fstype[] member.])
  82 fi
  83
  84 AC_TYPE_SIGNAL
  85 AC_TYPE_MODE_T
  86 AC_TYPE_PID_T
  87 AC_TYPE_OFF_T
  88 AC_TYPE_SIZE_T
  89 AC_TYPE_UID_T
  90 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  91                                    [Type of major device numbers.]))
  92 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  93                                    [Type of minor device numbers.]))
  94 AC_CHECK_TYPE(dev_t, unsigned)
  95 AC_CHECK_TYPE(ino_t, unsigned)
  96
  97 gt_TYPE_SSIZE_T
  98 jm_AC_TYPE_UINTMAX_T
  99
 100
 101 # gnulib modules
 102
 103 AM_FUNC_GETLINE
 104
 105 gl_BACKUPFILE
 106 gl_DIRNAME
 107 gl_ERROR
 108 gl_EXCLUDE
 109 gl_FILEBLOCKS
 110 gl_FUNC_ALLOCA
 111 gl_FUNC_FNMATCH_GNU
 112 gl_FUNC_MEMSET
 113 gl_FUNC_MKTIME
 114 gl_FUNC_RMDIR
 115 gl_FUNC_STRTOL
 116 gl_FUNC_STRTOUL
 117 gl_FUNC_STRTOULL
 118 gl_FUNC_STRTOIMAX
 119 gl_FUNC_STRTOUMAX
 120 gl_GETDATE
 121 gl_GETOPT
 122 gl_GETTIME
 123 gl_HASH
 124 gl_HUMAN
 125 gl_MODECHANGE
 126 gl_OBSTACK
 127 gl_PATHMAX
 128 gl_QUOTE
 129 gl_QUOTEARG
 130 gl_SAFE_READ
 131 gl_SAFE_WRITE
 132 gl_SAVE_CWD
 133 gl_SAVEDIR
 134 gl_STRCASE
 135 gl_TIME_R
 136 gl_TIMESPEC
 137 gl_XALLOC
 138 gl_XGETCWD
 139 gl_XSTRTOL
 140 gl_FUNC_STPCPY
 141
 142 jm_FUNC_FTRUNCATE
 143 jm_FUNC_GLIBC_UNLOCKED_IO
 144 jm_FUNC_CHOWN
 145 jm_FUNC_LCHOWN
 146 jm_FUNC_MALLOC
 147 jm_FUNC_REALLOC
 148 jm_FUNC_UTIME
 149 jm_XSTRTOUMAX
 150
 151 AC_CHECK_MEMBERS([struct stat.st_spare1, struct stat.st_atim.tv_nsec, struct stat.st_atimespec.tv_nsec, struct stat.st_atimensec], , ,
 152                  [
 153 #include <sys/types.h>
 154 #include <sys/stat.h>])
 155
 156 # Save and restore LIBS so e.g., -lrt, isn't added to it.  Otherwise, *all*
 157 # programs in the package would end up linked with that potentially-shared
 158 # library, inducing unnecessary run-time overhead.
 159
 160 # Solaris 2.5.1 needs -lposix4 to get the clock_gettime function.
 161 # Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
 162 tar_save_LIBS=$LIBS
 163   LIB_CLOCK_GETTIME=
 164   AC_SEARCH_LIBS(clock_gettime, [rt posix4])
 165   case "$ac_cv_search_clock_gettime" in
 166     -l*) LIB_CLOCK_GETTIME=$ac_cv_search_clock_gettime;;
 167   esac
 168   AC_SUBST(LIB_CLOCK_GETTIME)
 169   AC_CHECK_FUNCS(clock_gettime)
 170 LIBS=$tar_save_LIBS
 171
 172 AC_CHECK_FUNCS(fsync lstat mkfifo readlink strerror symlink setlocale utimes)
 173 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 174 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 175 AC_CHECK_DECLS([valloc])
 176 AC_CHECK_DECLS([time],,, [#include <time.h>])
 177
 178 # Set LIB_SETSOCKOPT to -lnsl -lsocket if necessary.
 179 tar_save_LIBS=$LIBS
 180   LIB_SETSOCKOPT=
 181   AC_SEARCH_LIBS(setsockopt, [socket], ,
 182     [AC_SEARCH_LIBS(setsockopt, [socket], , , [-lnsl])])
 183   AC_SEARCH_LIBS(setsockopt, [nsl])
 184
 185   case "$ac_cv_search_setsockopt" in
 186     -l*) LIB_SETSOCKOPT=$ac_cv_search_setsockopt
 187   esac
 188   AC_SUBST(LIB_SETSOCKOPT)
 189 LIBS=$tar_save_LIBS
 190
 191 AC_REPLACE_FUNCS(waitpid)
 192
 193 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 194   [if test -n "$RSH"; then
 195     tar_cv_path_RSH=$RSH
 196   else
 197     tar_cv_path_RSH=no
 198     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 199         /usr/bin/nsh /usr/bin/rcmd
 200     do
 201       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 202       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 203       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 204       if test -f $ac_file; then
 205         if (test -h $ac_file) 2>/dev/null; then
 206           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 207         else
 208           tar_cv_path_RSH=$ac_file
 209           break
 210         fi
 211       fi
 212     done
 213   fi])
 214 if test $tar_cv_path_RSH = no; then
 215   AC_CHECK_HEADERS(netdb.h)
 216 else
 217   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 218     [Define to the full path of your rsh, if any.])
 219 fi
 220
 221 AC_MSG_CHECKING(for default archive format)
 222
 223 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 224   DEFAULT_ARCHIVE_FORMAT="GNU"
 225 fi
 226 case $DEFAULT_ARCHIVE_FORMAT in
 227   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 228   *) AC_MSG_ERROR(Invalid format name);;
 229 esac
 230 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 231   [By default produce archives of this format])
 232 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 233
 234 AC_MSG_CHECKING(for default archive)
 235
 236 if test -z "$DEFAULT_ARCHIVE"; then
 237   DEFAULT_ARCHIVE=-
 238 else
 239   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 240     AC_MSG_WARN(DEFAULT_ARCHIVE \`$DEFAULT_ARCHIVE' not found on this system)
 241   fi
 242   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 243   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 244   # FIXME: Rearrange, here.
 245   case $DEFAULT_ARCHIVE in
 246     *[[0-7][lmh]])
 247       AC_DEFINE(DENSITY_LETTER, 1,
 248         [[Define to 1 if density may be indicated by [lmh] at end of device.]])
 249       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 250       ;;
 251     *[[0-7]])
 252       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 253       ;;
 254     *)
 255       device_prefix=
 256       ;;
 257   esac
 258   case "$device_prefix" in
 259     ?*)
 260       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 261         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 262       ;;
 263   esac
 264 fi
 265 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 266   [Define to a string giving the full name of the default archive file.])
 267 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 268
 269 AC_MSG_CHECKING(for default blocking)
 270 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 271 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 272   [Define to a number giving the default blocking size for archives.])
 273 AC_MSG_RESULT($DEFAULT_BLOCKING)
 274
 275 # Gettext.
 276 AM_GNU_GETTEXT([external], [need-ngettext])
 277 AM_GNU_GETTEXT_VERSION(0.12.1)
 278
 279 # Iconv
 280 AM_ICONV
 281 AC_CHECK_HEADERS(iconv.h,
 282                  [AC_CHECK_TYPE(iconv_t,:,
 283                                 AC_DEFINE(iconv_t, int,
 284                                           [Conversion descriptor type]),
 285                                 [#include <iconv.h>])])
 286
 287 AC_OUTPUT([Makefile\
 288            doc/Makefile\
 289            lib/Makefile\
 290            po/Makefile.in\
 291            scripts/Makefile\
 292            src/Makefile\
 293            tests/Makefile\
 294            tests/preset])