Dogcows Code - chaz/tar/blob - configure.ac

   1 # Configure template for GNU tar.  -*- autoconf -*-
   2
   3 # Copyright 1991, 1994-2010, 2013-2014 Free Software Foundation, Inc.
   4
   5 # This file is part of GNU tar.
   6
   7 # GNU tar is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11
  12 # GNU tar is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_INIT([GNU tar], [1.27.90], [bug-tar@gnu.org])
  21 AC_CONFIG_SRCDIR([src/tar.c])
  22 AC_CONFIG_AUX_DIR([build-aux])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_PREREQ([2.63])
  25 AM_INIT_AUTOMAKE([1.11 gnits tar-ustar dist-bzip2 dist-xz std-options silent-rules])
  26
  27 # Enable silent rules by default:
  28 AM_SILENT_RULES([yes])
  29
  30 AC_PROG_CC_STDC
  31 AC_EXEEXT
  32 AC_PROG_RANLIB
  33 AC_PROG_YACC
  34 gl_EARLY
  35 AC_CHECK_TOOLS([AR], [ar])
  36
  37 AC_SYS_LARGEFILE
  38 AC_C_INLINE
  39
  40 AC_CHECK_HEADERS_ONCE(fcntl.h linux/fd.h memory.h net/errno.h \
  41   sgtty.h string.h \
  42   sys/param.h sys/device.h sys/gentape.h \
  43   sys/inet.h sys/io/trioctl.h \
  44   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  45   unistd.h locale.h)
  46
  47 AC_CHECK_HEADERS([sys/buf.h], [], [],
  48 [#if HAVE_SYS_PARAM_H
  49 #include <sys/param.h>
  50 #endif])
  51
  52 AC_HEADER_MAJOR
  53
  54 AC_MSG_CHECKING([for st_fstype string in struct stat])
  55 AC_CACHE_VAL(diff_cv_st_fstype_string,
  56   [AC_TRY_COMPILE([#include <sys/types.h>
  57 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  58    diff_cv_st_fstype_string=yes,
  59    diff_cv_st_fstype_string=no)])
  60 AC_MSG_RESULT($diff_cv_st_fstype_string)
  61 if test $diff_cv_st_fstype_string = yes; then
  62   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  63     [Define if struct stat has a char st_fstype[] member.])
  64 fi
  65
  66 # even if we use gnulib's acl.h with integrated m4 file later on (used because
  67 # of very useful file_has_acl() function) we need following checks that restrict
  68 # tar to use POSIX.1e ACLs only.
  69 AC_ARG_WITH([posix-acls],
  70     AS_HELP_STRING([--without-posix-acls],
  71                    [do not use POSIX.1e access control lists]),
  72     [],
  73     [with_posix_acls=yes])
  74 if test "x$with_posix_acls" != "xno"; then
  75   AC_CHECK_HEADERS(sys/acl.h,, [with_posix_acls=no])
  76   for tar_acl_func in acl_get_file acl_get_fd acl_set_file acl_set_fd \
  77                       acl_to_text acl_from_text; do \
  78     test "x$with_posix_acls" = xno && break
  79     AC_SEARCH_LIBS([$tar_acl_func], [acl pacl], [], [with_posix_acls=no])
  80   done
  81   if test "x$with_posix_acls" != xno; then
  82     AC_DEFINE(HAVE_POSIX_ACLS,,[Define when we have working POSIX acls])
  83   fi
  84 else
  85   # disable acls in gnulib's checks
  86   export enable_acl=no
  87 fi
  88
  89 AC_TYPE_MODE_T
  90 AC_TYPE_PID_T
  91 AC_TYPE_OFF_T
  92 AC_TYPE_UID_T
  93 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  94                                    [Type of major device numbers.]))
  95 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  96                                    [Type of minor device numbers.]))
  97 AC_CHECK_TYPE(dev_t, unsigned)
  98 AC_CHECK_TYPE(ino_t, unsigned)
  99
 100 gt_TYPE_SSIZE_T
 101
 102 # gnulib modules
 103 gl_INIT
 104 # paxutils modules
 105 tar_PAXUTILS
 106
 107 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 108 # ------------------------------------------------
 109 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 110 # Otherwise, run RUN-IF-NOT-FOUND.
 111 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 112   [AC_PREPROC_IFELSE(
 113     [AC_LANG_PROGRAM(
 114       [[
 115 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 116 /* ok */
 117 #else
 118 # error "your version of gcc is older than $1.$2"
 119 #endif
 120       ]]),
 121     ], [$3], [$4])
 122   ]
 123 )
 124
 125 AC_ARG_ENABLE([gcc-warnings],
 126   [AS_HELP_STRING([--enable-gcc-warnings],
 127      [turn on many GCC warnings (for developers; best with GNU make)])],
 128   [case $enableval in
 129      yes|no) ;;
 130      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 131    esac
 132    gl_gcc_warnings=$enableval],
 133   [gl_gcc_warnings=no
 134    if test -d "$srcdir"/.git; then
 135      gl_GCC_VERSION_IFELSE([4], [6], [gl_gcc_warnings=yes])
 136    fi]
 137 )
 138
 139 if test "$gl_gcc_warnings" = yes; then
 140   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 141   AC_SUBST([WERROR_CFLAGS])
 142
 143   nw=
 144   # This, $nw, is the list of warnings we disable.
 145   nw="$nw -Wformat-nonliteral"      # warnings in Fedora 17 stdio.h
 146   nw="$nw -Wvla"                    # warnings in gettext.h
 147   nw="$nw -Wswitch-default"         # Too many warnings for now
 148   nw="$nw -Wunsafe-loop-optimizations" # It's OK to omit unsafe optimizations.
 149   nw="$nw -Winline"                 # It's OK to not inline.
 150   nw="$nw -Wstrict-overflow"        # It's OK to optimize strictly.
 151   nw="$nw -Wsuggest-attribute=pure" # Too many warnings for now.
 152
 153   gl_MANYWARN_ALL_GCC([ws])
 154   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 155   for w in $ws; do
 156     gl_WARN_ADD([$w])
 157   done
 158   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 159   gl_WARN_ADD([-Wno-type-limits])      # It's OK to optimize based on types.
 160   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 161   gl_WARN_ADD([-Wno-format-nonliteral])
 162
 163   gl_WARN_ADD([-fdiagnostics-show-option])
 164   gl_WARN_ADD([-funit-at-a-time])
 165
 166   AC_SUBST([WARN_CFLAGS])
 167
 168   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 169   AH_VERBATIM([FORTIFY_SOURCE],
 170   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 171       without upsetting glibc 2.15+. */
 172    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 173    # define _FORTIFY_SOURCE 2
 174    #endif
 175   ])
 176   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 177
 178   # Use a slightly smaller set of warning options for lib/.
 179   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 180   nw=
 181   nw="$nw -Wmissing-prototypes"
 182   nw="$nw -Wunused-macros"
 183   #
 184   # These are for argp.
 185   nw="$nw -Wmissing-field-initializers"
 186   nw="$nw -Wshadow"
 187   #
 188   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 189
 190   # This is also for argp.
 191   gl_WARN_ADD([-Wno-missing-field-initializers], [GNULIB_WARN_CFLAGS])
 192
 193   AC_SUBST([GNULIB_WARN_CFLAGS])
 194
 195   # For gnulib-tests, the set is slightly smaller still.
 196   nw=
 197   # It's not worth being this picky about test programs.
 198   nw="$nw -Wsuggest-attribute=const"
 199   gl_MANYWARN_COMPLEMENT([GNULIB_TEST_WARN_CFLAGS],
 200                          [$GNULIB_WARN_CFLAGS], [$nw])
 201   AC_SUBST([GNULIB_TEST_WARN_CFLAGS])
 202 fi
 203
 204 TAR_HEADERS_ATTR_XATTR_H
 205
 206 AC_CHECK_FUNCS_ONCE([fchmod fchown fsync lstat mkfifo readlink symlink])
 207
 208 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 209 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 210 AC_CHECK_DECLS([time],,, [#include <time.h>])
 211
 212 AC_REPLACE_FUNCS(waitpid)
 213
 214 AC_ARG_VAR([RSH], [Configure absolute path to default remote shell binary])
 215 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 216   [if test -n "$RSH"; then
 217     tar_cv_path_RSH=$RSH
 218   else
 219     tar_cv_path_RSH=no
 220     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 221         /usr/bin/nsh /usr/bin/rcmd
 222     do
 223       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 224       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 225       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 226       if test -f $ac_file; then
 227         if (test -h $ac_file) 2>/dev/null; then
 228           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 229         else
 230           tar_cv_path_RSH=$ac_file
 231           break
 232         fi
 233       fi
 234     done
 235   fi])
 236 if test $tar_cv_path_RSH = no; then
 237   AC_CHECK_HEADERS(netdb.h)
 238 else
 239   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 240     [Define to the full path of your rsh, if any.])
 241 fi
 242
 243 TAR_COMPR_PROGRAM(compress)
 244 TAR_COMPR_PROGRAM(gzip)
 245 TAR_COMPR_PROGRAM(bzip2)
 246 TAR_COMPR_PROGRAM(lzip)
 247 TAR_COMPR_PROGRAM(lzma)
 248 TAR_COMPR_PROGRAM(lzop)
 249 TAR_COMPR_PROGRAM(xz)
 250
 251 AC_MSG_CHECKING(for default archive format)
 252
 253 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 254            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 255
 256 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 257   DEFAULT_ARCHIVE_FORMAT="GNU"
 258 fi
 259 case $DEFAULT_ARCHIVE_FORMAT in
 260   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 261   *) AC_MSG_ERROR(Invalid format name);;
 262 esac
 263 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 264   [By default produce archives of this format])
 265 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 266
 267 AC_MSG_CHECKING(for default archive)
 268
 269 AC_ARG_VAR([DEFAULT_ARCHIVE],
 270            [Set the name of the default archive (default: -)])
 271 if test -z "$DEFAULT_ARCHIVE"; then
 272   DEFAULT_ARCHIVE=-
 273 else
 274   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 275     AC_MSG_WARN(DEFAULT_ARCHIVE '$DEFAULT_ARCHIVE' not found on this system)
 276   fi
 277   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 278   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 279   # FIXME: Rearrange, here.
 280   case $DEFAULT_ARCHIVE in
 281     *[[0-7][lmh]])
 282       AC_DEFINE(DENSITY_LETTER, 1,
 283         [Define to 1 if density may be indicated by [lmh] at end of device.])
 284       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 285       ;;
 286     *[[0-7]])
 287       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 288       ;;
 289     *)
 290       device_prefix=
 291       ;;
 292   esac
 293   case "$device_prefix" in
 294     ?*)
 295       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 296         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 297       ;;
 298   esac
 299 fi
 300 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 301   [Define to a string giving the full name of the default archive file.])
 302 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 303
 304 AC_ARG_VAR([DEFAULT_BLOCKING],
 305            [Define default blocking factor (default: 20)])
 306 AC_MSG_CHECKING(for default blocking)
 307 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 308 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 309   [Define to a number giving the default blocking size for archives.])
 310 AC_MSG_RESULT($DEFAULT_BLOCKING)
 311
 312 AC_MSG_CHECKING(for default quoting style)
 313
 314 m4_define([QUOTING_STYLES],dnl
 315           [literal|shell|shell-always|c|escape|locale|clocale])
 316 DEFAULT_QUOTING_STYLE="escape"
 317 AC_ARG_VAR([DEFAULT_QUOTING_STYLE],
 318            [Set the default quoting style. Allowed values are: ] m4_bpatsubst(QUOTING_STYLES,[|], [[, ]]) [. Default is "escape".])
 319
 320 case $DEFAULT_QUOTING_STYLE in
 321 QUOTING_STYLES) ;;
 322 *)  AC_MSG_ERROR(Invalid quoting style);;
 323 esac
 324 AC_MSG_RESULT($DEFAULT_QUOTING_STYLE)
 325 DEFAULT_QUOTING_STYLE=`echo ${DEFAULT_QUOTING_STYLE}|sed 's/-/_/g'`_quoting_style
 326 AC_DEFINE_UNQUOTED(DEFAULT_QUOTING_STYLE, $DEFAULT_QUOTING_STYLE,
 327   [Define to a default quoting style (see lib/quoteargs.c for the list)])
 328
 329 # Iconv
 330 AM_ICONV
 331 AC_CHECK_HEADERS(iconv.h)
 332 AC_CHECK_TYPE(iconv_t,:,
 333               AC_DEFINE(iconv_t, int,
 334                         [Conversion descriptor type]),
 335               [
 336 #ifdef HAVE_ICONV_H
 337 # include <iconv.h>
 338 #endif
 339 ])
 340
 341 # Gettext.
 342 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 343 AM_GNU_GETTEXT_VERSION([0.16])
 344
 345 # Initialize the test suite.
 346 AC_CONFIG_TESTDIR(tests)
 347 AC_CONFIG_FILES([tests/Makefile tests/atlocal]) # FIXME: tests/preset?
 348 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 349
 350 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 351 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 352 AC_ARG_ENABLE(backup-scripts,
 353               AC_HELP_STRING([--enable-backup-scripts],
 354                              [Create and install backup and restore scripts]),
 355               [case $enableval in
 356                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 357                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 358                     ;;
 359                esac])
 360
 361 AC_SUBST(BACKUP_SED_COND)
 362 if date +%Y-%m-%d 2>/dev/null >&2; then
 363         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 364 else
 365         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 366 fi
 367
 368 AC_OUTPUT([Makefile\
 369            doc/Makefile\
 370            gnu/Makefile\
 371            lib/Makefile\
 372            po/Makefile.in\
 373            scripts/Makefile\
 374            rmt/Makefile\
 375            src/Makefile])