Dogcows Code - chaz/p5-File-KDBX/blob - lib/File/KDBX/Object.pm

   1 package File::KDBX::Object;
   2 # ABSTRACT: A KDBX database object
   3
   4 use warnings;
   5 use strict;
   6
   7 use Devel::GlobalDestruction;
   8 use File::KDBX::Constants qw(:bool);
   9 use File::KDBX::Error;
  10 use File::KDBX::Util qw(:uuid);
  11 use Hash::Util::FieldHash qw(fieldhashes);
  12 use List::Util qw(any first);
  13 use Ref::Util qw(is_arrayref is_plain_arrayref is_plain_hashref is_ref);
  14 use Scalar::Util qw(blessed weaken);
  15 use namespace::clean;
  16
  17 our $VERSION = '999.999'; # VERSION
  18
  19 fieldhashes \my (%KDBX, %PARENT, %TXNS, %REFS, %SIGNALS);
  20
  21 =method new
  22
  23     $object = File::KDBX::Object->new;
  24     $object = File::KDBX::Object->new(%attributes);
  25     $object = File::KDBX::Object->new(\%data);
  26     $object = File::KDBX::Object->new(\%data, $kdbx);
  27
  28 Construct a new KDBX object.
  29
  30 There is a subtlety to take note of. There is a significant difference between:
  31
  32     File::KDBX::Entry->new(username => 'iambatman');
  33
  34 and:
  35
  36     File::KDBX::Entry->new({username => 'iambatman'}); # WRONG
  37
  38 In the first, an empty object is first created and then initialized with whatever I<attributes> are given. In
  39 the second, a hashref is blessed and essentially becomes the object. The significance is that the hashref
  40 key-value pairs will remain as-is so the structure is expected to adhere to the shape of a raw B<Object>
  41 (which varies based on the type of object), whereas with the first the attributes will set the structure in
  42 the correct way (just like using the object accessors / getters / setters).
  43
  44 The second example isn't I<generally> wrong -- this type of construction is supported for a reason, to allow
  45 for working with KDBX objects at a low level -- but it is wrong in this specific case only because
  46 C<< {username => $str} >> isn't a valid raw KDBX entry object. The L</username> attribute is really a proxy
  47 for the C<UserName> string, so the equivalent raw entry object should be
  48 C<< {strings => {UserName => {value => $str}}} >>. These are roughly equivalent:
  49
  50     File::KDBX::Entry->new(username => 'iambatman');
  51     File::KDBX::Entry->new({strings => {UserName => {value => 'iambatman'}}});
  52
  53 If this explanation went over your head, that's fine. Just stick with the attributes since they are typically
  54 easier to use correctly and provide the most convenience. If in the future you think of some kind of KDBX
  55 object manipulation you want to do that isn't supported by the accessors and methods, just know you I<can>
  56 access an object's data directly.
  57
  58 =cut
  59
  60 sub new {
  61     my $class = shift;
  62
  63     # copy constructor
  64     return $_[0]->clone if @_ == 1 && blessed $_[0] && $_[0]->isa($class);
  65
  66     my $data;
  67     $data = shift if is_plain_hashref($_[0]);
  68
  69     my $kdbx;
  70     $kdbx = shift if @_ % 2 == 1;
  71
  72     my %args = @_;
  73     $args{kdbx} //= $kdbx if defined $kdbx;
  74
  75     my $self = bless $data // {}, $class;
  76     $self->init(%args);
  77     $self->_set_nonlazy_attributes if !$data;
  78     return $self;
  79 }
  80
  81 sub _set_nonlazy_attributes { die 'Not implemented' }
  82
  83 =method init
  84
  85     $object = $object->init(%attributes);
  86
  87 Called by the constructor to set attributes. You normally should not call this.
  88
  89 =cut
  90
  91 sub init {
  92     my $self = shift;
  93     my %args = @_;
  94
  95     while (my ($key, $val) = each %args) {
  96         if (my $method = $self->can($key)) {
  97             $self->$method($val);
  98         }
  99     }
 100
 101     return $self;
 102 }
 103
 104 =method wrap
 105
 106     $object = File::KDBX::Object->wrap($object);
 107
 108 Ensure that a KDBX object is blessed.
 109
 110 =cut
 111
 112 sub wrap {
 113     my $class   = shift;
 114     my $object  = shift;
 115     return $object if blessed $object && $object->isa($class);
 116     return $class->new(@_, @$object) if is_arrayref($object);
 117     return $class->new($object, @_);
 118 }
 119
 120 =method label
 121
 122     $label = $object->label;
 123     $object->label($label);
 124
 125 Get or set the object's label, a text string that can act as a non-unique identifier. For an entry, the label
 126 is its title string. For a group, the label is its name.
 127
 128 =cut
 129
 130 sub label { die 'Not implemented' }
 131
 132 =method clone
 133
 134     $object_copy = $object->clone(%options);
 135     $object_copy = File::KDBX::Object->new($object);
 136
 137 Make a clone of an object. By default the clone is indeed an exact copy that is connected to the same database
 138 but not actually included in the object tree (i.e. it has no parent group). Some options are allowed to get
 139 different effects:
 140
 141 =for :list
 142 * C<new_uuid> - If set, generate a new UUID for the copy (default: false)
 143 * C<parent> - If set, add the copy to the same parent group, if any (default: false)
 144 * C<relabel> - If set, append " - Copy" to the object's title or name (default: false)
 145 * C<entries> - If set, copy child entries, if any (default: true)
 146 * C<groups> - If set, copy child groups, if any (default: true)
 147 * C<history> - If set, copy entry history, if any (default: true)
 148 * C<reference_password> - Toggle whether or not cloned entry's Password string should be set as a field
 149     reference to the original entry's Password string (default: false)
 150 * C<reference_username> - Toggle whether or not cloned entry's UserName string should be set as a field
 151     reference to the original entry's UserName string (default: false)
 152
 153 =cut
 154
 155 my %CLONE = (entries => 1, groups => 1, history => 1);
 156 sub clone {
 157     my $self = shift;
 158     my %args = @_;
 159
 160     local $CLONE{new_uuid}              = $args{new_uuid} // $args{parent} // 0;
 161     local $CLONE{entries}               = $args{entries}  // 1;
 162     local $CLONE{groups}                = $args{groups}   // 1;
 163     local $CLONE{history}               = $args{history}  // 1;
 164     local $CLONE{reference_password}    = $args{reference_password} // 0;
 165     local $CLONE{reference_username}    = $args{reference_username} // 0;
 166
 167     require Storable;
 168     my $copy = Storable::dclone($self);
 169
 170     if ($args{relabel} and my $label = $self->label) {
 171         $copy->label("$label - Copy");
 172     }
 173     if ($args{parent} and my $parent = $self->group) {
 174         $parent->add_object($copy);
 175     }
 176
 177     return $copy;
 178 }
 179
 180 sub STORABLE_freeze {
 181     my $self    = shift;
 182     my $cloning = shift;
 183
 184     my $copy = {%$self};
 185     delete $copy->{entries} if !$CLONE{entries};
 186     delete $copy->{groups}  if !$CLONE{groups};
 187     delete $copy->{history} if !$CLONE{history};
 188
 189     return ($cloning ? Hash::Util::FieldHash::id($self) : ''), $copy;
 190 }
 191
 192 sub STORABLE_thaw {
 193     my $self    = shift;
 194     my $cloning = shift;
 195     my $addr    = shift;
 196     my $copy    = shift;
 197
 198     @$self{keys %$copy} = values %$copy;
 199
 200     if ($cloning) {
 201         my $kdbx = $KDBX{$addr};
 202         $self->kdbx($kdbx) if $kdbx;
 203     }
 204
 205     if (defined $self->{uuid}) {
 206         if (($CLONE{reference_password} || $CLONE{reference_username}) && $self->can('strings')) {
 207             my $uuid = format_uuid($self->{uuid});
 208             my $clone_obj = do {
 209                 local $CLONE{new_uuid}              = 0;
 210                 local $CLONE{entries}               = 1;
 211                 local $CLONE{groups}                = 1;
 212                 local $CLONE{history}               = 1;
 213                 local $CLONE{reference_password}    = 0;
 214                 local $CLONE{reference_username}    = 0;
 215                 # Clone only the entry's data and manually bless to avoid infinite recursion.
 216                 bless Storable::dclone({%$copy}), 'File::KDBX::Entry';
 217             };
 218             my $txn = $self->begin_work(snapshot => $clone_obj);
 219             if ($CLONE{reference_password}) {
 220                 $self->password("{REF:P\@I:$uuid}");
 221             }
 222             if ($CLONE{reference_username}) {
 223                 $self->username("{REF:U\@I:$uuid}");
 224             }
 225             $txn->commit;
 226         }
 227         $self->uuid(generate_uuid) if $CLONE{new_uuid};
 228     }
 229
 230     # Dualvars aren't cloned as dualvars, so dualify the icon.
 231     $self->icon_id($self->{icon_id}) if defined $self->{icon_id};
 232 }
 233
 234 =attr kdbx
 235
 236     $kdbx = $object->kdbx;
 237     $object->kdbx($kdbx);
 238
 239 Get or set the L<File::KDBX> instance connected with this object.
 240
 241 =cut
 242
 243 sub kdbx {
 244     my $self = shift;
 245     $self = $self->new if !ref $self;
 246     if (@_) {
 247         if (my $kdbx = shift) {
 248             $KDBX{$self} = $kdbx;
 249             weaken $KDBX{$self};
 250         }
 251         else {
 252             delete $KDBX{$self};
 253         }
 254     }
 255     $KDBX{$self} or throw 'Object is disconnected', object => $self;
 256 }
 257
 258 =method is_connected
 259
 260     $bool = $object->is_connected;
 261
 262 Determine whether or not an object is connected to a database.
 263
 264 =cut
 265
 266 sub is_connected {
 267     my $self = shift;
 268     return !!eval { $self->kdbx };
 269 }
 270
 271 =method id
 272
 273     $string_uuid = $object->id;
 274     $string_uuid = $object->id($delimiter);
 275
 276 Get the unique identifier for this object as a B<formatted> UUID string, typically for display purposes. You
 277 could use this to compare with other identifiers formatted with the same delimiter, but it is more efficient
 278 to use the raw UUID for that purpose (see L</uuid>).
 279
 280 A delimiter can optionally be provided to break up the UUID string visually. See
 281 L<File::KDBX::Util/format_uuid>.
 282
 283 =cut
 284
 285 sub id { format_uuid(shift->uuid, @_) }
 286
 287 =method group
 288
 289     $parent_group = $object->group;
 290     $object->group($parent_group);
 291
 292 Get or set the parent group to which an object belongs or C<undef> if it belongs to no group.
 293
 294 =cut
 295
 296 sub group {
 297     my $self = shift;
 298
 299     if (my $new_group = shift) {
 300         my $old_group = $self->group;
 301         return $new_group if Hash::Util::FieldHash::id($old_group) == Hash::Util::FieldHash::id($new_group);
 302         # move to a new parent
 303         $self->remove(signal => 0) if $old_group;
 304         $new_group->add_object($self);
 305     }
 306
 307     my $id   = Hash::Util::FieldHash::id($self);
 308     if (my $group = $PARENT{$self}) {
 309         my $method = $self->_parent_container;
 310         return $group if first { $id == Hash::Util::FieldHash::id($_) } @{$group->$method};
 311         delete $PARENT{$self};
 312     }
 313     # always get lineage from root to leaf because the other way requires parent, so it would be recursive
 314     my $lineage = $self->kdbx->_trace_lineage($self) or return;
 315     my $group = pop @$lineage or return;
 316     $PARENT{$self} = $group; weaken $PARENT{$self};
 317     return $group;
 318 }
 319
 320 sub _set_group {
 321     my $self = shift;
 322     if (my $parent = shift) {
 323         $PARENT{$self} = $parent;
 324         weaken $PARENT{$self};
 325     }
 326     else {
 327         delete $PARENT{$self};
 328     }
 329     return $self;
 330 }
 331
 332 ### Name of the parent attribute expected to contain the object
 333 sub _parent_container { die 'Not implemented' }
 334
 335 =method lineage
 336
 337     \@lineage = $object->lineage;
 338     \@lineage = $object->lineage($base_group);
 339
 340 Get the direct line of ancestors from C<$base_group> (default: the root group) to an object. The lineage
 341 includes the base group but I<not> the target object. Returns C<undef> if the target is not in the database
 342 structure. Returns an empty arrayref is the object itself is a root group.
 343
 344 =cut
 345
 346 sub lineage {
 347     my $self = shift;
 348     my $base = shift;
 349
 350     my $base_addr = $base ? Hash::Util::FieldHash::id($base) : 0;
 351
 352     # try leaf to root
 353     my @path;
 354     my $object = $self;
 355     while ($object = $object->group) {
 356         unshift @path, $object;
 357         last if $base_addr == Hash::Util::FieldHash::id($object);
 358     }
 359     return \@path if @path && ($base_addr == Hash::Util::FieldHash::id($path[0]) || $path[0]->is_root);
 360
 361     # try root to leaf
 362     return $self->kdbx->_trace_lineage($self, $base);
 363 }
 364
 365 =method remove
 366
 367     $object = $object->remove(%options);
 368
 369 Remove an object from its parent. If the object is a group, all contained objects stay with the object and so
 370 are removed as well. Options:
 371
 372 =for :list
 373 * C<signal> Whether or not to signal the removal to the connected database (default: true)
 374
 375 =cut
 376
 377 sub remove {
 378     my $self = shift;
 379     my $parent = $self->group;
 380     $parent->remove_object($self, @_) if $parent;
 381     $self->_set_group(undef);
 382     return $self;
 383 }
 384
 385 =method recycle
 386
 387     $object = $object->recycle;
 388
 389 Remove an object from its parent and add it to the connected database's recycle bin group.
 390
 391 =cut
 392
 393 sub recycle {
 394     my $self = shift;
 395     return $self->group($self->kdbx->recycle_bin);
 396 }
 397
 398 =method recycle_or_remove
 399
 400     $object = $object->recycle_or_remove;
 401
 402 Recycle or remove an object, depending on the connected database's L<File::KDBX/recycle_bin_enabled>. If the
 403 object is not connected to a database or is already in the recycle bin, remove it.
 404
 405 =cut
 406
 407 sub recycle_or_remove {
 408     my $self = shift;
 409     my $kdbx = eval { $self->kdbx };
 410     if ($kdbx && $kdbx->recycle_bin_enabled && !$self->is_recycled) {
 411         $self->recycle;
 412     }
 413     else {
 414         $self->remove;
 415     }
 416 }
 417
 418 =method is_recycled
 419
 420     $bool = $object->is_recycled;
 421
 422 Get whether or not an object is in a recycle bin.
 423
 424 =cut
 425
 426 sub is_recycled {
 427     my $self = shift;
 428     eval { $self->kdbx } or return FALSE;
 429     return !!($self->group && any { $_->is_recycle_bin } @{$self->lineage});
 430 }
 431
 432 ##############################################################################
 433
 434 =method tag_list
 435
 436     @tags = $entry->tag_list;
 437
 438 Get a list of tags, split from L</tag> using delimiters C<,>, C<.>, C<:>, C<;> and whitespace.
 439
 440 =cut
 441
 442 sub tag_list {
 443     my $self = shift;
 444     return grep { $_ ne '' } split(/[,\.:;]|\s+/, trim($self->tags) // '');
 445 }
 446
 447 =method custom_icon
 448
 449     $image_data = $object->custom_icon;
 450     $image_data = $object->custom_icon($image_data, %attributes);
 451
 452 Get or set an icon image. Returns C<undef> if there is no custom icon set. Setting a custom icon will change
 453 the L</custom_icon_uuid> attribute.
 454
 455 Custom icon attributes (supported in KDBX4.1 and greater):
 456
 457 =for :list
 458 * C<name> - Name of the icon (text)
 459 * C<last_modification_time> - Just what it says (datetime)
 460
 461 =cut
 462
 463 sub custom_icon {
 464     my $self = shift;
 465     my $kdbx = $self->kdbx;
 466     if (@_) {
 467         my $img = shift;
 468         my $uuid = defined $img ? $kdbx->add_custom_icon($img, @_) : undef;
 469         $self->icon_id(0) if $uuid;
 470         $self->custom_icon_uuid($uuid);
 471         return $img;
 472     }
 473     return $kdbx->custom_icon_data($self->custom_icon_uuid);
 474 }
 475
 476 =method custom_data
 477
 478     \%all_data = $object->custom_data;
 479     $object->custom_data(\%all_data);
 480
 481     \%data = $object->custom_data($key);
 482     $object->custom_data($key => \%data);
 483     $object->custom_data(%data);
 484     $object->custom_data(key => $value, %data);
 485
 486 Get and set custom data. Custom data is metadata associated with an object.
 487
 488 Each data item can have a few attributes associated with it.
 489
 490 =for :list
 491 * C<key> - A unique text string identifier used to look up the data item (required)
 492 * C<value> - A text string value (required)
 493 * C<last_modification_time> (optional, KDBX4.1+)
 494
 495 =cut
 496
 497 sub custom_data {
 498     my $self = shift;
 499     $self->{custom_data} = shift if @_ == 1 && is_plain_hashref($_[0]);
 500     return $self->{custom_data} //= {} if !@_;
 501
 502     my %args = @_     == 2 ? (key => shift, value => shift)
 503              : @_ % 2 == 1 ? (key => shift, @_) : @_;
 504
 505     if (!$args{key} && !$args{value}) {
 506         my %standard = (key => 1, value => 1, last_modification_time => 1);
 507         my @other_keys = grep { !$standard{$_} } keys %args;
 508         if (@other_keys == 1) {
 509             my $key = $args{key} = $other_keys[0];
 510             $args{value} = delete $args{$key};
 511         }
 512     }
 513
 514     my $key = $args{key} or throw 'Must provide a custom_data key to access';
 515
 516     return $self->{custom_data}{$key} = $args{value} if is_plain_hashref($args{value});
 517
 518     while (my ($field, $value) = each %args) {
 519         $self->{custom_data}{$key}{$field} = $value;
 520     }
 521     return $self->{custom_data}{$key};
 522 }
 523
 524 =method custom_data_value
 525
 526     $value = $object->custom_data_value($key);
 527
 528 Exactly the same as L</custom_data> except returns just the custom data's value rather than a structure of
 529 attributes. This is a shortcut for:
 530
 531     my $data = $object->custom_data($key);
 532     my $value = defined $data ? $data->{value} : undef;
 533
 534 =cut
 535
 536 sub custom_data_value {
 537     my $self = shift;
 538     my $data = $self->custom_data(@_) // return undef;
 539     return $data->{value};
 540 }
 541
 542 ##############################################################################
 543
 544 =method begin_work
 545
 546     $txn = $object->begin_work(%options);
 547     $object->begin_work(%options);
 548
 549 Begin a new transaction. Returns a L<File::KDBX::Transaction> object that can be scoped to ensure a rollback
 550 occurs if exceptions are thrown. Alternatively, if called in void context, there will be no
 551 B<File::KDBX::Transaction> and it is instead your responsibility to call L</commit> or L</rollback> as
 552 appropriate. It is undefined behavior to call these if a B<File::KDBX::Transaction> exists. Recursive
 553 transactions are allowed.
 554
 555 Signals created during a transaction are delayed until all transactions are resolved. If the outermost
 556 transaction is committed, then the signals are de-duplicated and delivered. Otherwise the signals are dropped.
 557 This means that the KDBX database will not fix broken references or mark itself dirty until after the
 558 transaction is committed.
 559
 560 How it works: With the beginning of a transaction, a snapshot of the object is created. In the event of
 561 a rollback, the object's data is replaced with data from the snapshot.
 562
 563 By default, the snapshot is shallow (i.e. does not include subroups, entries or historical entries). This
 564 means that only modifications to the object itself (its data, fields, strings, etc.) are atomic; modifications
 565 to subroups etc., including adding or removing items, are auto-committed instantly and will persist regardless
 566 of the result of the pending transaction. You can override this for groups, entries and history independently
 567 using options:
 568
 569 =for :list
 570 * C<entries> - If set, snapshot entries within a group, deeply (default: false)
 571 * C<groups> - If set, snapshot subroups within a group, deeply (default: false)
 572 * C<history> - If set, snapshot historical entries within an entry (default: false)
 573
 574 For example, if you begin a transaction on a group object using the C<entries> option, like this:
 575
 576     $group->begin_work(entries => 1);
 577
 578 Then if you modify any of the group's entries OR add new entries OR delete entries, all of that will be undone
 579 if the transaction is rolled back. With a default-configured transaction, however, changes to entries are kept
 580 even if the transaction is rolled back.
 581
 582 =cut
 583
 584 sub begin_work {
 585     my $self = shift;
 586
 587     if (defined wantarray) {
 588         require File::KDBX::Transaction;
 589         return File::KDBX::Transaction->new($self, @_);
 590     }
 591
 592     my %args = @_;
 593     my $orig = $args{snapshot} // do {
 594         my $c = $self->clone(
 595             entries => $args{entries} // 0,
 596             groups  => $args{groups}  // 0,
 597             history => $args{history} // 0,
 598         );
 599         $c->{entries} = $self->{entries} if !$args{entries};
 600         $c->{groups}  = $self->{groups}  if !$args{groups};
 601         $c->{history} = $self->{history} if !$args{history};
 602         $c;
 603     };
 604
 605     my $id = Hash::Util::FieldHash::id($orig);
 606     _save_references($id, $self, $orig);
 607
 608     $self->_signal_begin_work;
 609
 610     push @{$self->_txns}, $orig;
 611 }
 612
 613 =method commit
 614
 615     $object->commit;
 616
 617 Commit a transaction, making updates to C<$object> permanent. Returns itself to allow method chaining.
 618
 619 =cut
 620
 621 sub commit {
 622     my $self = shift;
 623     my $orig = pop @{$self->_txns} or return $self;
 624     $self->_commit($orig);
 625     my $signals = $self->_signal_commit;
 626     $self->_signal_send($signals) if !$self->_in_txn;
 627     return $self;
 628 }
 629
 630 =method rollback
 631
 632     $object->rollback;
 633
 634 Roll back the most recent transaction, throwing away any updates to the L</object> made since the transaction
 635 began. Returns itself to allow method chaining.
 636
 637 =cut
 638
 639 sub rollback {
 640     my $self = shift;
 641
 642     my $orig = pop @{$self->_txns} or return $self;
 643
 644     my $id = Hash::Util::FieldHash::id($orig);
 645     _restore_references($id, $orig);
 646
 647     $self->_signal_rollback;
 648
 649     return $self;
 650 }
 651
 652 # Get whether or not there is at least one pending transaction.
 653 sub _in_txn { scalar @{$_[0]->_txns} }
 654
 655 # Get an array ref of pending transactions.
 656 sub _txns   { $TXNS{$_[0]} //= [] }
 657
 658 # The _commit hook notifies subclasses that a commit has occurred.
 659 sub _commit { die 'Not implemented' }
 660
 661 # Get a reference to an object that represents an object's committed state. If there is no pending
 662 # transaction, this is just $self. If there is a transaction, this is the snapshot take before the transaction
 663 # began. This method is private because it provides direct access to the actual snapshot. It is important that
 664 # the snapshot not be changed or a rollback would roll back to an altered state.
 665 # This is used by File::KDBX::Dumper::XML so as to not dump uncommitted changes.
 666 sub _committed {
 667     my $self = shift;
 668     my ($orig) = @{$self->_txns};
 669     return $orig // $self;
 670 }
 671
 672 # In addition to cloning an object when beginning work, we also keep track its hashrefs and arrayrefs
 673 # internally so that we can restore to the very same structures in the case of a rollback.
 674 sub _save_references {
 675     my $id   = shift;
 676     my $self = shift;
 677     my $orig = shift;
 678
 679     if (is_plain_arrayref($orig)) {
 680         for (my $i = 0; $i < @$orig; ++$i) {
 681             _save_references($id, $self->[$i], $orig->[$i]);
 682         }
 683         $REFS{$id}{Hash::Util::FieldHash::id($orig)} = $self;
 684     }
 685     elsif (is_plain_hashref($orig) || (blessed $orig && $orig->isa(__PACKAGE__))) {
 686         for my $key (keys %$orig) {
 687             _save_references($id, $self->{$key}, $orig->{$key});
 688         }
 689         $REFS{$id}{Hash::Util::FieldHash::id($orig)} = $self;
 690     }
 691 }
 692
 693 # During a rollback, copy data from the snapshot back into the original internal structures.
 694 sub _restore_references {
 695     my $id   = shift;
 696     my $orig = shift // return;
 697     my $self = delete $REFS{$id}{Hash::Util::FieldHash::id($orig) // ''} // return $orig;
 698
 699     if (is_plain_arrayref($orig)) {
 700         @$self = map { _restore_references($id, $_) } @$orig;
 701     }
 702     elsif (is_plain_hashref($orig) || (blessed $orig && $orig->isa(__PACKAGE__))) {
 703         for my $key (keys %$orig) {
 704             # next if is_ref($orig->{$key}) &&
 705             #     (Hash::Util::FieldHash::id($self->{$key}) // 0) == Hash::Util::FieldHash::id($orig->{$key});
 706             $self->{$key} = _restore_references($id, $orig->{$key});
 707         }
 708     }
 709
 710     return $self;
 711 }
 712
 713 ##############################################################################
 714
 715 sub _signal {
 716     my $self = shift;
 717     my $type = shift;
 718
 719     if ($self->_in_txn) {
 720         my $stack = $self->_signal_stack;
 721         my $queue = $stack->[-1];
 722         push @$queue, [$type, @_];
 723     }
 724
 725     $self->_signal_send([[$type, @_]]);
 726
 727     return $self;
 728 }
 729
 730 sub _signal_stack { $SIGNALS{$_[0]} //= [] }
 731
 732 sub _signal_begin_work {
 733     my $self = shift;
 734     push @{$self->_signal_stack}, [];
 735 }
 736
 737 sub _signal_commit {
 738     my $self = shift;
 739     my $signals = pop @{$self->_signal_stack};
 740     my $previous = $self->_signal_stack->[-1] // [];
 741     push @$previous, @$signals;
 742     return $previous;
 743 }
 744
 745 sub _signal_rollback {
 746     my $self = shift;
 747     pop @{$self->_signal_stack};
 748 }
 749
 750 sub _signal_send {
 751     my $self    = shift;
 752     my $signals = shift // [];
 753
 754     my $kdbx = $KDBX{$self} or return;
 755
 756     # de-duplicate, keeping the most recent signal for each type
 757     my %seen;
 758     my @signals = grep { !$seen{$_->[0]}++ } reverse @$signals;
 759
 760     for my $sig (reverse @signals) {
 761         $kdbx->_handle_signal($self, @$sig);
 762     }
 763 }
 764
 765 ##############################################################################
 766
 767 sub _wrap_group {
 768     my $self  = shift;
 769     my $group = shift;
 770     require File::KDBX::Group;
 771     return File::KDBX::Group->wrap($group, $KDBX{$self});
 772 }
 773
 774 sub _wrap_entry {
 775     my $self  = shift;
 776     my $entry = shift;
 777     require File::KDBX::Entry;
 778     return File::KDBX::Entry->wrap($entry, $KDBX{$self});
 779 }
 780
 781 sub TO_JSON { +{%{$_[0]}} }
 782
 783 1;
 784 __END__
 785
 786 =for Pod::Coverage STORABLE_freeze STORABLE_thaw TO_JSON
 787
 788 =head1 DESCRIPTION
 789
 790 KDBX is an object database. This abstract class represents an object. You should not use this class directly
 791 but instead use its subclasses:
 792
 793 =for :list
 794 * L<File::KDBX::Entry>
 795 * L<File::KDBX::Group>
 796
 797 There is some functionality shared by both types of objects, and that's what this class provides.
 798
 799 Each object can be connected with a L<File::KDBX> database or be disconnected. A disconnected object exists in
 800 memory but will not be persisted when dumping a database. It is also possible for an object to be connected
 801 with a database but not be part of the object tree (i.e. is not the root group or any subroup or entry).
 802 A disconnected object or an object not part of the object tree of a database can be added to a database using
 803 one of:
 804
 805 =for :list
 806 * L<File::KDBX/add_entry>
 807 * L<File::KDBX/add_group>
 808 * L<File::KDBX::Group/add_entry>
 809 * L<File::KDBX::Group/add_group>
 810 * L<File::KDBX::Entry/add_historical_entry>
 811
 812 It is possible to copy or move objects between databases, but B<DO NOT> include the same object in more
 813 than one database at once or there could be some strange aliasing effects (i.e. changes in one database might
 814 effect another in unexpected ways). This could lead to difficult-to-debug problems. It is similarly not safe
 815 or valid to add the same object multiple times to the same database. For example:
 816
 817     my $entry = File::KDBX::Entry->(title => 'Whatever');
 818
 819     # DO NOT DO THIS:
 820     $kdbx->add_entry($entry);
 821     $another_kdbx->add_entry($entry);
 822
 823     # DO NOT DO THIS:
 824     $kdbx->add_entry($entry);
 825     $kdbx->add_entry($entry); # again
 826
 827 Instead, do this:
 828
 829     # Copy an entry to multiple databases:
 830     $kdbx->add_entry($entry);
 831     $another_kdbx->add_entry($entry->clone);
 832
 833     # OR move an existing entry from one database to another:
 834     $another_kdbx->add_entry($entry->remove);
 835
 836 =cut