Dogcows Code - chaz/tar/blob - configure.ac

   1 # Configure template for GNU tar.  -*- autoconf -*-
   2
   3 # Copyright 1991, 1994-2010, 2013 Free Software Foundation, Inc.
   4
   5 # This file is part of GNU tar.
   6
   7 # GNU tar is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11
  12 # GNU tar is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_INIT([GNU tar], [1.27.1], [bug-tar@gnu.org])
  21 AC_CONFIG_SRCDIR([src/tar.c])
  22 AC_CONFIG_AUX_DIR([build-aux])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_PREREQ([2.63])
  25 AM_INIT_AUTOMAKE([1.11 gnits tar-ustar dist-bzip2 dist-xz dist-shar std-options silent-rules])
  26
  27 # Enable silent rules by default:
  28 AM_SILENT_RULES([yes])
  29
  30 AC_PROG_CC
  31 AC_EXEEXT
  32 AC_PROG_RANLIB
  33 AC_PROG_YACC
  34 gl_EARLY
  35
  36 AC_SYS_LARGEFILE
  37 AC_ISC_POSIX
  38 AC_C_INLINE
  39
  40 AC_CHECK_HEADERS_ONCE(fcntl.h linux/fd.h memory.h net/errno.h \
  41   sgtty.h string.h \
  42   sys/param.h sys/device.h sys/gentape.h \
  43   sys/inet.h sys/io/trioctl.h \
  44   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  45   unistd.h locale.h)
  46
  47 AC_CHECK_HEADERS([sys/buf.h], [], [],
  48 [#if HAVE_SYS_PARAM_H
  49 #include <sys/param.h>
  50 #endif])
  51
  52 AC_HEADER_SYS_WAIT
  53
  54 AC_HEADER_DIRENT
  55 AC_HEADER_MAJOR
  56 AC_HEADER_STAT
  57 AC_HEADER_STDC
  58
  59 AC_MSG_CHECKING([for st_fstype string in struct stat])
  60 AC_CACHE_VAL(diff_cv_st_fstype_string,
  61   [AC_TRY_COMPILE([#include <sys/types.h>
  62 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  63    diff_cv_st_fstype_string=yes,
  64    diff_cv_st_fstype_string=no)])
  65 AC_MSG_RESULT($diff_cv_st_fstype_string)
  66 if test $diff_cv_st_fstype_string = yes; then
  67   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  68     [Define if struct stat has a char st_fstype[] member.])
  69 fi
  70
  71 # even if we use gnulib's acl.h with integrated m4 file later on (used because
  72 # of very useful file_has_acl() function) we need following checks that restrict
  73 # tar to use POSIX.1e ACLs only.
  74 AC_ARG_WITH([posix-acls],
  75     AS_HELP_STRING([--without-posix-acls],
  76                    [do not use POSIX.1e access control lists]),
  77     [],
  78     [with_posix_acls=yes])
  79 if test "x$with_posix_acls" != "xno"; then
  80   AC_CHECK_HEADERS(sys/acl.h,, [with_posix_acls=no])
  81   for tar_acl_func in acl_get_file acl_get_fd acl_set_file acl_set_fd \
  82                       acl_to_text acl_from_text; do \
  83     test "x$with_posix_acls" = xno && break
  84     AC_SEARCH_LIBS([$tar_acl_func], [acl pacl], [], [with_posix_acls=no])
  85   done
  86   if test "x$with_posix_acls" != xno; then
  87     AC_DEFINE(HAVE_POSIX_ACLS,,[Define when we have working POSIX acls])
  88   fi
  89 else
  90   # disable acls in gnulib's checks
  91   export enable_acl=no
  92 fi
  93
  94 AC_TYPE_SIGNAL
  95 AC_TYPE_MODE_T
  96 AC_TYPE_PID_T
  97 AC_TYPE_OFF_T
  98 AC_TYPE_SIZE_T
  99 AC_TYPE_UID_T
 100 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
 101                                    [Type of major device numbers.]))
 102 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
 103                                    [Type of minor device numbers.]))
 104 AC_CHECK_TYPE(dev_t, unsigned)
 105 AC_CHECK_TYPE(ino_t, unsigned)
 106
 107 gt_TYPE_SSIZE_T
 108
 109 # gnulib modules
 110 gl_INIT
 111 # paxutils modules
 112 tar_PAXUTILS
 113
 114 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 115 # ------------------------------------------------
 116 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 117 # Otherwise, run RUN-IF-NOT-FOUND.
 118 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 119   [AC_PREPROC_IFELSE(
 120     [AC_LANG_PROGRAM(
 121       [[
 122 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 123 /* ok */
 124 #else
 125 # error "your version of gcc is older than $1.$2"
 126 #endif
 127       ]]),
 128     ], [$3], [$4])
 129   ]
 130 )
 131
 132 AC_ARG_ENABLE([gcc-warnings],
 133   [AS_HELP_STRING([--enable-gcc-warnings],
 134      [turn on many GCC warnings (for developers; best with GNU make)])],
 135   [case $enableval in
 136      yes|no) ;;
 137      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 138    esac
 139    gl_gcc_warnings=$enableval],
 140   [gl_gcc_warnings=no
 141    if test -d "$srcdir"/.git; then
 142      gl_GCC_VERSION_IFELSE([4], [6], [gl_gcc_warnings=yes])
 143    fi]
 144 )
 145
 146 if test "$gl_gcc_warnings" = yes; then
 147   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 148   AC_SUBST([WERROR_CFLAGS])
 149
 150   nw=
 151   # This, $nw, is the list of warnings we disable.
 152   nw="$nw -Wformat-nonliteral"      # warnings in Fedora 17 stdio.h
 153   nw="$nw -Wvla"                    # warnings in gettext.h
 154   nw="$nw -Wswitch-default"         # Too many warnings for now
 155   nw="$nw -Wunsafe-loop-optimizations" # It's OK to omit unsafe optimizations.
 156   nw="$nw -Winline"                 # It's OK to not inline.
 157   nw="$nw -Wstrict-overflow"        # It's OK to optimize strictly.
 158   nw="$nw -Wsuggest-attribute=pure" # Too many warnings for now.
 159
 160   gl_MANYWARN_ALL_GCC([ws])
 161   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 162   for w in $ws; do
 163     gl_WARN_ADD([$w])
 164   done
 165   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 166   gl_WARN_ADD([-Wno-type-limits])      # It's OK to optimize based on types.
 167   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 168   gl_WARN_ADD([-Wno-format-nonliteral])
 169
 170   gl_WARN_ADD([-fdiagnostics-show-option])
 171   gl_WARN_ADD([-funit-at-a-time])
 172
 173   AC_SUBST([WARN_CFLAGS])
 174
 175   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 176   AH_VERBATIM([FORTIFY_SOURCE],
 177   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 178       without upsetting glibc 2.15+. */
 179    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 180    # define _FORTIFY_SOURCE 2
 181    #endif
 182   ])
 183   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 184
 185   # Use a slightly smaller set of warning options for lib/.
 186   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 187   nw=
 188   nw="$nw -Wmissing-prototypes"
 189   nw="$nw -Wunused-macros"
 190   #
 191   # These are for argp.
 192   nw="$nw -Wmissing-field-initializers"
 193   nw="$nw -Wshadow"
 194   #
 195   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 196
 197   # This is also for argp.
 198   gl_WARN_ADD([-Wno-missing-field-initializers], [GNULIB_WARN_CFLAGS])
 199
 200   AC_SUBST([GNULIB_WARN_CFLAGS])
 201
 202   # For gnulib-tests, the set is slightly smaller still.
 203   nw=
 204   # It's not worth being this picky about test programs.
 205   nw="$nw -Wsuggest-attribute=const"
 206   gl_MANYWARN_COMPLEMENT([GNULIB_TEST_WARN_CFLAGS],
 207                          [$GNULIB_WARN_CFLAGS], [$nw])
 208   AC_SUBST([GNULIB_TEST_WARN_CFLAGS])
 209 fi
 210
 211 TAR_HEADERS_ATTR_XATTR_H
 212
 213 AC_CHECK_FUNCS_ONCE([fchmod fchown fsync lstat mkfifo readlink symlink])
 214
 215 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 216 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 217 AC_CHECK_DECLS([time],,, [#include <time.h>])
 218
 219 AC_REPLACE_FUNCS(waitpid)
 220
 221 AC_ARG_VAR([RSH], [Configure absolute path to default remote shell binary])
 222 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 223   [if test -n "$RSH"; then
 224     tar_cv_path_RSH=$RSH
 225   else
 226     tar_cv_path_RSH=no
 227     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 228         /usr/bin/nsh /usr/bin/rcmd
 229     do
 230       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 231       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 232       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 233       if test -f $ac_file; then
 234         if (test -h $ac_file) 2>/dev/null; then
 235           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 236         else
 237           tar_cv_path_RSH=$ac_file
 238           break
 239         fi
 240       fi
 241     done
 242   fi])
 243 if test $tar_cv_path_RSH = no; then
 244   AC_CHECK_HEADERS(netdb.h)
 245 else
 246   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 247     [Define to the full path of your rsh, if any.])
 248 fi
 249
 250 TAR_COMPR_PROGRAM(compress)
 251 TAR_COMPR_PROGRAM(gzip)
 252 TAR_COMPR_PROGRAM(bzip2)
 253 TAR_COMPR_PROGRAM(lzip)
 254 TAR_COMPR_PROGRAM(lzma)
 255 TAR_COMPR_PROGRAM(lzop)
 256 TAR_COMPR_PROGRAM(xz)
 257
 258 AC_MSG_CHECKING(for default archive format)
 259
 260 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 261            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 262
 263 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 264   DEFAULT_ARCHIVE_FORMAT="GNU"
 265 fi
 266 case $DEFAULT_ARCHIVE_FORMAT in
 267   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 268   *) AC_MSG_ERROR(Invalid format name);;
 269 esac
 270 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 271   [By default produce archives of this format])
 272 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 273
 274 AC_MSG_CHECKING(for default archive)
 275
 276 AC_ARG_VAR([DEFAULT_ARCHIVE],
 277            [Set the name of the default archive (default: -)])
 278 if test -z "$DEFAULT_ARCHIVE"; then
 279   DEFAULT_ARCHIVE=-
 280 else
 281   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 282     AC_MSG_WARN(DEFAULT_ARCHIVE '$DEFAULT_ARCHIVE' not found on this system)
 283   fi
 284   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 285   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 286   # FIXME: Rearrange, here.
 287   case $DEFAULT_ARCHIVE in
 288     *[[0-7][lmh]])
 289       AC_DEFINE(DENSITY_LETTER, 1,
 290         [Define to 1 if density may be indicated by [lmh] at end of device.])
 291       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 292       ;;
 293     *[[0-7]])
 294       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 295       ;;
 296     *)
 297       device_prefix=
 298       ;;
 299   esac
 300   case "$device_prefix" in
 301     ?*)
 302       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 303         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 304       ;;
 305   esac
 306 fi
 307 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 308   [Define to a string giving the full name of the default archive file.])
 309 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 310
 311 AC_ARG_VAR([DEFAULT_BLOCKING],
 312            [Define default blocking factor (default: 20)])
 313 AC_MSG_CHECKING(for default blocking)
 314 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 315 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 316   [Define to a number giving the default blocking size for archives.])
 317 AC_MSG_RESULT($DEFAULT_BLOCKING)
 318
 319 AC_MSG_CHECKING(for default quoting style)
 320
 321 m4_define([QUOTING_STYLES],dnl
 322           [literal|shell|shell-always|c|escape|locale|clocale])
 323 DEFAULT_QUOTING_STYLE="escape"
 324 AC_ARG_VAR([DEFAULT_QUOTING_STYLE],
 325            [Set the default quoting style. Allowed values are: ] m4_bpatsubst(QUOTING_STYLES,[|], [[, ]]) [. Default is "escape".])
 326
 327 case $DEFAULT_QUOTING_STYLE in
 328 QUOTING_STYLES) ;;
 329 *)  AC_MSG_ERROR(Invalid quoting style);;
 330 esac
 331 AC_MSG_RESULT($DEFAULT_QUOTING_STYLE)
 332 DEFAULT_QUOTING_STYLE=`echo ${DEFAULT_QUOTING_STYLE}|sed 's/-/_/g'`_quoting_style
 333 AC_DEFINE_UNQUOTED(DEFAULT_QUOTING_STYLE, $DEFAULT_QUOTING_STYLE,
 334   [Define to a default quoting style (see lib/quoteargs.c for the list)])
 335
 336 # Iconv
 337 AM_ICONV
 338 AC_CHECK_HEADERS(iconv.h)
 339 AC_CHECK_TYPE(iconv_t,:,
 340               AC_DEFINE(iconv_t, int,
 341                         [Conversion descriptor type]),
 342               [
 343 #ifdef HAVE_ICONV_H
 344 # include <iconv.h>
 345 #endif
 346 ])
 347
 348 # Gettext.
 349 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 350 AM_GNU_GETTEXT_VERSION([0.16])
 351
 352 # Initialize the test suite.
 353 AC_CONFIG_TESTDIR(tests)
 354 AC_CONFIG_FILES([tests/Makefile tests/atlocal]) # FIXME: tests/preset?
 355 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 356
 357 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 358 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 359 AC_ARG_ENABLE(backup-scripts,
 360               AC_HELP_STRING([--enable-backup-scripts],
 361                              [Create and install backup and restore scripts]),
 362               [case $enableval in
 363                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 364                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 365                     ;;
 366                esac])
 367
 368 AC_SUBST(BACKUP_SED_COND)
 369 if date +%Y-%m-%d 2>/dev/null >&2; then
 370         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 371 else
 372         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 373 fi
 374
 375 AC_OUTPUT([Makefile\
 376            doc/Makefile\
 377            gnu/Makefile\
 378            lib/Makefile\
 379            po/Makefile.in\
 380            scripts/Makefile\
 381            rmt/Makefile\
 382            src/Makefile])