Dogcows Code - chaz/tint2/blob - CMakeLists.txt

   1 project( tint2 )
   2 cmake_minimum_required( VERSION 2.6 )
   3
   4 include( FindPkgConfig )
   5 include( CheckLibraryExists )
   6 pkg_check_modules( X11 REQUIRED x11 xcomposite xdamage xinerama xrender xrandr )
   7 pkg_check_modules( PANGOCAIRO REQUIRED pangocairo )
   8 pkg_check_modules( PANGO REQUIRED pango )
   9 pkg_check_modules( CAIRO REQUIRED cairo )
  10 pkg_check_modules( GLIB2 REQUIRED glib-2.0 )
  11 pkg_check_modules( GOBJECT2 REQUIRED gobject-2.0 )
  12 pkg_check_modules( IMLIB2 REQUIRED imlib2 )
  13 find_library( RT_LIBRARY rt )
  14
  15 if( NOT X11_FOUND OR NOT PANGOCAIRO_FOUND OR NOT PANGO_FOUND OR NOT CAIRO_FOUND OR NOT GLIB2_FOUND OR NOT GOBJECT2_FOUND OR NOT IMLIB2_FOUND )
  16   message( FATAL_ERROR "Not all dependencies fulfilled. See http://code.google.com/p/tint2/wiki/Install" )
  17 endif( NOT X11_FOUND OR NOT PANGOCAIRO_FOUND OR NOT PANGO_FOUND OR NOT CAIRO_FOUND OR NOT GLIB2_FOUND OR NOT GOBJECT2_FOUND OR NOT IMLIB2_FOUND )
  18
  19 string( REPLACE ";" " " FLAGS_REPLACED "${IMLIB2_LDFLAGS}" )
  20 set( CMAKE_REQUIRED_FLAGS "${FLAGS_REPLACED}" )
  21 check_library_exists( "${IMLIB2_LIBRARIES}" "imlib_context_set_display" "${IMLIB2_LIBRARY_DIRS}" IMLIB_BUILD_WITH_X )
  22 if( NOT IMLIB_BUILD_WITH_X )
  23   message( FATAL_ERROR "Imlib is not build with x support" )
  24 endif( NOT IMLIB_BUILD_WITH_X )
  25
  26 include_directories( ${PROJECT_BINARY_DIR}
  27                      src
  28                      src/battery
  29                      src/clock
  30                      src/systray
  31                      src/taskbar
  32                      src/launcher
  33                      src/tooltip
  34                      src/util
  35                      ${X11_INCLUDE_DIRS}
  36                      ${PANGOCAIRO_INCLUDE_DIRS}
  37                      ${PANGO_INCLUDE_DIRS}
  38                      ${CAIRO_INCLUDE_DIRS}
  39                      ${GLIB2_INCLUDE_DIRS}
  40                      ${GOBJECT2_INCLUDE_DIRS}
  41                      ${IMLIB2_INCLUDE_DIRS} )
  42
  43 set( SOURCES src/config.c
  44              src/panel.c
  45              src/server.c
  46              src/tint.c
  47              src/clock/clock.c
  48              src/systray/systraybar.c
  49              src/launcher/launcher.c
  50              src/taskbar/task.c
  51              src/taskbar/taskbar.c
  52              src/taskbar/taskbarname.c
  53              src/tooltip/tooltip.c
  54              src/util/area.c
  55              src/util/common.c
  56              src/util/timer.c
  57              src/util/window.c )
  58
  59 option( ENABLE_BATTERY "Enable battery status plugin" ON )
  60 option( ENABLE_TINT2CONF "Enable tint2conf build, a GTK+2 theme switcher for tint2" ON )
  61 option( ENABLE_EXAMPLES "Install additional tin2rc examples" OFF )
  62
  63 if( ENABLE_BATTERY )
  64   set( SOURCES ${SOURCES} src/battery/battery.c )
  65   add_definitions( -DENABLE_BATTERY )
  66 endif( ENABLE_BATTERY )
  67
  68 if( ENABLE_TINT2CONF )
  69   add_definitions( -DHAVE_VERSION_H )
  70   add_subdirectory( src/tint2conf )
  71   add_dependencies( tint2conf version )
  72 endif( ENABLE_TINT2CONF )
  73
  74 set( MANDIR share/man CACHE PATH "Directory for man pages" )
  75 set( DATADIR share CACHE PATH "Directory for shared data" )
  76 set( SYSCONFDIR /etc CACHE PATH "Directory for configuration files" )
  77 set( DOCDIR share/doc/tint2 CACHE PATH "Directory for documentation files" )
  78
  79 add_custom_target( version ALL "${PROJECT_SOURCE_DIR}/get_svnrev.sh" "\"${PROJECT_SOURCE_DIR}\"" )
  80
  81 link_directories( ${X11_LIBRARY_DIRS}
  82                   ${PANGOCAIRO_LIBRARY_DIRS}
  83                   ${PANGO_LIBRARY_DIRS}
  84                   ${CAIRO_LIBRARY_DIRS}
  85                   ${GLIB2_LIBRARY_DIRS}
  86                   ${GOBJECT2_LIBRARY_DIRS}
  87                   ${IMLIB2_LIBRARY_DIRS} )
  88 add_executable(tint2 ${SOURCES})
  89 target_link_libraries( tint2 ${X11_LIBRARIES}
  90                              ${PANGOCAIRO_LIBRARIES}
  91                              ${PANGO_LIBRARIES}
  92                              ${CAIRO_LIBRARIES}
  93                              ${GLIB2_LIBRARIES}
  94                              ${GOBJECT2_LIBRARIES}
  95                              ${IMLIB2_LIBRARIES} )
  96 if( RT_LIBRARY )
  97   target_link_libraries( tint2 ${RT_LIBRARY} )
  98 endif( RT_LIBRARY )
  99
 100 add_dependencies( tint2 version )
 101 set_target_properties( tint2 PROPERTIES COMPILE_FLAGS "-Wall -pthread" )
 102 set_target_properties(tint2 PROPERTIES LINK_FLAGS "-pthread" )
 103
 104 install( TARGETS tint2 DESTINATION bin )
 105 install( FILES sample/tint2rc DESTINATION ${SYSCONFDIR}/xdg/tint2 )
 106 install( FILES default_icon.png DESTINATION ${DATADIR}/tint2 )
 107 install( FILES AUTHORS ChangeLog README DESTINATION ${DOCDIR} )
 108 install( FILES doc/tint2.1 DESTINATION ${MANDIR}/man1 )
 109 if( ENABLE_EXAMPLES )
 110   file( GLOB SAMPLEFILES sample/*.tint2rc )
 111   install( FILES ${SAMPLEFILES} DESTINATION ${DOCDIR}/examples )
 112 endif( ENABLE_EXAMPLES )