Dogcows Code - chaz/p5-File-KDBX/blob - lib/File/KDBX/Error.pm

   1 package File::KDBX::Error;
   2 # ABSTRACT: Represents something bad that happened
   3
   4 use warnings;
   5 use strict;
   6
   7 use Exporter qw(import);
   8 use Scalar::Util qw(blessed);
   9 use namespace::clean -except => 'import';
  10
  11 our $VERSION = '999.999'; # VERSION
  12
  13 our @EXPORT = qw(alert error throw);
  14
  15 my $WARNINGS_CATEGORY;
  16 BEGIN {
  17     $WARNINGS_CATEGORY = 'File::KDBX';
  18     if (warnings->can('register_categories')) {
  19         warnings::register_categories($WARNINGS_CATEGORY);
  20     }
  21     else {
  22         eval qq{package $WARNINGS_CATEGORY; use warnings::register; 1}; ## no critic ProhibitStringyEval
  23     }
  24 }
  25
  26 use overload '""' => 'to_string', cmp => '_cmp';
  27
  28 =method new
  29
  30     $error = File::KDBX::Error->new($message, %details);
  31
  32 Construct a new error.
  33
  34 =cut
  35
  36 sub new {
  37     my $class = shift;
  38     my %args = @_ % 2 == 0 ? @_ : (_error => shift, @_);
  39
  40     my $error = delete $args{_error};
  41     my $e = $error;
  42     # $e =~ s/ at \H+ line \d+.*//g;
  43
  44     my $self = bless {
  45         details     => \%args,
  46         error      => $e // 'Something happened',
  47         errno      => $!,
  48         previous   => $@,
  49         trace      => do {
  50             require Carp;
  51             local $Carp::CarpInternal{''.__PACKAGE__} = 1;
  52             my $mess = $error =~ /at \H+ line \d+/ ? $error : Carp::longmess($error);
  53             [map { /^\h*(.*?)\.?$/ ? $1 : $_ } split(/\n/, $mess)];
  54         },
  55     }, $class;
  56     chomp $self->{error};
  57     return $self;
  58 }
  59
  60 =method error
  61
  62     $error = error($error);
  63     $error = error($message, %details);
  64     $error = File::KDBX::Error->error($error);
  65     $error = File::KDBX::Error->error($message, %details);
  66
  67 Wrap a thing to make it an error object. If the thing is already an error, it gets returned. Otherwise what is
  68 passed will be forwarded to L</new> to create a new error object.
  69
  70 This can be convenient for error handling when you're not sure what the exception is but you want to treat it
  71 as a B<File::KDBX::Error>. Example:
  72
  73     eval { ... };
  74     if (my $error = error(@_)) {
  75         if ($error->type eq 'key.missing') {
  76             handle_missing_key($error);
  77         }
  78         else {
  79             handle_other_error($error);
  80         }
  81     }
  82
  83 =cut
  84
  85 sub error {
  86     my $class = @_ && $_[0] eq __PACKAGE__ ? shift : undef;
  87     my $self = (blessed($_[0]) && $_[0]->isa('File::KDBX::Error'))
  88         ? shift
  89         : $class
  90             ? $class->new(@_)
  91             : __PACKAGE__->new(@_);
  92     return $self;
  93 }
  94
  95 =attr details
  96
  97     \%details = $error->details;
  98
  99 Get the error details.
 100
 101 =cut
 102
 103 sub details {
 104     my $self = shift;
 105     my %args = @_;
 106     my $details = $self->{details} //= {};
 107     @$details{keys %args} = values %args;
 108     return $details;
 109 }
 110
 111 sub errno { $_[0]->{errno} }
 112
 113 sub previous { $_[0]->{previous} }
 114
 115 sub trace { $_[0]->{trace} // [] }
 116
 117 sub type { $_[0]->details->{type} // '' }
 118
 119 =method to_string
 120
 121     $message = $error->to_string;
 122     $message = "$error";
 123
 124 Stringify an error.
 125
 126 This does not contain a stack trace, but you can set the C<DEBUG> environment
 127 variable to truthy to stringify the whole error object.
 128
 129 =cut
 130
 131 sub _cmp { "$_[0]" cmp "$_[1]" }
 132
 133 sub PROPAGATE {
 134     'wat';
 135 }
 136
 137 sub to_string {
 138     my $self = shift;
 139     # return "uh oh\n";
 140     my $msg = "$self->{trace}[0]";
 141     $msg .= '.' if $msg !~ /[\.\!\?]$/; # Why does this cause infinite recursion on some perls?
 142     # $msg .= '.' if $msg !~ /(?:\.|!|\?)$/;
 143     if ($ENV{DEBUG}) {
 144         require Data::Dumper;
 145         local $Data::Dumper::Indent = 1;
 146         local $Data::Dumper::Quotekeys = 0;
 147         local $Data::Dumper::Sortkeys = 1;
 148         local $Data::Dumper::Terse = 1;
 149         local $Data::Dumper::Trailingcomma = 1;
 150         local $Data::Dumper::Useqq = 1;
 151         $msg .= "\n" . Data::Dumper::Dumper $self;
 152     }
 153     $msg .= "\n" if $msg !~ /\n$/;
 154     return $msg;
 155 }
 156
 157 =method throw
 158
 159     File::KDBX::Error::throw($message, %details);
 160     $error->throw;
 161
 162 Throw an error.
 163
 164 =cut
 165
 166 sub throw {
 167     my $self = error(@_);
 168     die $self;
 169 }
 170
 171 =method warn
 172
 173     File::KDBX::Error::warn($message, %details);
 174     $error->warn;
 175
 176 Log a warning.
 177
 178 =cut
 179
 180 sub warn {
 181     return if !($File::KDBX::WARNINGS // 1);
 182
 183     my $self = error(@_);
 184
 185     # Use die and warn directly instead of warnings::warnif because the latter only provides the stringified
 186     # error to the warning signal handler (perl 5.34). Maybe that's a warnings.pm bug?
 187
 188     if (my $fatal = warnings->can('fatal_enabled_at_level')) {
 189         my $blame = _find_blame_frame();
 190         die $self if $fatal->($WARNINGS_CATEGORY, $blame);
 191     }
 192
 193     if (my $enabled = warnings->can('enabled_at_level')) {
 194         my $blame = _find_blame_frame();
 195         warn $self if $enabled->($WARNINGS_CATEGORY, $blame);
 196     }
 197     elsif ($enabled = warnings->can('enabled')) {
 198         warn $self if $enabled->($WARNINGS_CATEGORY);
 199     }
 200     else {
 201         warn $self;
 202     }
 203     return $self;
 204 }
 205
 206 =method alert
 207
 208     alert $error;
 209
 210 Importable alias for L</warn>.
 211
 212 =cut
 213
 214 sub alert { goto &warn }
 215
 216 sub _find_blame_frame {
 217     my $frame = 1;
 218     while (1) {
 219         my ($package) = caller($frame);
 220         last if !$package;
 221         return $frame - 1 if $package !~ /^\Q$WARNINGS_CATEGORY\E/;
 222         $frame++;
 223     }
 224     return 0;
 225 }
 226
 227 1;