Dogcows Code - chaz/tar/blob - configure.ac

   1 # Configure template for GNU tar.  -*- autoconf -*-
   2
   3 # Copyright 1991, 1994-2010, 2013 Free Software Foundation, Inc.
   4
   5 # This file is part of GNU tar.
   6
   7 # GNU tar is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11
  12 # GNU tar is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_INIT([GNU tar], [1.26.90], [bug-tar@gnu.org])
  21 AC_CONFIG_SRCDIR([src/tar.c])
  22 AC_CONFIG_AUX_DIR([build-aux])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_PREREQ([2.63])
  25 AM_INIT_AUTOMAKE([1.11 gnits tar-ustar dist-bzip2 dist-xz dist-shar std-options silent-rules])
  26
  27 # Enable silent rules by default:
  28 AM_SILENT_RULES([yes])
  29
  30 AC_PROG_CC
  31 AC_EXEEXT
  32 AC_PROG_RANLIB
  33 AC_PROG_YACC
  34 gl_EARLY
  35
  36 AC_SYS_LARGEFILE
  37 AC_ISC_POSIX
  38 AC_C_INLINE
  39
  40 AC_CHECK_HEADERS_ONCE(fcntl.h linux/fd.h memory.h net/errno.h \
  41   sgtty.h string.h \
  42   sys/param.h sys/device.h sys/gentape.h \
  43   sys/inet.h sys/io/trioctl.h \
  44   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  45   unistd.h locale.h)
  46
  47 AC_CHECK_HEADERS([sys/buf.h], [], [],
  48 [#if HAVE_SYS_PARAM_H
  49 #include <sys/param.h>
  50 #endif])
  51
  52 AC_HEADER_SYS_WAIT
  53
  54 AC_HEADER_DIRENT
  55 AC_HEADER_MAJOR
  56 AC_HEADER_STAT
  57 AC_HEADER_STDC
  58
  59 AC_MSG_CHECKING([for st_fstype string in struct stat])
  60 AC_CACHE_VAL(diff_cv_st_fstype_string,
  61   [AC_TRY_COMPILE([#include <sys/types.h>
  62 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  63    diff_cv_st_fstype_string=yes,
  64    diff_cv_st_fstype_string=no)])
  65 AC_MSG_RESULT($diff_cv_st_fstype_string)
  66 if test $diff_cv_st_fstype_string = yes; then
  67   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  68     [Define if struct stat has a char st_fstype[] member.])
  69 fi
  70
  71 # even if we use gnulib's acl.h with integrated m4 file later on (used because
  72 # of very useful file_has_acl() function) we need following checks that restrict
  73 # tar to use POSIX.1e ACLs only.
  74 AC_ARG_WITH([posix-acls],
  75     AS_HELP_STRING([--without-posix-acls],
  76                    [do not use POSIX.1e access control lists]),
  77     [with_posix_acls=no])
  78 if test "x$with_posix_acls" != "xno"; then
  79   AC_CHECK_HEADERS(sys/acl.h,, [with_posix_acls=no])
  80   for tar_acl_func in acl_get_file acl_get_fd acl_set_file acl_set_fd \
  81                       acl_to_text acl_from_text; do \
  82     test "x$with_posix_acls" = xno && break
  83     AC_SEARCH_LIBS([$tar_acl_func], [acl pacl], [], [with_posix_acls=no])
  84   done
  85   if test "x$with_posix_acls" != xno; then
  86     AC_DEFINE(HAVE_POSIX_ACLS,,[Define when we have working POSIX acls])
  87   fi
  88 else
  89   # disable acls in gnulib's checks
  90   export enable_acl=no
  91 fi
  92
  93 AC_TYPE_SIGNAL
  94 AC_TYPE_MODE_T
  95 AC_TYPE_PID_T
  96 AC_TYPE_OFF_T
  97 AC_TYPE_SIZE_T
  98 AC_TYPE_UID_T
  99 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
 100                                    [Type of major device numbers.]))
 101 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
 102                                    [Type of minor device numbers.]))
 103 AC_CHECK_TYPE(dev_t, unsigned)
 104 AC_CHECK_TYPE(ino_t, unsigned)
 105
 106 gt_TYPE_SSIZE_T
 107
 108 # gnulib modules
 109 gl_INIT
 110 # paxutils modules
 111 tar_PAXUTILS
 112
 113 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 114 # ------------------------------------------------
 115 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 116 # Otherwise, run RUN-IF-NOT-FOUND.
 117 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 118   [AC_PREPROC_IFELSE(
 119     [AC_LANG_PROGRAM(
 120       [[
 121 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 122 /* ok */
 123 #else
 124 # error "your version of gcc is older than $1.$2"
 125 #endif
 126       ]]),
 127     ], [$3], [$4])
 128   ]
 129 )
 130
 131 AC_ARG_ENABLE([gcc-warnings],
 132   [AS_HELP_STRING([--enable-gcc-warnings],
 133      [turn on many GCC warnings (for developers; best with GNU make)])],
 134   [case $enableval in
 135      yes|no) ;;
 136      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 137    esac
 138    gl_gcc_warnings=$enableval],
 139   [gl_gcc_warnings=no
 140    if test -d "$srcdir"/.git; then
 141      gl_GCC_VERSION_IFELSE([4], [6], [gl_gcc_warnings=yes])
 142    fi]
 143 )
 144
 145 if test "$gl_gcc_warnings" = yes; then
 146   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 147   AC_SUBST([WERROR_CFLAGS])
 148
 149   nw=
 150   # This, $nw, is the list of warnings we disable.
 151   nw="$nw -Wformat-nonliteral"      # warnings in Fedora 17 stdio.h
 152   nw="$nw -Wvla"                    # warnings in gettext.h
 153   nw="$nw -Wswitch-default"         # Too many warnings for now
 154   nw="$nw -Wunsafe-loop-optimizations" # It's OK to omit unsafe optimizations.
 155   nw="$nw -Winline"                 # It's OK to not inline.
 156   nw="$nw -Wstrict-overflow"        # It's OK to optimize strictly.
 157   nw="$nw -Wsuggest-attribute=pure" # Too many warnings for now.
 158
 159   gl_MANYWARN_ALL_GCC([ws])
 160   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 161   for w in $ws; do
 162     gl_WARN_ADD([$w])
 163   done
 164   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 165   gl_WARN_ADD([-Wno-type-limits])      # It's OK to optimize based on types.
 166   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 167   gl_WARN_ADD([-Wno-format-nonliteral])
 168
 169   gl_WARN_ADD([-fdiagnostics-show-option])
 170   gl_WARN_ADD([-funit-at-a-time])
 171
 172   AC_SUBST([WARN_CFLAGS])
 173
 174   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 175   AH_VERBATIM([FORTIFY_SOURCE],
 176   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 177       without upsetting glibc 2.15+. */
 178    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 179    # define _FORTIFY_SOURCE 2
 180    #endif
 181   ])
 182   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 183
 184   # Use a slightly smaller set of warning options for lib/.
 185   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 186   nw=
 187   nw="$nw -Wmissing-prototypes"
 188   nw="$nw -Wunused-macros"
 189   #
 190   # These are for argp.
 191   nw="$nw -Wmissing-field-initializers"
 192   nw="$nw -Wshadow"
 193   #
 194   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 195
 196   # This is also for argp.
 197   gl_WARN_ADD([-Wno-missing-field-initializers], [GNULIB_WARN_CFLAGS])
 198
 199   AC_SUBST([GNULIB_WARN_CFLAGS])
 200
 201   # For gnulib-tests, the set is slightly smaller still.
 202   nw=
 203   # It's not worth being this picky about test programs.
 204   nw="$nw -Wsuggest-attribute=const"
 205   gl_MANYWARN_COMPLEMENT([GNULIB_TEST_WARN_CFLAGS],
 206                          [$GNULIB_WARN_CFLAGS], [$nw])
 207   AC_SUBST([GNULIB_TEST_WARN_CFLAGS])
 208 fi
 209
 210 TAR_HEADERS_ATTR_XATTR_H
 211
 212 AC_CHECK_FUNCS_ONCE([fchmod fchown fsync lstat mkfifo readlink symlink])
 213
 214 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 215 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 216 AC_CHECK_DECLS([time],,, [#include <time.h>])
 217
 218 AC_REPLACE_FUNCS(waitpid)
 219
 220 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 221   [if test -n "$RSH"; then
 222     tar_cv_path_RSH=$RSH
 223   else
 224     tar_cv_path_RSH=no
 225     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 226         /usr/bin/nsh /usr/bin/rcmd
 227     do
 228       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 229       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 230       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 231       if test -f $ac_file; then
 232         if (test -h $ac_file) 2>/dev/null; then
 233           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 234         else
 235           tar_cv_path_RSH=$ac_file
 236           break
 237         fi
 238       fi
 239     done
 240   fi])
 241 if test $tar_cv_path_RSH = no; then
 242   AC_CHECK_HEADERS(netdb.h)
 243 else
 244   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 245     [Define to the full path of your rsh, if any.])
 246 fi
 247
 248 TAR_COMPR_PROGRAM(compress)
 249 TAR_COMPR_PROGRAM(gzip)
 250 TAR_COMPR_PROGRAM(bzip2)
 251 TAR_COMPR_PROGRAM(lzip)
 252 TAR_COMPR_PROGRAM(lzma)
 253 TAR_COMPR_PROGRAM(lzop)
 254 TAR_COMPR_PROGRAM(xz)
 255
 256 AC_MSG_CHECKING(for default archive format)
 257
 258 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 259            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 260
 261 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 262   DEFAULT_ARCHIVE_FORMAT="GNU"
 263 fi
 264 case $DEFAULT_ARCHIVE_FORMAT in
 265   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 266   *) AC_MSG_ERROR(Invalid format name);;
 267 esac
 268 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 269   [By default produce archives of this format])
 270 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 271
 272 AC_MSG_CHECKING(for default archive)
 273
 274 AC_ARG_VAR([DEFAULT_ARCHIVE],
 275            [Set the name of the default archive (default: -)])
 276 if test -z "$DEFAULT_ARCHIVE"; then
 277   DEFAULT_ARCHIVE=-
 278 else
 279   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 280     AC_MSG_WARN(DEFAULT_ARCHIVE '$DEFAULT_ARCHIVE' not found on this system)
 281   fi
 282   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 283   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 284   # FIXME: Rearrange, here.
 285   case $DEFAULT_ARCHIVE in
 286     *[[0-7][lmh]])
 287       AC_DEFINE(DENSITY_LETTER, 1,
 288         [Define to 1 if density may be indicated by [lmh] at end of device.])
 289       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 290       ;;
 291     *[[0-7]])
 292       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 293       ;;
 294     *)
 295       device_prefix=
 296       ;;
 297   esac
 298   case "$device_prefix" in
 299     ?*)
 300       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 301         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 302       ;;
 303   esac
 304 fi
 305 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 306   [Define to a string giving the full name of the default archive file.])
 307 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 308
 309 AC_ARG_VAR([DEFAULT_BLOCKING],
 310            [Define default blocking factor (default: 20)])
 311 AC_MSG_CHECKING(for default blocking)
 312 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 313 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 314   [Define to a number giving the default blocking size for archives.])
 315 AC_MSG_RESULT($DEFAULT_BLOCKING)
 316
 317 AC_MSG_CHECKING(for default quoting style)
 318
 319 m4_define([QUOTING_STYLES],dnl
 320           [literal|shell|shell-always|c|escape|locale|clocale])
 321 DEFAULT_QUOTING_STYLE="escape"
 322 AC_ARG_VAR([DEFAULT_QUOTING_STYLE],
 323            [Set the default quoting style. Allowed values are: ] m4_bpatsubst(QUOTING_STYLES,[|], [[, ]]) [. Default is "escape".])
 324
 325 case $DEFAULT_QUOTING_STYLE in
 326 QUOTING_STYLES) ;;
 327 *)  AC_MSG_ERROR(Invalid quoting style);;
 328 esac
 329 AC_MSG_RESULT($DEFAULT_QUOTING_STYLE)
 330 DEFAULT_QUOTING_STYLE=`echo ${DEFAULT_QUOTING_STYLE}|sed 's/-/_/g'`_quoting_style
 331 AC_DEFINE_UNQUOTED(DEFAULT_QUOTING_STYLE, $DEFAULT_QUOTING_STYLE,
 332   [Define to a default quoting style (see lib/quoteargs.c for the list)])
 333
 334 # Iconv
 335 AM_ICONV
 336 AC_CHECK_HEADERS(iconv.h)
 337 AC_CHECK_TYPE(iconv_t,:,
 338               AC_DEFINE(iconv_t, int,
 339                         [Conversion descriptor type]),
 340               [
 341 #ifdef HAVE_ICONV_H
 342 # include <iconv.h>
 343 #endif
 344 ])
 345
 346 # Gettext.
 347 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 348 AM_GNU_GETTEXT_VERSION([0.16])
 349
 350 # Initialize the test suite.
 351 AC_CONFIG_TESTDIR(tests)
 352 AC_CONFIG_FILES([tests/Makefile tests/atlocal]) # FIXME: tests/preset?
 353 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 354
 355 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 356 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 357 AC_ARG_ENABLE(backup-scripts,
 358               AC_HELP_STRING([--enable-backup-scripts],
 359                              [Create and install backup and restore scripts]),
 360               [case $enableval in
 361                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 362                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 363                     ;;
 364                esac])
 365
 366 AC_SUBST(BACKUP_SED_COND)
 367 if date +%Y-%m-%d 2>/dev/null >&2; then
 368         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 369 else
 370         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 371 fi
 372
 373 AC_OUTPUT([Makefile\
 374            doc/Makefile\
 375            gnu/Makefile\
 376            lib/Makefile\
 377            po/Makefile.in\
 378            scripts/Makefile\
 379            rmt/Makefile\
 380            src/Makefile])