Dogcows Code - chaz/tint2/blob - CMakeLists.txt

   1 project( tint2 )
   2 cmake_minimum_required( VERSION 2.6 )
   3
   4 include( FindPkgConfig )
   5 include( CheckLibraryExists )
   6 pkg_check_modules( X11 REQUIRED x11 xcomposite xdamage xinerama xrender xrandr>=1.3 )
   7 pkg_check_modules( PANGOCAIRO REQUIRED pangocairo )
   8 pkg_check_modules( PANGO REQUIRED pango )
   9 pkg_check_modules( CAIRO REQUIRED cairo )
  10 pkg_check_modules( GLIB2 REQUIRED glib-2.0 )
  11 pkg_check_modules( GOBJECT2 REQUIRED gobject-2.0 )
  12 pkg_check_modules( IMLIB2 REQUIRED imlib2>=1.4.2 )
  13 pkg_check_modules( SN libstartup-notification-1.0>=0.12 )
  14 find_library( RT_LIBRARY rt )
  15
  16 if( NOT X11_FOUND OR NOT PANGOCAIRO_FOUND OR NOT PANGO_FOUND OR NOT CAIRO_FOUND OR NOT GLIB2_FOUND OR NOT GOBJECT2_FOUND OR NOT IMLIB2_FOUND )
  17   message( FATAL_ERROR "Not all dependencies fulfilled. See http://code.google.com/p/tint2/wiki/Install" )
  18 endif( NOT X11_FOUND OR NOT PANGOCAIRO_FOUND OR NOT PANGO_FOUND OR NOT CAIRO_FOUND OR NOT GLIB2_FOUND OR NOT GOBJECT2_FOUND OR NOT IMLIB2_FOUND )
  19
  20 string( REPLACE ";" " " FLAGS_REPLACED "${IMLIB2_LDFLAGS}" )
  21 set( CMAKE_REQUIRED_FLAGS "${FLAGS_REPLACED}" )
  22 check_library_exists( "${IMLIB2_LIBRARIES}" "imlib_context_set_display" "${IMLIB2_LIBRARY_DIRS}" IMLIB_BUILD_WITH_X )
  23 if( NOT IMLIB_BUILD_WITH_X )
  24   message( FATAL_ERROR "Imlib is not build with x support" )
  25 endif( NOT IMLIB_BUILD_WITH_X )
  26
  27 include_directories( ${PROJECT_BINARY_DIR}
  28                      src
  29                      src/battery
  30                      src/clock
  31                      src/systray
  32                      src/taskbar
  33                      src/launcher
  34                      src/tooltip
  35                      src/util
  36                      ${X11_INCLUDE_DIRS}
  37                      ${PANGOCAIRO_INCLUDE_DIRS}
  38                      ${PANGO_INCLUDE_DIRS}
  39                      ${CAIRO_INCLUDE_DIRS}
  40                      ${GLIB2_INCLUDE_DIRS}
  41                      ${GOBJECT2_INCLUDE_DIRS}
  42                      ${IMLIB2_INCLUDE_DIRS}
  43                      ${SN_INCLUDE_DIRS} )
  44
  45 set( SOURCES src/config.c
  46              src/panel.c
  47              src/server.c
  48              src/tint.c
  49              src/clock/clock.c
  50              src/systray/systraybar.c
  51              src/launcher/launcher.c
  52              src/launcher/xsettings-client.c
  53              src/launcher/xsettings-common.c
  54              src/taskbar/task.c
  55              src/taskbar/taskbar.c
  56              src/taskbar/taskbarname.c
  57              src/tooltip/tooltip.c
  58              src/util/area.c
  59              src/util/common.c
  60              src/util/timer.c
  61              src/util/window.c )
  62
  63 option( ENABLE_BATTERY "Enable battery status plugin" ON )
  64 option( ENABLE_TINT2CONF "Enable tint2conf build, a GTK+2 theme switcher for tint2" ON )
  65 option( ENABLE_EXAMPLES "Install additional tin2rc examples" OFF )
  66 option( ENABLE_SN "Startup notification support" ON )
  67 if( ENABLE_SN )
  68   if( SN_FOUND )
  69     add_definitions( -DHAVE_SN -DSN_API_NOT_YET_FROZEN )
  70   endif( SN_FOUND )
  71 endif( ENABLE_SN)
  72
  73 if( ENABLE_BATTERY )
  74   set( SOURCES ${SOURCES} src/battery/battery.c )
  75   add_definitions( -DENABLE_BATTERY )
  76 endif( ENABLE_BATTERY )
  77
  78 set( MANDIR share/man CACHE PATH "Directory for man pages" )
  79 set( DATADIR share CACHE PATH "Directory for shared data" )
  80 set( SYSCONFDIR /etc CACHE PATH "Directory for configuration files" )
  81 set( DOCDIR share/doc/tint2 CACHE PATH "Directory for documentation files" )
  82
  83 if( ENABLE_TINT2CONF )
  84   add_definitions( -DHAVE_VERSION_H )
  85   add_subdirectory( src/tint2conf )
  86   add_dependencies( tint2conf version )
  87 endif( ENABLE_TINT2CONF )
  88
  89 add_custom_target( version ALL "${PROJECT_SOURCE_DIR}/get_svnrev.sh" "\"${PROJECT_SOURCE_DIR}\"" )
  90
  91 link_directories( ${X11_LIBRARY_DIRS}
  92                   ${PANGOCAIRO_LIBRARY_DIRS}
  93                   ${PANGO_LIBRARY_DIRS}
  94                   ${CAIRO_LIBRARY_DIRS}
  95                   ${GLIB2_LIBRARY_DIRS}
  96                   ${GOBJECT2_LIBRARY_DIRS}
  97                   ${IMLIB2_LIBRARY_DIRS}
  98                   ${SN_LIBRARY_DIRS} )
  99 add_executable(tint2 ${SOURCES})
 100 target_link_libraries( tint2 ${X11_LIBRARIES}
 101                              ${PANGOCAIRO_LIBRARIES}
 102                              ${PANGO_LIBRARIES}
 103                              ${CAIRO_LIBRARIES}
 104                              ${GLIB2_LIBRARIES}
 105                              ${GOBJECT2_LIBRARIES}
 106                              ${IMLIB2_LIBRARIES}
 107                              ${SN_LIBRARIES} )
 108 if( RT_LIBRARY )
 109   target_link_libraries( tint2 ${RT_LIBRARY} )
 110 endif( RT_LIBRARY )
 111
 112 add_dependencies( tint2 version )
 113 set_target_properties( tint2 PROPERTIES COMPILE_FLAGS "-Wall -pthread" )
 114 set_target_properties(tint2 PROPERTIES LINK_FLAGS "-pthread" )
 115
 116 install( TARGETS tint2 DESTINATION bin )
 117 install( FILES sample/tint2rc DESTINATION ${SYSCONFDIR}/xdg/tint2 )
 118 install( FILES default_icon.png DESTINATION ${DATADIR}/tint2 )
 119 install( FILES AUTHORS ChangeLog README DESTINATION ${DOCDIR} )
 120 install( FILES doc/tint2.1 DESTINATION ${MANDIR}/man1 )
 121 if( ENABLE_EXAMPLES )
 122   file( GLOB SAMPLEFILES sample/*.tint2rc )
 123   install( FILES ${SAMPLEFILES} DESTINATION ${DOCDIR}/examples )
 124 endif( ENABLE_EXAMPLES )