Dogcows Code - chaz/p5-File-KDBX/blob - lib/File/KDBX/Util.pm

   1 package File::KDBX::Util;
   2 # ABSTRACT: Utility functions for working with KDBX files
   3
   4 use warnings;
   5 use strict;
   6
   7 use Crypt::PRNG qw(random_bytes random_string);
   8 use Encode qw(decode encode);
   9 use Exporter qw(import);
  10 use File::KDBX::Constants qw(:bool);
  11 use File::KDBX::Error;
  12 use List::Util 1.33 qw(any all);
  13 use Module::Load;
  14 use Ref::Util qw(is_arrayref is_coderef is_hashref is_ref is_refref is_scalarref);
  15 use Scalar::Util qw(blessed looks_like_number readonly);
  16 use Time::Piece;
  17 use boolean;
  18 use namespace::clean -except => 'import';
  19
  20 our $VERSION = '999.999'; # VERSION
  21
  22 our %EXPORT_TAGS = (
  23     assert      => [qw(DEBUG assert assert_64bit)],
  24     class       => [qw(extends has list_attributes)],
  25     clone       => [qw(clone clone_nomagic)],
  26     coercion    => [qw(to_bool to_number to_string to_time to_tristate to_uuid)],
  27     crypt       => [qw(pad_pkcs7)],
  28     debug       => [qw(DEBUG dumper)],
  29     fork        => [qw(can_fork)],
  30     function    => [qw(memoize recurse_limit)],
  31     empty       => [qw(empty nonempty)],
  32     erase       => [qw(erase erase_scoped)],
  33     gzip        => [qw(gzip gunzip)],
  34     io          => [qw(is_readable is_writable read_all)],
  35     load        => [qw(load_optional load_xs try_load_optional)],
  36     search      => [qw(query search simple_expression_query)],
  37     text        => [qw(snakify trim)],
  38     uuid        => [qw(format_uuid generate_uuid is_uuid uuid UUID_NULL)],
  39     uri         => [qw(split_url uri_escape_utf8 uri_unescape_utf8)],
  40 );
  41
  42 $EXPORT_TAGS{all} = [map { @$_ } values %EXPORT_TAGS];
  43 our @EXPORT_OK = @{$EXPORT_TAGS{all}};
  44
  45 BEGIN {
  46     my $debug = $ENV{DEBUG};
  47     $debug = looks_like_number($debug) ? (0 + $debug) : ($debug ? 1 : 0);
  48     *DEBUG = $debug == 1 ? sub() { 1 } :
  49              $debug == 2 ? sub() { 2 } :
  50              $debug == 3 ? sub() { 3 } :
  51              $debug == 4 ? sub() { 4 } : sub() { 0 };
  52 }
  53
  54 my %OPS = (
  55     'eq'        =>  2, # binary
  56     'ne'        =>  2,
  57     'lt'        =>  2,
  58     'gt'        =>  2,
  59     'le'        =>  2,
  60     'ge'        =>  2,
  61     '=='        =>  2,
  62     '!='        =>  2,
  63     '<'         =>  2,
  64     '>'         =>  2,
  65     '<='        =>  2,
  66     '>='        =>  2,
  67     '=~'        =>  2,
  68     '!~'        =>  2,
  69     '!'         =>  1, # unary
  70     '!!'        =>  1,
  71     '-not'      =>  1, # special
  72     '-false'    =>  1,
  73     '-true'     =>  1,
  74     '-defined'  =>  1,
  75     '-undef'    =>  1,
  76     '-empty'    =>  1,
  77     '-nonempty' =>  1,
  78     '-or'       => -1,
  79     '-and'      => -1,
  80 );
  81 my %OP_NEG = (
  82     'eq'    =>  'ne',
  83     'ne'    =>  'eq',
  84     'lt'    =>  'ge',
  85     'gt'    =>  'le',
  86     'le'    =>  'gt',
  87     'ge'    =>  'lt',
  88     '=='    =>  '!=',
  89     '!='    =>  '==',
  90     '<'     =>  '>=',
  91     '>'     =>  '<=',
  92     '<='    =>  '>',
  93     '>='    =>  '<',
  94     '=~'    =>  '!~',
  95     '!~'    =>  '=~',
  96 );
  97 my %ATTRIBUTES;
  98
  99 =func load_xs
 100
 101     $bool = load_xs();
 102     $bool = load_xs($version);
 103
 104 Attempt to load L<File::KDBX::XS>. Return truthy if C<XS> is loaded. If C<$version> is given, it will check
 105 that at least the given version is loaded.
 106
 107 =cut
 108
 109 my $XS_LOADED;
 110 sub load_xs {
 111     my $version = shift;
 112
 113     goto IS_LOADED if defined $XS_LOADED;
 114
 115     if ($ENV{PERL_ONLY} || (exists $ENV{PERL_FILE_KDBX_XS} && !$ENV{PERL_FILE_KDBX_XS})) {
 116         return $XS_LOADED = FALSE;
 117     }
 118
 119     $XS_LOADED = !!eval { require File::KDBX::XS; 1 };
 120
 121     IS_LOADED:
 122     {
 123         local $@;
 124         return $XS_LOADED if !$version;
 125         return !!eval { File::KDBX::XS->VERSION($version); 1 };
 126     }
 127 }
 128
 129 =func assert
 130
 131     assert { ... };
 132
 133 Write an executable comment. Only executed if C<DEBUG> is set in the environment.
 134
 135 =cut
 136
 137 sub assert(&) { ## no critic (ProhibitSubroutinePrototypes)
 138     return if !DEBUG;
 139     my $code = shift;
 140     return if $code->();
 141
 142     (undef, my $file, my $line) = caller;
 143     $file =~ s!([^/\\]+)$!$1!;
 144     my $assertion = '';
 145     if (try_load_optional('B::Deparse')) {
 146         my $deparse = B::Deparse->new(qw{-P -x9});
 147         $assertion = $deparse->coderef2text($code);
 148         $assertion =~ s/^\{(?:\s*(?:package[^;]+|use[^;]+);)*\s*(.*?);\s*\}$/$1/s;
 149         $assertion =~ s/\s+/ /gs;
 150         $assertion = ": $assertion";
 151     }
 152     die "$0: $file:$line: Assertion failed$assertion\n";
 153 }
 154
 155 =func assert_64bit
 156
 157     assert_64bit();
 158
 159 Throw if perl doesn't support 64-bit IVs.
 160
 161 =cut
 162
 163 sub assert_64bit() {
 164     require Config;
 165     $Config::Config{ivsize} < 8
 166         and throw "64-bit perl is required to use this feature.\n", ivsize => $Config::Config{ivsize};
 167 }
 168
 169 =func can_fork
 170
 171     $bool = can_fork;
 172
 173 Determine if perl can fork, with logic lifted from L<Test2::Util/CAN_FORK>.
 174
 175 =cut
 176
 177 sub can_fork {
 178     require Config;
 179     return 1 if $Config::Config{d_fork};
 180     return 0 if $^O ne 'MSWin32' && $^O ne 'NetWare';
 181     return 0 if !$Config::Config{useithreads};
 182     return 0 if $Config::Config{ccflags} !~ /-DPERL_IMPLICIT_SYS/;
 183     return 0 if $] < 5.008001;
 184     if ($] == 5.010000 && $Config::Config{ccname} eq 'gcc' && $Config::Config{gccversion}) {
 185         return 0 if $Config::Config{gccversion} !~ m/^(\d+)\.(\d+)/;
 186         my @parts = split(/[\.\s]+/, $Config::Config{gccversion});
 187         return 0 if $parts[0] > 4 || ($parts[0] == 4 && $parts[1] >= 8);
 188     }
 189     return 0 if $INC{'Devel/Cover.pm'};
 190     return 1;
 191 }
 192
 193 =func clone
 194
 195     $clone = clone($thing);
 196
 197 Clone deeply. This is an unadorned alias to L<Storable> C<dclone>.
 198
 199 =cut
 200
 201 sub clone {
 202     require Storable;
 203     goto &Storable::dclone;
 204 }
 205
 206 =func clone_nomagic
 207
 208     $clone = clone_nomagic($thing);
 209
 210 Clone deeply without keeping [most of] the magic.
 211
 212 B<WARNING:> At the moment the implementation is naïve and won't respond well to nontrivial data or recursive
 213 structures.
 214
 215 =cut
 216
 217 sub clone_nomagic {
 218     my $thing = shift;
 219     if (is_arrayref($thing)) {
 220         my @arr = map { clone_nomagic($_) } @$thing;
 221         return \@arr;
 222     }
 223     elsif (is_hashref($thing)) {
 224         my %hash;
 225         $hash{$_} = clone_nomagic($thing->{$_}) for keys %$thing;
 226         return \%hash;
 227     }
 228     elsif (is_ref($thing)) {
 229         return clone($thing);
 230     }
 231     return $thing;
 232 }
 233
 234 =func dumper
 235
 236     $str = dumper $thing;
 237     dumper $thing;  # in void context, prints to STDERR
 238
 239 Like L<Data::Dumper> but slightly terser in some cases relevent to L<File::KDBX>.
 240
 241 =cut
 242
 243 sub dumper {
 244     require Data::Dumper;
 245     # avoid "once" warnings
 246     local $Data::Dumper::Deepcopy = $Data::Dumper::Deepcopy = 1;
 247     local $Data::Dumper::Deparse = $Data::Dumper::Deparse = 1;
 248     local $Data::Dumper::Indent = 1;
 249     local $Data::Dumper::Quotekeys = 0;
 250     local $Data::Dumper::Sortkeys = 1;
 251     local $Data::Dumper::Terse = 1;
 252     local $Data::Dumper::Trailingcomma = 1;
 253     local $Data::Dumper::Useqq = 1;
 254
 255     my @dumps;
 256     for my $struct (@_) {
 257         my $str = Data::Dumper::Dumper($struct);
 258
 259         # boolean
 260         $str =~ s/bless\( do\{\\\(my \$o = ([01])\)\}, 'boolean' \)/boolean($1)/gs;
 261         # Time::Piece
 262         $str =~ s/bless\([^\)]+?(\d+)'?,\s+\d+,?\s+\], 'Time::Piece' \),/
 263             "scalar gmtime($1), # " . scalar gmtime($1)->datetime/ges;
 264
 265         print STDERR $str if !defined wantarray;
 266         push @dumps, $str;
 267         return $str;
 268     }
 269     return join("\n", @dumps);
 270 }
 271
 272 =func empty
 273
 274 =func nonempty
 275
 276     $bool = empty $thing;
 277
 278     $bool = nonempty $thing;
 279
 280 Test whether a thing is empty (or nonempty). An empty thing is one of these:
 281
 282 =for :list
 283 * nonexistent
 284 * C<undef>
 285 * zero-length string
 286 * zero-length array
 287 * hash with zero keys
 288 * reference to an empty thing (recursive)
 289
 290 Note in particular that zero C<0> is not considered empty because it is an actual value.
 291
 292 =cut
 293
 294 sub empty    {  _empty(@_) }
 295 sub nonempty { !_empty(@_) }
 296
 297 sub _empty {
 298     return 1 if @_ == 0;
 299     local $_ = shift;
 300     return !defined $_
 301         || $_ eq ''
 302         || (is_arrayref($_)  && @$_ == 0)
 303         || (is_hashref($_)   && keys %$_ == 0)
 304         || (is_scalarref($_) && (!defined $$_ || $$_ eq ''))
 305         || (is_refref($_)    && _empty($$_));
 306 }
 307
 308 =func erase
 309
 310     erase($string, ...);
 311     erase(\$string, ...);
 312
 313 Overwrite the memory used by one or more string.
 314
 315 =cut
 316
 317 BEGIN {
 318     if (load_xs) {
 319         *_CowREFCNT = \&File::KDBX::XS::CowREFCNT;
 320     }
 321     elsif (eval { require B::COW; 1 }) {
 322         *_CowREFCNT = \&B::COW::cowrefcnt;
 323     }
 324     else {
 325         *_CowREFCNT = sub { undef };
 326     }
 327 }
 328
 329 sub erase {
 330     # Only bother zeroing out memory if we have the last SvPV COW reference, otherwise we'll end up just
 331     # creating a copy and erasing the copy.
 332     # TODO - Is this worth doing? Need some benchmarking.
 333     for (@_) {
 334         if (!is_ref($_)) {
 335             next if !defined $_ || readonly $_;
 336             my $cowrefcnt = _CowREFCNT($_);
 337             goto FREE_NONREF if defined $cowrefcnt && 1 < $cowrefcnt;
 338             # if (__PACKAGE__->can('erase_xs')) {
 339             #     erase_xs($_);
 340             # }
 341             # else {
 342                 substr($_, 0, length($_), "\0" x length($_));
 343             # }
 344             FREE_NONREF: {
 345                 no warnings 'uninitialized';
 346                 undef $_;
 347             }
 348         }
 349         elsif (is_scalarref($_)) {
 350             next if !defined $$_ || readonly $$_;
 351             my $cowrefcnt = _CowREFCNT($$_);
 352             goto FREE_REF if defined $cowrefcnt && 1 < $cowrefcnt;
 353             # if (__PACKAGE__->can('erase_xs')) {
 354             #     erase_xs($$_);
 355             # }
 356             # else {
 357                 substr($$_, 0, length($$_), "\0" x length($$_));
 358             # }
 359             FREE_REF: {
 360                 no warnings 'uninitialized';
 361                 undef $$_;
 362             }
 363         }
 364         elsif (is_arrayref($_)) {
 365             erase(@$_);
 366             @$_ = ();
 367         }
 368         elsif (is_hashref($_)) {
 369             erase(values %$_);
 370             %$_ = ();
 371         }
 372         else {
 373             throw 'Cannot erase this type of scalar', type => ref $_, what => $_;
 374         }
 375     }
 376 }
 377
 378 =func erase_scoped
 379
 380     $scope_guard = erase_scoped($string, ...);
 381     $scope_guard = erase_scoped(\$string, ...);
 382     undef $scope_guard; # erase happens here
 383
 384 Get a scope guard that will cause scalars to be erased later (i.e. when the scope ends). This is useful if you
 385 want to make sure a string gets erased after you're done with it, even if the scope ends abnormally.
 386
 387 See L</erase>.
 388
 389 =cut
 390
 391 sub erase_scoped {
 392     throw 'Programmer error: Cannot call erase_scoped in void context' if !defined wantarray;
 393     my @args;
 394     for (@_) {
 395         !is_ref($_) || is_arrayref($_) || is_hashref($_) || is_scalarref($_)
 396             or throw 'Cannot erase this type of scalar', type => ref $_, what => $_;
 397         push @args, is_ref($_) ? $_ : \$_;
 398     }
 399     require Scope::Guard;
 400     return Scope::Guard->new(sub { erase(@args) });
 401 }
 402
 403 =func extends
 404
 405     extends $class;
 406
 407 Set up the current module to inheret from another module.
 408
 409 =cut
 410
 411 sub extends {
 412     my $parent  = shift;
 413     my $caller  = caller;
 414     load $parent;
 415     no strict 'refs'; ## no critic (ProhibitNoStrict)
 416     @{"${caller}::ISA"} = $parent;
 417 }
 418
 419 =func has
 420
 421     has $name => %options;
 422
 423 Create an attribute getter/setter. Possible options:
 424
 425 =for :list
 426 * C<is> - Either "rw" (default) or "ro"
 427 * C<default> - Default value
 428 * C<coerce> - Coercive function
 429
 430 =cut
 431
 432 sub has {
 433     my $name = shift;
 434     my %args = @_ % 2 == 1 ? (default => shift, @_) : @_;
 435
 436     my ($package, $file, $line) = caller;
 437
 438     my $d = $args{default};
 439     my $default = is_arrayref($d) ? sub { [@$d] } : is_hashref($d) ? sub { +{%$d} } : $d;
 440     my $coerce  = $args{coerce};
 441     my $is      = $args{is} || 'rw';
 442
 443     my $store = $args{store};
 444     ($store, $name) = split(/\./, $name, 2) if $name =~ /\./;
 445     push @{$ATTRIBUTES{$package} //= []}, $name;
 446
 447     my $store_code = '';
 448     $store_code = qq{->$store} if $store;
 449     my $member = qq{\$_[0]$store_code\->{'$name'}};
 450
 451     my $default_code = is_coderef $default ? q{scalar $default->($_[0])}
 452                         : defined $default ? q{$default}
 453                                            : q{undef};
 454     my $get = qq{$member //= $default_code;};
 455
 456     my $set = '';
 457     if ($is eq 'rw') {
 458         $set = is_coderef $coerce ? qq{$member = scalar \$coerce->(\@_[1..\$#_]) if \$#_;}
 459                 : defined $coerce ? qq{$member = do { local @_ = (\@_[1..\$#_]); $coerce } if \$#_;}
 460                                   : qq{$member = \$_[1] if \$#_;};
 461     }
 462
 463     $line -= 4;
 464     my $code = <<END;
 465 # line $line "$file"
 466 sub ${package}::${name} {
 467     return $default_code if !Scalar::Util::blessed(\$_[0]);
 468     $set
 469     $get
 470 }
 471 END
 472     eval $code; ## no critic (ProhibitStringyEval)
 473 }
 474
 475 =func format_uuid
 476
 477     $string_uuid = format_uuid($raw_uuid);
 478     $string_uuid = format_uuid($raw_uuid, $delimiter);
 479
 480 Format a 128-bit UUID (given as a string of 16 octets) into a hexidecimal string, optionally with a delimiter
 481 to break up the UUID visually into five parts. Examples:
 482
 483     my $uuid = uuid('01234567-89AB-CDEF-0123-456789ABCDEF');
 484     say format_uuid($uuid);         # -> 0123456789ABCDEF0123456789ABCDEF
 485     say format_uuid($uuid, '-');    # -> 01234567-89AB-CDEF-0123-456789ABCDEF
 486
 487 This is the inverse of L</uuid>.
 488
 489 =cut
 490
 491 sub format_uuid {
 492     local $_    = shift // "\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0";
 493     my $delim   = shift // '';
 494     length($_) == 16 or throw 'Must provide a 16-bytes UUID', size => length($_), str => $_;
 495     return uc(join($delim, unpack('H8 H4 H4 H4 H12', $_)));
 496 }
 497
 498 =func generate_uuid
 499
 500     $uuid = generate_uuid;
 501     $uuid = generate_uuid(\%set);
 502     $uuid = generate_uuid(\&test_uuid);
 503
 504 Generate a new random UUID. It's pretty unlikely that this will generate a repeat, but if you're worried about
 505 that you can provide either a set of existing UUIDs (as a hashref where the keys are the elements of a set) or
 506 a function to check for existing UUIDs, and this will be sure to not return a UUID already in provided set.
 507 Perhaps an example will make it clear:
 508
 509     my %uuid_set = (
 510         uuid('12345678-9ABC-DEFG-1234-56789ABCDEFG') => 'whatever',
 511     );
 512     $uuid = generate_uuid(\%uuid_set);
 513     # OR
 514     $uuid = generate_uuid(sub { !$uuid_set{$_} });
 515
 516 Here, C<$uuid> can't be "12345678-9ABC-DEFG-1234-56789ABCDEFG". This example uses L</uuid> to easily pack
 517 a 16-byte UUID from a literal, but it otherwise is not a consequential part of the example.
 518
 519 =cut
 520
 521 sub generate_uuid {
 522     my $set  = @_ % 2 == 1 ? shift : undef;
 523     my %args = @_;
 524     my $test = $set //= $args{test};
 525     $test   = sub { !$set->{$_} } if is_hashref($test);
 526     $test //= sub { 1 };
 527     my $printable = $args{printable} // $args{print};
 528     local $_ = '';
 529     do {
 530         $_ = $printable ? random_string(16) : random_bytes(16);
 531     } while (!$test->($_));
 532     return $_;
 533 }
 534
 535 =func gunzip
 536
 537     $unzipped = gunzip($string);
 538
 539 Decompress an octet stream.
 540
 541 =cut
 542
 543 sub gunzip {
 544     load_optional('Compress::Raw::Zlib');
 545     local $_ = shift;
 546     my ($i, $status) = Compress::Raw::Zlib::Inflate->new(-WindowBits => 31);
 547     $status == Compress::Raw::Zlib::Z_OK()
 548         or throw 'Failed to initialize compression library', status => $status;
 549     $status = $i->inflate($_, my $out);
 550     $status == Compress::Raw::Zlib::Z_STREAM_END()
 551         or throw 'Failed to decompress data', status => $status;
 552     return $out;
 553 }
 554
 555 =func gzip
 556
 557     $zipped = gzip($string);
 558
 559 Compress an octet stream.
 560
 561 =cut
 562
 563 sub gzip {
 564     load_optional('Compress::Raw::Zlib');
 565     local $_ = shift;
 566     my ($d, $status) = Compress::Raw::Zlib::Deflate->new(-WindowBits => 31, -AppendOutput => 1);
 567     $status == Compress::Raw::Zlib::Z_OK()
 568         or throw 'Failed to initialize compression library', status => $status;
 569     $status = $d->deflate($_, my $out);
 570     $status == Compress::Raw::Zlib::Z_OK()
 571         or throw 'Failed to compress data', status => $status;
 572     $status = $d->flush($out);
 573     $status == Compress::Raw::Zlib::Z_OK()
 574         or throw 'Failed to compress data', status => $status;
 575     return $out;
 576 }
 577
 578 =func is_readable
 579
 580 =func is_writable
 581
 582     $bool = is_readable($mode);
 583     $bool = is_writable($mode);
 584
 585 Determine of an C<fopen>-style mode is readable, writable or both.
 586
 587 =cut
 588
 589 sub is_readable { $_[0] !~ /^[aw]b?$/ }
 590 sub is_writable { $_[0] !~ /^rb?$/ }
 591
 592 =func is_uuid
 593
 594     $bool = is_uuid($thing);
 595
 596 Check if a thing is a UUID (i.e. scalar string of length 16).
 597
 598 =cut
 599
 600 sub is_uuid { defined $_[0] && !is_ref($_[0]) && length($_[0]) == 16 }
 601
 602 =func list_attributes
 603
 604     @attributes = list_attributes($package);
 605
 606 Get a list of attributes for a class.
 607
 608 =cut
 609
 610 sub list_attributes {
 611     my $package = shift;
 612     return @{$ATTRIBUTES{$package} // []};
 613 }
 614
 615 =func load_optional
 616
 617     $package = load_optional($package);
 618
 619 Load a module that isn't required but can provide extra functionality. Throw if the module is not available.
 620
 621 =cut
 622
 623 sub load_optional {
 624     for my $module (@_) {
 625         eval { load $module };
 626         if (my $err = $@) {
 627             throw "Missing dependency: Please install $module to use this feature.\n",
 628                 module  => $module,
 629                 error   => $err;
 630         }
 631     }
 632     return wantarray ? @_ : $_[0];
 633 }
 634
 635 =func memoize
 636
 637     \&memoized_code = memoize(\&code, ...);
 638
 639 Memoize a function. Extra arguments are passed through to C<&code> when it is called.
 640
 641 =cut
 642
 643 sub memoize {
 644     my $func = shift;
 645     my @args = @_;
 646     my %cache;
 647     return sub { $cache{join("\0", grep { defined } @_)} //= $func->(@args, @_) };
 648 }
 649
 650 =func pad_pkcs7
 651
 652     $padded_string = pad_pkcs7($string, $block_size),
 653
 654 Pad a block using the PKCS#7 method.
 655
 656 =cut
 657
 658 sub pad_pkcs7 {
 659     my $data = shift // throw 'Must provide a string to pad';
 660     my $size = shift or throw 'Must provide block size';
 661
 662     0 <= $size && $size < 256
 663         or throw 'Cannot add PKCS7 padding to a large block size', size => $size;
 664
 665     my $pad_len = $size - length($data) % $size;
 666     $data .= chr($pad_len) x $pad_len;
 667 }
 668
 669 =func query
 670
 671     $query = query(@where);
 672     $query->(\%data);
 673
 674 Generate a function that will run a series of tests on a passed hashref and return true or false depending on
 675 if the data record in the hash matched the specified logic.
 676
 677 The logic can be specified in a manner similar to L<SQL::Abstract/"WHERE CLAUSES"> which was the inspiration
 678 for this function, but this code is distinct, supporting an overlapping but not identical feature set and
 679 having its own bugs.
 680
 681 See L<File::KDBX/QUERY> for examples.
 682
 683 =cut
 684
 685 sub query { _query(undef, '-or', \@_) }
 686
 687 =func read_all
 688
 689     $size = read_all($fh, my $buffer, $size);
 690     $size = read_all($fh, my $buffer, $size, $offset);
 691
 692 Like L<functions/read> but returns C<undef> if not all C<$size> bytes are read. This is considered an error,
 693 distinguishable from other errors by C<$!> not being set.
 694
 695 =cut
 696
 697 sub read_all($$$;$) { ## no critic (ProhibitSubroutinePrototypes)
 698     my $result = @_ == 3 ? read($_[0], $_[1], $_[2])
 699                          : read($_[0], $_[1], $_[2], $_[3]);
 700     return if !defined $result;
 701     return if $result != $_[2];
 702     return $result;
 703 }
 704
 705 =func recurse_limit
 706
 707     \&limited_code = recurse_limit(\&code);
 708     \&limited_code = recurse_limit(\&code, $max_depth);
 709     \&limited_code = recurse_limit(\&code, $max_depth, \&error_handler);
 710
 711 Wrap a function with a guard to prevent deep recursion.
 712
 713 =cut
 714
 715 sub recurse_limit {
 716     my $func        = shift;
 717     my $max_depth   = shift // 200;
 718     my $error       = shift // sub {};
 719     my $depth = 0;
 720     return sub { return $error->(@_) if $max_depth < ++$depth; $func->(@_) };
 721 };
 722
 723 =func search
 724
 725     # Generate a query on-the-fly:
 726     \@matches = search(\@records, @where);
 727
 728     # Use a pre-compiled query:
 729     $query = query(@where);
 730     \@matches = search(\@records, $query);
 731
 732     # Use a simple expression:
 733     \@matches = search(\@records, \'query terms', @fields);
 734     \@matches = search(\@records, \'query terms', $operator, @fields);
 735
 736     # Use your own subroutine:
 737     \@matches = search(\@records, \&query);
 738     \@matches = search(\@records, sub { $record = shift; ... });
 739
 740 Execute a linear search over an array of records using a L</query>. A "record" is usually a hash.
 741
 742 This is the search engine described with many examples at L<File::KDBX/QUERY>.
 743
 744 =cut
 745
 746 sub search {
 747     my $list    = shift;
 748     my $query   = shift;
 749
 750     if (is_coderef($query) && !@_) {
 751         # already a query
 752     }
 753     elsif (is_scalarref($query)) {
 754         $query = simple_expression_query($$query, @_);
 755     }
 756     else {
 757         $query = query($query, @_);
 758     }
 759
 760     my @match;
 761     for my $item (@$list) {
 762         push @match, $item if $query->($item);
 763     }
 764     return \@match;
 765 }
 766
 767 =func simple_expression_query
 768
 769     $query = simple_expression_query($expression, @fields);
 770     $query = simple_expression_query($expression, $operator, @fields);
 771
 772 Generate a query, like L</query>, to be used with L</search> but built from a "simple expression" as
 773 L<described here|https://keepass.info/help/base/search.html#mode_se>.
 774
 775 An expression is a string with one or more space-separated terms. Terms with spaces can be enclosed in double
 776 quotes. Terms are negated if they are prefixed with a minus sign. A record must match every term on at least
 777 one of the given fields.
 778
 779 =cut
 780
 781 sub simple_expression_query {
 782     my $expr = shift;
 783     my $op   = @_ && ($OPS{$_[0] || ''} || 0) == 2 ? shift : '=~';
 784
 785     my $neg_op = $OP_NEG{$op};
 786     my $is_re  = $op eq '=~' || $op eq '!~';
 787
 788     require Text::ParseWords;
 789     my @terms = Text::ParseWords::shellwords($expr);
 790
 791     my @query = qw(-and);
 792
 793     for my $term (@terms) {
 794         my @subquery = qw(-or);
 795
 796         my $neg = $term =~ s/^-//;
 797         my $condition = [($neg ? $neg_op : $op) => ($is_re ? qr/\Q$term\E/i : $term)];
 798
 799         for my $field (@_) {
 800             push @subquery, $field => $condition;
 801         }
 802
 803         push @query, \@subquery;
 804     }
 805
 806     return query(\@query);
 807 }
 808
 809 =func snakify
 810
 811     $string = snakify($string);
 812
 813 Turn a CamelCase string into snake_case.
 814
 815 =cut
 816
 817 sub snakify {
 818     local $_ = shift;
 819     s/UserName/Username/g;
 820     s/([a-z])([A-Z0-9])/${1}_${2}/g;
 821     s/([A-Z0-9]+)([A-Z0-9])(?![A-Z0-9]|$)/${1}_${2}/g;
 822     return lc($_);
 823 }
 824
 825 =func split_url
 826
 827     ($scheme, $auth, $host, $port, $path, $query, $hash, $usename, $password) = split_url($url);
 828
 829 Split a URL into its parts.
 830
 831 For example, C<http://user:pass@localhost:4000/path?query#hash> gets split like:
 832
 833 =for :list
 834 * C<http>
 835 * C<user:pass>
 836 * C<host>
 837 * C<4000>
 838 * C</path>
 839 * C<?query>
 840 * C<#hash>
 841 * C<user>
 842 * C<pass>
 843
 844 =cut
 845
 846 sub split_url {
 847     local $_ = shift;
 848     my ($scheme, $auth, $host, $port, $path, $query, $hash) =~ m!
 849         ^([^:/\?\#]+) ://
 850         (?:([^\@]+)\@)
 851         ([^:/\?\#]*)
 852         (?::(\d+))?
 853         ([^\?\#]*)
 854         (\?[^\#]*)?
 855         (\#(.*))?
 856     !x;
 857
 858     $scheme = lc($scheme);
 859
 860     $host ||= 'localhost';
 861     $host = lc($host);
 862
 863     $path = "/$path" if $path !~ m!^/!;
 864
 865     $port ||= $scheme eq 'http' ? 80 : $scheme eq 'https' ? 433 : undef;
 866
 867     my ($username, $password) = split($auth, ':', 2);
 868
 869     return ($scheme, $auth, $host, $port, $path, $query, $hash, $username, $password);
 870 }
 871
 872 =func to_bool
 873
 874 =func to_number
 875
 876 =func to_string
 877
 878 =func to_time
 879
 880 =func to_tristate
 881
 882 =func to_uuid
 883
 884 Various typecasting / coercive functions.
 885
 886 =cut
 887
 888 sub to_bool   { $_[0] // return; boolean($_[0]) }
 889 sub to_number { $_[0] // return; 0+$_[0] }
 890 sub to_string { $_[0] // return; "$_[0]" }
 891 sub to_time   {
 892     $_[0] // return;
 893     return gmtime($_[0]) if looks_like_number($_[0]);
 894     return Time::Piece->strptime($_[0], '%Y-%m-%d %H:%M:%S') if !blessed $_[0];
 895     return $_[0];
 896 }
 897 sub to_tristate { $_[0] // return; boolean($_[0]) }
 898 sub to_uuid {
 899     my $str = to_string(@_) // return;
 900     return sprintf('%016s', $str) if length($str) < 16;
 901     return substr($str, 0, 16) if 16 < length($str);
 902     return $str;
 903 }
 904
 905 =func trim
 906
 907     $string = trim($string);
 908
 909 The ubiquitous C<trim> function. Removes all whitespace from both ends of a string.
 910
 911 =cut
 912
 913 sub trim($) { ## no critic (ProhibitSubroutinePrototypes)
 914     local $_ = shift // return;
 915     s/^\s*//;
 916     s/\s*$//;
 917     return $_;
 918 }
 919
 920 =func try_load_optional
 921
 922     $package = try_load_optional($package);
 923
 924 Try to load a module that isn't required but can provide extra functionality, and return true if successful.
 925
 926 =cut
 927
 928 sub try_load_optional {
 929     for my $module (@_) {
 930         eval { load $module };
 931         if (my $err = $@) {
 932             warn $err if 3 <= DEBUG;
 933             return;
 934         }
 935     }
 936     return @_;
 937 }
 938
 939 =func uri_escape_utf8
 940
 941     $string = uri_escape_utf8($string);
 942
 943 Percent-encode arbitrary text strings, like for a URI.
 944
 945 =cut
 946
 947 my %ESC = map { chr($_) => sprintf('%%%02X', $_) } 0..255;
 948 sub uri_escape_utf8 {
 949     local $_ = shift // return;
 950     $_ = encode('UTF-8', $_);
 951     # RFC 3986 section 2.3 unreserved characters
 952     s/([^A-Za-z0-9\-\._~])/$ESC{$1}/ge;
 953     return $_;
 954 }
 955
 956 =func uri_unescape_utf8
 957
 958     $string = uri_unescape_utf8($string);
 959
 960 Inverse of L</uri_escape_utf8>.
 961
 962 =cut
 963
 964 sub uri_unescape_utf8 {
 965     local $_ = shift // return;
 966     s/\%([A-Fa-f0-9]{2})/chr(hex($1))/;
 967     return decode('UTF-8', $_);
 968 }
 969
 970 =func uuid
 971
 972     $raw_uuid = uuid($string_uuid);
 973
 974 Pack a 128-bit UUID (given as a hexidecimal string with optional C<->'s, like
 975 C<12345678-9ABC-DEFG-1234-56789ABCDEFG>) into a string of exactly 16 octets.
 976
 977 This is the inverse of L</format_uuid>.
 978
 979 =cut
 980
 981 sub uuid {
 982     local $_ = shift // return "\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0";
 983     s/-//g;
 984     /^[A-Fa-f0-9]{32}$/ or throw 'Must provide a formatted 128-bit UUID';
 985     return pack('H32', $_);
 986
 987 }
 988
 989 =func UUID_NULL
 990
 991 Get the null UUID (i.e. string of 16 null bytes).
 992
 993 =cut
 994
 995 sub UUID_NULL() { "\0" x 16 }
 996
 997 ### --------------------------------------------------------------------------
 998
 999 # Determine if an array looks like keypairs from a hash.
1000 sub _looks_like_keypairs {
1001     my $arr = shift;
1002     return 0 if @$arr % 2 == 1;
1003     for (my $i = 0; $i < @$arr; $i += 2) {
1004         return 0 if is_ref($arr->[$i]);
1005     }
1006     return 1;
1007 }
1008
1009 sub _is_operand_plain {
1010     local $_ = shift;
1011     return !(is_hashref($_) || is_arrayref($_));
1012 }
1013
1014 sub _query {
1015     # dumper \@_;
1016     my $subject = shift;
1017     my $op      = shift // throw 'Must specify a query operator';
1018     my $operand = shift;
1019
1020     return _query_simple($op, $subject) if defined $subject && !is_ref($op) && ($OPS{$subject} || 2) < 2;
1021     return _query_simple($subject, $op, $operand) if _is_operand_plain($operand);
1022     return _query_inverse(_query($subject, '-or', $operand)) if $op eq '-not' || $op eq '-false';
1023     return _query($subject, '-and', [%$operand]) if is_hashref($operand);
1024
1025     my @queries;
1026
1027     my @atoms = @$operand;
1028     while (@atoms) {
1029         if (_looks_like_keypairs(\@atoms)) {
1030             my ($atom, $operand) = splice @atoms, 0, 2;
1031             if (my $op_type = $OPS{$atom}) {
1032                 if ($op_type == 1 && _is_operand_plain($operand)) { # unary
1033                     push @queries, _query_simple($operand, $atom);
1034                 }
1035                 else {
1036                     push @queries, _query($subject, $atom, $operand);
1037                 }
1038             }
1039             elsif (!is_ref($atom)) {
1040                 push @queries, _query($atom, 'eq', $operand);
1041             }
1042         }
1043         else {
1044             my $atom = shift @atoms;
1045             if ($OPS{$atom}) {     # apply new operator over the rest
1046                 push @queries, _query($subject, $atom, \@atoms);
1047                 last;
1048             }
1049             else {  # apply original operator over this one
1050                 push @queries, _query($subject, $op, $atom);
1051             }
1052         }
1053     }
1054
1055     if (@queries == 1) {
1056         return $queries[0];
1057     }
1058     elsif ($op eq '-and') {
1059         return _query_all(@queries);
1060     }
1061     elsif ($op eq '-or') {
1062         return _query_any(@queries);
1063     }
1064     throw 'Malformed query';
1065 }
1066
1067 sub _query_simple {
1068     my $subject = shift;
1069     my $op      = shift // 'eq';
1070     my $operand = shift;
1071
1072     # these special operators can also act as simple operators
1073     $op = '!!' if $op eq '-true';
1074     $op = '!'  if $op eq '-false';
1075     $op = '!'  if $op eq '-not';
1076
1077     defined $subject or throw 'Subject is not set in query';
1078     $OPS{$op} >= 0   or throw 'Cannot use a non-simple operator in a simple query';
1079     if (empty($operand)) {
1080         if ($OPS{$op} < 2) {
1081             # no operand needed
1082         }
1083         # Allow field => undef and field => {'ne' => undef} to do the (arguably) right thing.
1084         elsif ($op eq 'eq' || $op eq '==') {
1085             $op = '-empty';
1086         }
1087         elsif ($op eq 'ne' || $op eq '!=') {
1088             $op = '-nonempty';
1089         }
1090         else {
1091             throw 'Operand is required';
1092         }
1093     }
1094
1095     my $field = sub { blessed $_[0] && $_[0]->can($subject) ? $_[0]->$subject : $_[0]->{$subject} };
1096
1097     my %map = (
1098         'eq'        => sub { local $_ = $field->(@_); defined && $_ eq $operand },
1099         'ne'        => sub { local $_ = $field->(@_); defined && $_ ne $operand },
1100         'lt'        => sub { local $_ = $field->(@_); defined && $_ lt $operand },
1101         'gt'        => sub { local $_ = $field->(@_); defined && $_ gt $operand },
1102         'le'        => sub { local $_ = $field->(@_); defined && $_ le $operand },
1103         'ge'        => sub { local $_ = $field->(@_); defined && $_ ge $operand },
1104         '=='        => sub { local $_ = $field->(@_); defined && $_ == $operand },
1105         '!='        => sub { local $_ = $field->(@_); defined && $_ != $operand },
1106         '<'         => sub { local $_ = $field->(@_); defined && $_ <  $operand },
1107         '>'         => sub { local $_ = $field->(@_); defined && $_ >  $operand },
1108         '<='        => sub { local $_ = $field->(@_); defined && $_ <= $operand },
1109         '>='        => sub { local $_ = $field->(@_); defined && $_ >= $operand },
1110         '=~'        => sub { local $_ = $field->(@_); defined && $_ =~ $operand },
1111         '!~'        => sub { local $_ = $field->(@_); defined && $_ !~ $operand },
1112         '!'         => sub { local $_ = $field->(@_); ! $_ },
1113         '!!'        => sub { local $_ = $field->(@_); !!$_ },
1114         '-defined'  => sub { local $_ = $field->(@_);  defined $_ },
1115         '-undef'    => sub { local $_ = $field->(@_); !defined $_ },
1116         '-nonempty' => sub { local $_ = $field->(@_); nonempty $_ },
1117         '-empty'    => sub { local $_ = $field->(@_); empty    $_ },
1118     );
1119
1120     return $map{$op} // throw "Unexpected operator in query: $op",
1121         subject     => $subject,
1122         operator    => $op,
1123         operand     => $operand;
1124 }
1125
1126 sub _query_inverse {
1127     my $query = shift;
1128     return sub { !$query->(@_) };
1129 }
1130
1131 sub _query_all {
1132     my @queries = @_;
1133     return sub {
1134         my $val = shift;
1135         all { $_->($val) } @queries;
1136     };
1137 }
1138
1139 sub _query_any {
1140     my @queries = @_;
1141     return sub {
1142         my $val = shift;
1143         any { $_->($val) } @queries;
1144     };
1145 }
1146
1147 1;