Dogcows Code - chaz/p5-File-KDBX/blob - lib/File/KDBX/Util.pm

   1 package File::KDBX::Util;
   2 # ABSTRACT: Utility functions for working with KDBX files
   3
   4 use warnings;
   5 use strict;
   6
   7 use Crypt::PRNG qw(random_bytes random_string);
   8 use Encode qw(decode encode);
   9 use Exporter qw(import);
  10 use File::KDBX::Constants qw(:bool);
  11 use File::KDBX::Error;
  12 use List::Util 1.33 qw(any all);
  13 use Module::Load;
  14 use Ref::Util qw(is_arrayref is_coderef is_hashref is_ref is_refref is_scalarref);
  15 use Scalar::Util qw(blessed looks_like_number readonly);
  16 use Time::Piece;
  17 use boolean;
  18 use namespace::clean -except => 'import';
  19
  20 our $VERSION = '999.999'; # VERSION
  21
  22 our %EXPORT_TAGS = (
  23     assert      => [qw(DEBUG assert assert_64bit)],
  24     class       => [qw(extends has list_attributes)],
  25     clone       => [qw(clone clone_nomagic)],
  26     coercion    => [qw(to_bool to_number to_string to_time to_tristate to_uuid)],
  27     crypt       => [qw(pad_pkcs7)],
  28     debug       => [qw(DEBUG dumper)],
  29     fork        => [qw(can_fork)],
  30     function    => [qw(memoize recurse_limit)],
  31     empty       => [qw(empty nonempty)],
  32     erase       => [qw(erase erase_scoped)],
  33     gzip        => [qw(gzip gunzip)],
  34     io          => [qw(is_readable is_writable read_all)],
  35     load        => [qw(load_optional load_xs try_load_optional)],
  36     search      => [qw(query search simple_expression_query)],
  37     text        => [qw(snakify trim)],
  38     uuid        => [qw(format_uuid generate_uuid is_uuid uuid UUID_NULL)],
  39     uri         => [qw(split_url uri_escape_utf8 uri_unescape_utf8)],
  40 );
  41
  42 $EXPORT_TAGS{all} = [map { @$_ } values %EXPORT_TAGS];
  43 our @EXPORT_OK = @{$EXPORT_TAGS{all}};
  44
  45 BEGIN {
  46     my $debug = $ENV{DEBUG};
  47     $debug = looks_like_number($debug) ? (0 + $debug) : ($debug ? 1 : 0);
  48     *DEBUG = $debug == 1 ? sub() { 1 } :
  49              $debug == 2 ? sub() { 2 } :
  50              $debug == 3 ? sub() { 3 } :
  51              $debug == 4 ? sub() { 4 } : sub() { 0 };
  52 }
  53
  54 my %OPS = (
  55     'eq'        =>  2, # binary
  56     'ne'        =>  2,
  57     'lt'        =>  2,
  58     'gt'        =>  2,
  59     'le'        =>  2,
  60     'ge'        =>  2,
  61     '=='        =>  2,
  62     '!='        =>  2,
  63     '<'         =>  2,
  64     '>'         =>  2,
  65     '<='        =>  2,
  66     '>='        =>  2,
  67     '=~'        =>  2,
  68     '!~'        =>  2,
  69     '!'         =>  1, # unary
  70     '!!'        =>  1,
  71     '-not'      =>  1, # special
  72     '-false'    =>  1,
  73     '-true'     =>  1,
  74     '-defined'  =>  1,
  75     '-undef'    =>  1,
  76     '-empty'    =>  1,
  77     '-nonempty' =>  1,
  78     '-or'       => -1,
  79     '-and'      => -1,
  80 );
  81 my %OP_NEG = (
  82     'eq'    =>  'ne',
  83     'ne'    =>  'eq',
  84     'lt'    =>  'ge',
  85     'gt'    =>  'le',
  86     'le'    =>  'gt',
  87     'ge'    =>  'lt',
  88     '=='    =>  '!=',
  89     '!='    =>  '==',
  90     '<'     =>  '>=',
  91     '>'     =>  '<=',
  92     '<='    =>  '>',
  93     '>='    =>  '<',
  94     '=~'    =>  '!~',
  95     '!~'    =>  '=~',
  96 );
  97 my %ATTRIBUTES;
  98
  99 =func load_xs
 100
 101     $bool = load_xs();
 102     $bool = load_xs($version);
 103
 104 Attempt to load L<File::KDBX::XS>. Return truthy if C<XS> is loaded. If C<$version> is given, it will check
 105 that at least the given version is loaded.
 106
 107 =cut
 108
 109 my $XS_LOADED;
 110 sub load_xs {
 111     my $version = shift;
 112
 113     goto IS_LOADED if defined $XS_LOADED;
 114
 115     if ($ENV{PERL_ONLY} || (exists $ENV{PERL_FILE_KDBX_XS} && !$ENV{PERL_FILE_KDBX_XS})) {
 116         return $XS_LOADED = FALSE;
 117     }
 118
 119     $XS_LOADED = !!eval { require File::KDBX::XS; 1 };
 120
 121     IS_LOADED:
 122     {
 123         local $@;
 124         return $XS_LOADED if !$version;
 125         return !!eval { File::KDBX::XS->VERSION($version); 1 };
 126     }
 127 }
 128
 129 =func assert
 130
 131     assert { ... };
 132
 133 Write an executable comment. Only executed if C<DEBUG> is set in the environment.
 134
 135 =cut
 136
 137 sub assert(&) { ## no critic (ProhibitSubroutinePrototypes)
 138     return if !DEBUG;
 139     my $code = shift;
 140     return if $code->();
 141
 142     (undef, my $file, my $line) = caller;
 143     $file =~ s!([^/\\]+)$!$1!;
 144     my $assertion = '';
 145     if (try_load_optional('B::Deparse')) {
 146         my $deparse = B::Deparse->new(qw{-P -x9});
 147         $assertion = $deparse->coderef2text($code);
 148         $assertion =~ s/^\{(?:\s*(?:package[^;]+|use[^;]+);)*\s*(.*?);\s*\}$/$1/s;
 149         $assertion =~ s/\s+/ /gs;
 150         $assertion = ": $assertion";
 151     }
 152     die "$0: $file:$line: Assertion failed$assertion\n";
 153 }
 154
 155 =func assert_64bit
 156
 157     assert_64bit();
 158
 159 Throw if perl doesn't support 64-bit IVs.
 160
 161 =cut
 162
 163 sub assert_64bit() {
 164     require Config;
 165     $Config::Config{ivsize} < 8
 166         and throw "64-bit perl is required to use this feature.\n", ivsize => $Config::Config{ivsize};
 167 }
 168
 169 =func can_fork
 170
 171     $bool = can_fork;
 172
 173 Determine if perl can fork, with logic lifted from L<Test2::Util/CAN_FORK>.
 174
 175 =cut
 176
 177 sub can_fork {
 178     require Config;
 179     return 1 if $Config::Config{d_fork};
 180     return 0 if $^O ne 'MSWin32' && $^O ne 'NetWare';
 181     return 0 if !$Config::Config{useithreads};
 182     return 0 if $Config::Config{ccflags} !~ /-DPERL_IMPLICIT_SYS/;
 183     return 0 if $] < 5.008001;
 184     if ($] == 5.010000 && $Config::Config{ccname} eq 'gcc' && $Config::Config{gccversion}) {
 185         return 0 if $Config::Config{gccversion} !~ m/^(\d+)\.(\d+)/;
 186         my @parts = split(/[\.\s]+/, $Config::Config{gccversion});
 187         return 0 if $parts[0] > 4 || ($parts[0] == 4 && $parts[1] >= 8);
 188     }
 189     return 0 if $INC{'Devel/Cover.pm'};
 190     return 1;
 191 }
 192
 193 =func clone
 194
 195     $clone = clone($thing);
 196
 197 Clone deeply. This is an unadorned alias to L<Storable> C<dclone>.
 198
 199 =cut
 200
 201 sub clone {
 202     require Storable;
 203     goto &Storable::dclone;
 204 }
 205
 206 =func clone_nomagic
 207
 208     $clone = clone_nomagic($thing);
 209
 210 Clone deeply without keeping [most of] the magic.
 211
 212 B<WARNING:> At the moment the implementation is naïve and won't respond well to nontrivial data or recursive
 213 structures.
 214
 215 =cut
 216
 217 sub clone_nomagic {
 218     my $thing = shift;
 219     if (is_arrayref($thing)) {
 220         my @arr = map { clone_nomagic($_) } @$thing;
 221         return \@arr;
 222     }
 223     elsif (is_hashref($thing)) {
 224         my %hash;
 225         $hash{$_} = clone_nomagic($thing->{$_}) for keys %$thing;
 226         return \%hash;
 227     }
 228     elsif (is_ref($thing)) {
 229         return clone($thing);
 230     }
 231     return $thing;
 232 }
 233
 234 =func dumper
 235
 236     $str = dumper $thing;
 237     dumper $thing;  # in void context, prints to STDERR
 238
 239 Like L<Data::Dumper> but slightly terser in some cases relevent to L<File::KDBX>.
 240
 241 =cut
 242
 243 sub dumper {
 244     require Data::Dumper;
 245     # avoid "once" warnings
 246     local $Data::Dumper::Deepcopy = $Data::Dumper::Deepcopy = 1;
 247     local $Data::Dumper::Deparse = $Data::Dumper::Deparse = 1;
 248     local $Data::Dumper::Indent = 1;
 249     local $Data::Dumper::Quotekeys = 0;
 250     local $Data::Dumper::Sortkeys = 1;
 251     local $Data::Dumper::Terse = 1;
 252     local $Data::Dumper::Trailingcomma = 1;
 253     local $Data::Dumper::Useqq = 1;
 254
 255     my @dumps;
 256     for my $struct (@_) {
 257         my $str = Data::Dumper::Dumper($struct);
 258
 259         # boolean
 260         $str =~ s/bless\( do\{\\\(my \$o = ([01])\)\}, 'boolean' \)/boolean($1)/gs;
 261         # Time::Piece
 262         $str =~ s/bless\([^\)]+?(\d+)'?,\s+\d+,?\s+\], 'Time::Piece' \),/
 263             "scalar gmtime($1), # " . scalar gmtime($1)->datetime/ges;
 264
 265         print STDERR $str if !defined wantarray;
 266         push @dumps, $str;
 267         return $str;
 268     }
 269     return join("\n", @dumps);
 270 }
 271
 272 =func empty
 273
 274 =func nonempty
 275
 276     $bool = empty $thing;
 277
 278     $bool = nonempty $thing;
 279
 280 Test whether a thing is empty (or nonempty). An empty thing is one of these:
 281
 282 =for :list
 283 * nonexistent
 284 * C<undef>
 285 * zero-length string
 286 * zero-length array
 287 * hash with zero keys
 288 * reference to an empty thing (recursive)
 289
 290 Note in particular that zero C<0> is not considered empty because it is an actual value.
 291
 292 =cut
 293
 294 sub empty    {  _empty(@_) }
 295 sub nonempty { !_empty(@_) }
 296
 297 sub _empty {
 298     return 1 if @_ == 0;
 299     local $_ = shift;
 300     return !defined $_
 301         || $_ eq ''
 302         || (is_arrayref($_)  && @$_ == 0)
 303         || (is_hashref($_)   && keys %$_ == 0)
 304         || (is_scalarref($_) && (!defined $$_ || $$_ eq ''))
 305         || (is_refref($_)    && _empty($$_));
 306 }
 307
 308 =func erase
 309
 310     erase($string, ...);
 311     erase(\$string, ...);
 312
 313 Overwrite the memory used by one or more string.
 314
 315 =cut
 316
 317 BEGIN {
 318     if (load_xs) {
 319         *_CowREFCNT = \&File::KDBX::XS::CowREFCNT;
 320     }
 321     elsif (eval { require B::COW; 1 }) {
 322         *_CowREFCNT = \&B::COW::cowrefcnt;
 323     }
 324     else {
 325         *_CowREFCNT = sub { undef };
 326     }
 327 }
 328
 329 sub erase {
 330     # Only bother zeroing out memory if we have the last SvPV COW reference, otherwise we'll end up just
 331     # creating a copy and erasing the copy.
 332     # TODO - Is this worth doing? Need some benchmarking.
 333     for (@_) {
 334         if (!is_ref($_)) {
 335             next if !defined $_ || readonly $_;
 336             my $cowrefcnt = _CowREFCNT($_);
 337             goto FREE_NONREF if defined $cowrefcnt && 1 < $cowrefcnt;
 338             # if (__PACKAGE__->can('erase_xs')) {
 339             #     erase_xs($_);
 340             # }
 341             # else {
 342                 substr($_, 0, length($_), "\0" x length($_));
 343             # }
 344             FREE_NONREF: {
 345                 no warnings 'uninitialized';
 346                 undef $_;
 347             }
 348         }
 349         elsif (is_scalarref($_)) {
 350             next if !defined $$_ || readonly $$_;
 351             my $cowrefcnt = _CowREFCNT($$_);
 352             goto FREE_REF if defined $cowrefcnt && 1 < $cowrefcnt;
 353             # if (__PACKAGE__->can('erase_xs')) {
 354             #     erase_xs($$_);
 355             # }
 356             # else {
 357                 substr($$_, 0, length($$_), "\0" x length($$_));
 358             # }
 359             FREE_REF: {
 360                 no warnings 'uninitialized';
 361                 undef $$_;
 362             }
 363         }
 364         elsif (is_arrayref($_)) {
 365             erase(@$_);
 366             @$_ = ();
 367         }
 368         elsif (is_hashref($_)) {
 369             erase(values %$_);
 370             %$_ = ();
 371         }
 372         else {
 373             throw 'Cannot erase this type of scalar', type => ref $_, what => $_;
 374         }
 375     }
 376 }
 377
 378 =func erase_scoped
 379
 380     $scope_guard = erase_scoped($string, ...);
 381     $scope_guard = erase_scoped(\$string, ...);
 382     undef $scope_guard; # erase happens here
 383
 384 Get a scope guard that will cause scalars to be erased later (i.e. when the scope ends). This is useful if you
 385 want to make sure a string gets erased after you're done with it, even if the scope ends abnormally.
 386
 387 See L</erase>.
 388
 389 =cut
 390
 391 sub erase_scoped {
 392     throw 'Programmer error: Cannot call erase_scoped in void context' if !defined wantarray;
 393     my @args;
 394     for (@_) {
 395         !is_ref($_) || is_arrayref($_) || is_hashref($_) || is_scalarref($_)
 396             or throw 'Cannot erase this type of scalar', type => ref $_, what => $_;
 397         push @args, is_ref($_) ? $_ : \$_;
 398     }
 399     require Scope::Guard;
 400     return Scope::Guard->new(sub { erase(@args) });
 401 }
 402
 403 =func extends
 404
 405     extends $class;
 406
 407 Set up the current module to inheret from another module.
 408
 409 =cut
 410
 411 sub extends {
 412     my $parent  = shift;
 413     my $caller  = caller;
 414     # load $parent;
 415     eval qq[require $parent];
 416     no strict 'refs'; ## no critic (ProhibitNoStrict)
 417     @{"${caller}::ISA"} = $parent;
 418 }
 419
 420 =func has
 421
 422     has $name => %options;
 423
 424 Create an attribute getter/setter. Possible options:
 425
 426 =for :list
 427 * C<is> - Either "rw" (default) or "ro"
 428 * C<default> - Default value
 429 * C<coerce> - Coercive function
 430
 431 =cut
 432
 433 sub has {
 434     my $name = shift;
 435     my %args = @_ % 2 == 1 ? (default => shift, @_) : @_;
 436
 437     my ($package, $file, $line) = caller;
 438
 439     my $d = $args{default};
 440     my $default = is_arrayref($d) ? sub { [@$d] } : is_hashref($d) ? sub { +{%$d} } : $d;
 441     my $coerce  = $args{coerce};
 442     my $is      = $args{is} || 'rw';
 443
 444     my $store = $args{store};
 445     ($store, $name) = split(/\./, $name, 2) if $name =~ /\./;
 446     push @{$ATTRIBUTES{$package} //= []}, $name;
 447
 448     my $store_code = '';
 449     $store_code = qq{->$store} if $store;
 450     my $member = qq{\$_[0]$store_code\->{'$name'}};
 451
 452     my $default_code = is_coderef $default ? q{scalar $default->($_[0])}
 453                         : defined $default ? q{$default}
 454                                            : q{undef};
 455     my $get = qq{$member //= $default_code;};
 456
 457     my $set = '';
 458     if ($is eq 'rw') {
 459         $set = is_coderef $coerce ? qq{$member = scalar \$coerce->(\@_[1..\$#_]) if \$#_;}
 460                 : defined $coerce ? qq{$member = do { local @_ = (\@_[1..\$#_]); $coerce } if \$#_;}
 461                                   : qq{$member = \$_[1] if \$#_;};
 462     }
 463
 464     $line -= 4;
 465     my $code = <<END;
 466 # line $line "$file"
 467 sub ${package}::${name} {
 468     return $default_code if !Scalar::Util::blessed(\$_[0]);
 469     $set
 470     $get
 471 }
 472 END
 473     eval $code; ## no critic (ProhibitStringyEval)
 474 }
 475
 476 =func format_uuid
 477
 478     $string_uuid = format_uuid($raw_uuid);
 479     $string_uuid = format_uuid($raw_uuid, $delimiter);
 480
 481 Format a 128-bit UUID (given as a string of 16 octets) into a hexidecimal string, optionally with a delimiter
 482 to break up the UUID visually into five parts. Examples:
 483
 484     my $uuid = uuid('01234567-89AB-CDEF-0123-456789ABCDEF');
 485     say format_uuid($uuid);         # -> 0123456789ABCDEF0123456789ABCDEF
 486     say format_uuid($uuid, '-');    # -> 01234567-89AB-CDEF-0123-456789ABCDEF
 487
 488 This is the inverse of L</uuid>.
 489
 490 =cut
 491
 492 sub format_uuid {
 493     local $_    = shift // "\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0";
 494     my $delim   = shift // '';
 495     length($_) == 16 or throw 'Must provide a 16-bytes UUID', size => length($_), str => $_;
 496     return uc(join($delim, unpack('H8 H4 H4 H4 H12', $_)));
 497 }
 498
 499 =func generate_uuid
 500
 501     $uuid = generate_uuid;
 502     $uuid = generate_uuid(\%set);
 503     $uuid = generate_uuid(\&test_uuid);
 504
 505 Generate a new random UUID. It's pretty unlikely that this will generate a repeat, but if you're worried about
 506 that you can provide either a set of existing UUIDs (as a hashref where the keys are the elements of a set) or
 507 a function to check for existing UUIDs, and this will be sure to not return a UUID already in provided set.
 508 Perhaps an example will make it clear:
 509
 510     my %uuid_set = (
 511         uuid('12345678-9ABC-DEFG-1234-56789ABCDEFG') => 'whatever',
 512     );
 513     $uuid = generate_uuid(\%uuid_set);
 514     # OR
 515     $uuid = generate_uuid(sub { !$uuid_set{$_} });
 516
 517 Here, C<$uuid> can't be "12345678-9ABC-DEFG-1234-56789ABCDEFG". This example uses L</uuid> to easily pack
 518 a 16-byte UUID from a literal, but it otherwise is not a consequential part of the example.
 519
 520 =cut
 521
 522 sub generate_uuid {
 523     my $set  = @_ % 2 == 1 ? shift : undef;
 524     my %args = @_;
 525     my $test = $set //= $args{test};
 526     $test   = sub { !$set->{$_} } if is_hashref($test);
 527     $test //= sub { 1 };
 528     my $printable = $args{printable} // $args{print};
 529     local $_ = '';
 530     do {
 531         $_ = $printable ? random_string(16) : random_bytes(16);
 532     } while (!$test->($_));
 533     return $_;
 534 }
 535
 536 =func gunzip
 537
 538     $unzipped = gunzip($string);
 539
 540 Decompress an octet stream.
 541
 542 =cut
 543
 544 sub gunzip {
 545     load_optional('Compress::Raw::Zlib');
 546     local $_ = shift;
 547     my ($i, $status) = Compress::Raw::Zlib::Inflate->new(-WindowBits => 31);
 548     $status == Compress::Raw::Zlib::Z_OK()
 549         or throw 'Failed to initialize compression library', status => $status;
 550     $status = $i->inflate($_, my $out);
 551     $status == Compress::Raw::Zlib::Z_STREAM_END()
 552         or throw 'Failed to decompress data', status => $status;
 553     return $out;
 554 }
 555
 556 =func gzip
 557
 558     $zipped = gzip($string);
 559
 560 Compress an octet stream.
 561
 562 =cut
 563
 564 sub gzip {
 565     load_optional('Compress::Raw::Zlib');
 566     local $_ = shift;
 567     my ($d, $status) = Compress::Raw::Zlib::Deflate->new(-WindowBits => 31, -AppendOutput => 1);
 568     $status == Compress::Raw::Zlib::Z_OK()
 569         or throw 'Failed to initialize compression library', status => $status;
 570     $status = $d->deflate($_, my $out);
 571     $status == Compress::Raw::Zlib::Z_OK()
 572         or throw 'Failed to compress data', status => $status;
 573     $status = $d->flush($out);
 574     $status == Compress::Raw::Zlib::Z_OK()
 575         or throw 'Failed to compress data', status => $status;
 576     return $out;
 577 }
 578
 579 =func is_readable
 580
 581 =func is_writable
 582
 583     $bool = is_readable($mode);
 584     $bool = is_writable($mode);
 585
 586 Determine of an C<fopen>-style mode is readable, writable or both.
 587
 588 =cut
 589
 590 sub is_readable { $_[0] !~ /^[aw]b?$/ }
 591 sub is_writable { $_[0] !~ /^rb?$/ }
 592
 593 =func is_uuid
 594
 595     $bool = is_uuid($thing);
 596
 597 Check if a thing is a UUID (i.e. scalar string of length 16).
 598
 599 =cut
 600
 601 sub is_uuid { defined $_[0] && !is_ref($_[0]) && length($_[0]) == 16 }
 602
 603 =func list_attributes
 604
 605     @attributes = list_attributes($package);
 606
 607 Get a list of attributes for a class.
 608
 609 =cut
 610
 611 sub list_attributes {
 612     my $package = shift;
 613     return @{$ATTRIBUTES{$package} // []};
 614 }
 615
 616 =func load_optional
 617
 618     $package = load_optional($package);
 619
 620 Load a module that isn't required but can provide extra functionality. Throw if the module is not available.
 621
 622 =cut
 623
 624 sub load_optional {
 625     for my $module (@_) {
 626         eval { load $module };
 627         if (my $err = $@) {
 628             throw "Missing dependency: Please install $module to use this feature.\n",
 629                 module  => $module,
 630                 error   => $err;
 631         }
 632     }
 633     return wantarray ? @_ : $_[0];
 634 }
 635
 636 =func memoize
 637
 638     \&memoized_code = memoize(\&code, ...);
 639
 640 Memoize a function. Extra arguments are passed through to C<&code> when it is called.
 641
 642 =cut
 643
 644 sub memoize {
 645     my $func = shift;
 646     my @args = @_;
 647     my %cache;
 648     return sub { $cache{join("\0", grep { defined } @_)} //= $func->(@args, @_) };
 649 }
 650
 651 =func pad_pkcs7
 652
 653     $padded_string = pad_pkcs7($string, $block_size),
 654
 655 Pad a block using the PKCS#7 method.
 656
 657 =cut
 658
 659 sub pad_pkcs7 {
 660     my $data = shift // throw 'Must provide a string to pad';
 661     my $size = shift or throw 'Must provide block size';
 662
 663     0 <= $size && $size < 256
 664         or throw 'Cannot add PKCS7 padding to a large block size', size => $size;
 665
 666     my $pad_len = $size - length($data) % $size;
 667     $data .= chr($pad_len) x $pad_len;
 668 }
 669
 670 =func query
 671
 672     $query = query(@where);
 673     $query->(\%data);
 674
 675 Generate a function that will run a series of tests on a passed hashref and return true or false depending on
 676 if the data record in the hash matched the specified logic.
 677
 678 The logic can be specified in a manner similar to L<SQL::Abstract/"WHERE CLAUSES"> which was the inspiration
 679 for this function, but this code is distinct, supporting an overlapping but not identical feature set and
 680 having its own bugs.
 681
 682 See L<File::KDBX/QUERY> for examples.
 683
 684 =cut
 685
 686 sub query { _query(undef, '-or', \@_) }
 687
 688 =func read_all
 689
 690     $size = read_all($fh, my $buffer, $size);
 691     $size = read_all($fh, my $buffer, $size, $offset);
 692
 693 Like L<functions/read> but returns C<undef> if not all C<$size> bytes are read. This is considered an error,
 694 distinguishable from other errors by C<$!> not being set.
 695
 696 =cut
 697
 698 sub read_all($$$;$) { ## no critic (ProhibitSubroutinePrototypes)
 699     my $result = @_ == 3 ? read($_[0], $_[1], $_[2])
 700                          : read($_[0], $_[1], $_[2], $_[3]);
 701     return if !defined $result;
 702     return if $result != $_[2];
 703     return $result;
 704 }
 705
 706 =func recurse_limit
 707
 708     \&limited_code = recurse_limit(\&code);
 709     \&limited_code = recurse_limit(\&code, $max_depth);
 710     \&limited_code = recurse_limit(\&code, $max_depth, \&error_handler);
 711
 712 Wrap a function with a guard to prevent deep recursion.
 713
 714 =cut
 715
 716 sub recurse_limit {
 717     my $func        = shift;
 718     my $max_depth   = shift // 200;
 719     my $error       = shift // sub {};
 720     my $depth = 0;
 721     return sub { return $error->(@_) if $max_depth < ++$depth; $func->(@_) };
 722 };
 723
 724 =func search
 725
 726     # Generate a query on-the-fly:
 727     \@matches = search(\@records, @where);
 728
 729     # Use a pre-compiled query:
 730     $query = query(@where);
 731     \@matches = search(\@records, $query);
 732
 733     # Use a simple expression:
 734     \@matches = search(\@records, \'query terms', @fields);
 735     \@matches = search(\@records, \'query terms', $operator, @fields);
 736
 737     # Use your own subroutine:
 738     \@matches = search(\@records, \&query);
 739     \@matches = search(\@records, sub { $record = shift; ... });
 740
 741 Execute a linear search over an array of records using a L</query>. A "record" is usually a hash.
 742
 743 This is the search engine described with many examples at L<File::KDBX/QUERY>.
 744
 745 =cut
 746
 747 sub search {
 748     my $list    = shift;
 749     my $query   = shift;
 750
 751     if (is_coderef($query) && !@_) {
 752         # already a query
 753     }
 754     elsif (is_scalarref($query)) {
 755         $query = simple_expression_query($$query, @_);
 756     }
 757     else {
 758         $query = query($query, @_);
 759     }
 760
 761     my @match;
 762     for my $item (@$list) {
 763         push @match, $item if $query->($item);
 764     }
 765     return \@match;
 766 }
 767
 768 =func simple_expression_query
 769
 770     $query = simple_expression_query($expression, @fields);
 771     $query = simple_expression_query($expression, $operator, @fields);
 772
 773 Generate a query, like L</query>, to be used with L</search> but built from a "simple expression" as
 774 L<described here|https://keepass.info/help/base/search.html#mode_se>.
 775
 776 An expression is a string with one or more space-separated terms. Terms with spaces can be enclosed in double
 777 quotes. Terms are negated if they are prefixed with a minus sign. A record must match every term on at least
 778 one of the given fields.
 779
 780 =cut
 781
 782 sub simple_expression_query {
 783     my $expr = shift;
 784     my $op   = @_ && ($OPS{$_[0] || ''} || 0) == 2 ? shift : '=~';
 785
 786     my $neg_op = $OP_NEG{$op};
 787     my $is_re  = $op eq '=~' || $op eq '!~';
 788
 789     require Text::ParseWords;
 790     my @terms = Text::ParseWords::shellwords($expr);
 791
 792     my @query = qw(-and);
 793
 794     for my $term (@terms) {
 795         my @subquery = qw(-or);
 796
 797         my $neg = $term =~ s/^-//;
 798         my $condition = [($neg ? $neg_op : $op) => ($is_re ? qr/\Q$term\E/i : $term)];
 799
 800         for my $field (@_) {
 801             push @subquery, $field => $condition;
 802         }
 803
 804         push @query, \@subquery;
 805     }
 806
 807     return query(\@query);
 808 }
 809
 810 =func snakify
 811
 812     $string = snakify($string);
 813
 814 Turn a CamelCase string into snake_case.
 815
 816 =cut
 817
 818 sub snakify {
 819     local $_ = shift;
 820     s/UserName/Username/g;
 821     s/([a-z])([A-Z0-9])/${1}_${2}/g;
 822     s/([A-Z0-9]+)([A-Z0-9])(?![A-Z0-9]|$)/${1}_${2}/g;
 823     return lc($_);
 824 }
 825
 826 =func split_url
 827
 828     ($scheme, $auth, $host, $port, $path, $query, $hash, $usename, $password) = split_url($url);
 829
 830 Split a URL into its parts.
 831
 832 For example, C<http://user:pass@localhost:4000/path?query#hash> gets split like:
 833
 834 =for :list
 835 * C<http>
 836 * C<user:pass>
 837 * C<host>
 838 * C<4000>
 839 * C</path>
 840 * C<?query>
 841 * C<#hash>
 842 * C<user>
 843 * C<pass>
 844
 845 =cut
 846
 847 sub split_url {
 848     local $_ = shift;
 849     my ($scheme, $auth, $host, $port, $path, $query, $hash) =~ m!
 850         ^([^:/\?\#]+) ://
 851         (?:([^\@]+)\@)
 852         ([^:/\?\#]*)
 853         (?::(\d+))?
 854         ([^\?\#]*)
 855         (\?[^\#]*)?
 856         (\#(.*))?
 857     !x;
 858
 859     $scheme = lc($scheme);
 860
 861     $host ||= 'localhost';
 862     $host = lc($host);
 863
 864     $path = "/$path" if $path !~ m!^/!;
 865
 866     $port ||= $scheme eq 'http' ? 80 : $scheme eq 'https' ? 433 : undef;
 867
 868     my ($username, $password) = split($auth, ':', 2);
 869
 870     return ($scheme, $auth, $host, $port, $path, $query, $hash, $username, $password);
 871 }
 872
 873 =func to_bool
 874
 875 =func to_number
 876
 877 =func to_string
 878
 879 =func to_time
 880
 881 =func to_tristate
 882
 883 =func to_uuid
 884
 885 Various typecasting / coercive functions.
 886
 887 =cut
 888
 889 sub to_bool   { $_[0] // return; boolean($_[0]) }
 890 sub to_number { $_[0] // return; 0+$_[0] }
 891 sub to_string { $_[0] // return; "$_[0]" }
 892 sub to_time   {
 893     $_[0] // return;
 894     return gmtime($_[0]) if looks_like_number($_[0]);
 895     return Time::Piece->strptime($_[0], '%Y-%m-%d %H:%M:%S') if !blessed $_[0];
 896     return $_[0];
 897 }
 898 sub to_tristate { $_[0] // return; boolean($_[0]) }
 899 sub to_uuid {
 900     my $str = to_string(@_) // return;
 901     return sprintf('%016s', $str) if length($str) < 16;
 902     return substr($str, 0, 16) if 16 < length($str);
 903     return $str;
 904 }
 905
 906 =func trim
 907
 908     $string = trim($string);
 909
 910 The ubiquitous C<trim> function. Removes all whitespace from both ends of a string.
 911
 912 =cut
 913
 914 sub trim($) { ## no critic (ProhibitSubroutinePrototypes)
 915     local $_ = shift // return;
 916     s/^\s*//;
 917     s/\s*$//;
 918     return $_;
 919 }
 920
 921 =func try_load_optional
 922
 923     $package = try_load_optional($package);
 924
 925 Try to load a module that isn't required but can provide extra functionality, and return true if successful.
 926
 927 =cut
 928
 929 sub try_load_optional {
 930     for my $module (@_) {
 931         eval { load $module };
 932         if (my $err = $@) {
 933             warn $err if 3 <= DEBUG;
 934             return;
 935         }
 936     }
 937     return @_;
 938 }
 939
 940 =func uri_escape_utf8
 941
 942     $string = uri_escape_utf8($string);
 943
 944 Percent-encode arbitrary text strings, like for a URI.
 945
 946 =cut
 947
 948 my %ESC = map { chr($_) => sprintf('%%%02X', $_) } 0..255;
 949 sub uri_escape_utf8 {
 950     local $_ = shift // return;
 951     $_ = encode('UTF-8', $_);
 952     # RFC 3986 section 2.3 unreserved characters
 953     s/([^A-Za-z0-9\-\._~])/$ESC{$1}/ge;
 954     return $_;
 955 }
 956
 957 =func uri_unescape_utf8
 958
 959     $string = uri_unescape_utf8($string);
 960
 961 Inverse of L</uri_escape_utf8>.
 962
 963 =cut
 964
 965 sub uri_unescape_utf8 {
 966     local $_ = shift // return;
 967     s/\%([A-Fa-f0-9]{2})/chr(hex($1))/;
 968     return decode('UTF-8', $_);
 969 }
 970
 971 =func uuid
 972
 973     $raw_uuid = uuid($string_uuid);
 974
 975 Pack a 128-bit UUID (given as a hexidecimal string with optional C<->'s, like
 976 C<12345678-9ABC-DEFG-1234-56789ABCDEFG>) into a string of exactly 16 octets.
 977
 978 This is the inverse of L</format_uuid>.
 979
 980 =cut
 981
 982 sub uuid {
 983     local $_ = shift // return "\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0";
 984     s/-//g;
 985     /^[A-Fa-f0-9]{32}$/ or throw 'Must provide a formatted 128-bit UUID';
 986     return pack('H32', $_);
 987
 988 }
 989
 990 =func UUID_NULL
 991
 992 Get the null UUID (i.e. string of 16 null bytes).
 993
 994 =cut
 995
 996 sub UUID_NULL() { "\0" x 16 }
 997
 998 ### --------------------------------------------------------------------------
 999
1000 # Determine if an array looks like keypairs from a hash.
1001 sub _looks_like_keypairs {
1002     my $arr = shift;
1003     return 0 if @$arr % 2 == 1;
1004     for (my $i = 0; $i < @$arr; $i += 2) {
1005         return 0 if is_ref($arr->[$i]);
1006     }
1007     return 1;
1008 }
1009
1010 sub _is_operand_plain {
1011     local $_ = shift;
1012     return !(is_hashref($_) || is_arrayref($_));
1013 }
1014
1015 sub _query {
1016     # dumper \@_;
1017     my $subject = shift;
1018     my $op      = shift // throw 'Must specify a query operator';
1019     my $operand = shift;
1020
1021     return _query_simple($op, $subject) if defined $subject && !is_ref($op) && ($OPS{$subject} || 2) < 2;
1022     return _query_simple($subject, $op, $operand) if _is_operand_plain($operand);
1023     return _query_inverse(_query($subject, '-or', $operand)) if $op eq '-not' || $op eq '-false';
1024     return _query($subject, '-and', [%$operand]) if is_hashref($operand);
1025
1026     my @queries;
1027
1028     my @atoms = @$operand;
1029     while (@atoms) {
1030         if (_looks_like_keypairs(\@atoms)) {
1031             my ($atom, $operand) = splice @atoms, 0, 2;
1032             if (my $op_type = $OPS{$atom}) {
1033                 if ($op_type == 1 && _is_operand_plain($operand)) { # unary
1034                     push @queries, _query_simple($operand, $atom);
1035                 }
1036                 else {
1037                     push @queries, _query($subject, $atom, $operand);
1038                 }
1039             }
1040             elsif (!is_ref($atom)) {
1041                 push @queries, _query($atom, 'eq', $operand);
1042             }
1043         }
1044         else {
1045             my $atom = shift @atoms;
1046             if ($OPS{$atom}) {     # apply new operator over the rest
1047                 push @queries, _query($subject, $atom, \@atoms);
1048                 last;
1049             }
1050             else {  # apply original operator over this one
1051                 push @queries, _query($subject, $op, $atom);
1052             }
1053         }
1054     }
1055
1056     if (@queries == 1) {
1057         return $queries[0];
1058     }
1059     elsif ($op eq '-and') {
1060         return _query_all(@queries);
1061     }
1062     elsif ($op eq '-or') {
1063         return _query_any(@queries);
1064     }
1065     throw 'Malformed query';
1066 }
1067
1068 sub _query_simple {
1069     my $subject = shift;
1070     my $op      = shift // 'eq';
1071     my $operand = shift;
1072
1073     # these special operators can also act as simple operators
1074     $op = '!!' if $op eq '-true';
1075     $op = '!'  if $op eq '-false';
1076     $op = '!'  if $op eq '-not';
1077
1078     defined $subject or throw 'Subject is not set in query';
1079     $OPS{$op} >= 0   or throw 'Cannot use a non-simple operator in a simple query';
1080     if (empty($operand)) {
1081         if ($OPS{$op} < 2) {
1082             # no operand needed
1083         }
1084         # Allow field => undef and field => {'ne' => undef} to do the (arguably) right thing.
1085         elsif ($op eq 'eq' || $op eq '==') {
1086             $op = '-empty';
1087         }
1088         elsif ($op eq 'ne' || $op eq '!=') {
1089             $op = '-nonempty';
1090         }
1091         else {
1092             throw 'Operand is required';
1093         }
1094     }
1095
1096     my $field = sub { blessed $_[0] && $_[0]->can($subject) ? $_[0]->$subject : $_[0]->{$subject} };
1097
1098     my %map = (
1099         'eq'        => sub { local $_ = $field->(@_); defined && $_ eq $operand },
1100         'ne'        => sub { local $_ = $field->(@_); defined && $_ ne $operand },
1101         'lt'        => sub { local $_ = $field->(@_); defined && $_ lt $operand },
1102         'gt'        => sub { local $_ = $field->(@_); defined && $_ gt $operand },
1103         'le'        => sub { local $_ = $field->(@_); defined && $_ le $operand },
1104         'ge'        => sub { local $_ = $field->(@_); defined && $_ ge $operand },
1105         '=='        => sub { local $_ = $field->(@_); defined && $_ == $operand },
1106         '!='        => sub { local $_ = $field->(@_); defined && $_ != $operand },
1107         '<'         => sub { local $_ = $field->(@_); defined && $_ <  $operand },
1108         '>'         => sub { local $_ = $field->(@_); defined && $_ >  $operand },
1109         '<='        => sub { local $_ = $field->(@_); defined && $_ <= $operand },
1110         '>='        => sub { local $_ = $field->(@_); defined && $_ >= $operand },
1111         '=~'        => sub { local $_ = $field->(@_); defined && $_ =~ $operand },
1112         '!~'        => sub { local $_ = $field->(@_); defined && $_ !~ $operand },
1113         '!'         => sub { local $_ = $field->(@_); ! $_ },
1114         '!!'        => sub { local $_ = $field->(@_); !!$_ },
1115         '-defined'  => sub { local $_ = $field->(@_);  defined $_ },
1116         '-undef'    => sub { local $_ = $field->(@_); !defined $_ },
1117         '-nonempty' => sub { local $_ = $field->(@_); nonempty $_ },
1118         '-empty'    => sub { local $_ = $field->(@_); empty    $_ },
1119     );
1120
1121     return $map{$op} // throw "Unexpected operator in query: $op",
1122         subject     => $subject,
1123         operator    => $op,
1124         operand     => $operand;
1125 }
1126
1127 sub _query_inverse {
1128     my $query = shift;
1129     return sub { !$query->(@_) };
1130 }
1131
1132 sub _query_all {
1133     my @queries = @_;
1134     return sub {
1135         my $val = shift;
1136         all { $_->($val) } @queries;
1137     };
1138 }
1139
1140 sub _query_any {
1141     my @queries = @_;
1142     return sub {
1143         my $val = shift;
1144         any { $_->($val) } @queries;
1145     };
1146 }
1147
1148 1;