Dogcows Code - chaz/p5-File-KDBX/blob - lib/File/KDBX/Error.pm

   1 package File::KDBX::Error;
   2 # ABSTRACT: Represents something bad that happened
   3
   4 use warnings;
   5 use strict;
   6
   7 use Exporter qw(import);
   8 use Scalar::Util qw(blessed);
   9 use namespace::clean -except => 'import';
  10
  11 our $VERSION = '999.999'; # VERSION
  12
  13 our @EXPORT = qw(alert error throw);
  14
  15 my $WARNINGS_CATEGORY;
  16 BEGIN {
  17     $WARNINGS_CATEGORY = 'File::KDBX';
  18     if (warnings->can('register_categories')) {
  19         warnings::register_categories($WARNINGS_CATEGORY);
  20     }
  21     else {
  22         eval qq{package $WARNINGS_CATEGORY; use warnings::register; 1}; ## no critic ProhibitStringyEval
  23     }
  24 }
  25
  26 use overload '""' => 'to_string', cmp => '_cmp';
  27
  28 =method new
  29
  30     $error = File::KDBX::Error->new($message, %details);
  31
  32 Construct a new error.
  33
  34 =cut
  35
  36 sub new {
  37     my $class = shift;
  38     my %args = @_ % 2 == 0 ? @_ : (_error => shift, @_);
  39
  40     my $error = delete $args{_error};
  41     my $e = $error;
  42     $e =~ s/ at \H+ line \d+.*//g;
  43
  44     my $self = bless {
  45         details     => \%args,
  46         error      => $e // 'Something happened',
  47         errno      => $!,
  48         previous   => $@,
  49         trace      => do {
  50             require Carp;
  51             local $Carp::CarpInternal{''.__PACKAGE__} = 1;
  52             my $mess = $error =~ /at \H+ line \d+/ ? $error : Carp::longmess($error);
  53             [map { /^\h*(.*?)\.?$/ ? $1 : $_ } split(/\n/, $mess)];
  54         },
  55     }, $class;
  56     chomp $self->{error};
  57     return $self;
  58 }
  59
  60 =method error
  61
  62     $error = error($error);
  63     $error = error($message, %details);
  64     $error = File::KDBX::Error->error($error);
  65     $error = File::KDBX::Error->error($message, %details);
  66
  67 Wrap a thing to make it an error object. If the thing is already an error, it gets returned. Otherwise what is
  68 passed will be forwarded to L</new> to create a new error object.
  69
  70 This can be convenient for error handling when you're not sure what the exception is but you want to treat it
  71 as a B<File::KDBX::Error>. Example:
  72
  73     eval { ... };
  74     if (my $error = error(@_)) {
  75         if ($error->type eq 'key.missing') {
  76             handle_missing_key($error);
  77         }
  78         else {
  79             handle_other_error($error);
  80         }
  81     }
  82
  83 =cut
  84
  85 sub error {
  86     my $class = @_ && $_[0] eq __PACKAGE__ ? shift : undef;
  87     my $self = (blessed($_[0]) && $_[0]->isa('File::KDBX::Error'))
  88         ? shift
  89         : $class
  90             ? $class->new(@_)
  91             : __PACKAGE__->new(@_);
  92     return $self;
  93 }
  94
  95 =attr details
  96
  97     \%details = $error->details;
  98
  99 Get the error details.
 100
 101 =cut
 102
 103 sub details {
 104     my $self = shift;
 105     my %args = @_;
 106     my $details = $self->{details} //= {};
 107     @$details{keys %args} = values %args;
 108     return $details;
 109 }
 110
 111 =attr errno
 112
 113 Get the value of C<errno> when the exception was created.
 114
 115 =cut
 116
 117 sub errno { $_[0]->{errno} }
 118
 119 =attr previous
 120
 121 Get the value of C<$@> (i.e. latest exception) at the time the exception was created.
 122
 123
 124 =cut
 125
 126 sub previous { $_[0]->{previous} }
 127
 128 =attr trace
 129
 130 Get a stack trace indicating where in the code the exception was created.
 131
 132 =cut
 133
 134 sub trace { $_[0]->{trace} // [] }
 135
 136 =attr type
 137
 138 Get the exception type, if any.
 139
 140 =cut
 141
 142 sub type { $_[0]->details->{type} // '' }
 143
 144 =method to_string
 145
 146     $message = $error->to_string;
 147     $message = "$error";
 148
 149 Stringify an error.
 150
 151 This does not contain a stack trace, but you can set the C<DEBUG> environment
 152 variable to truthy to stringify the whole error object.
 153
 154 =cut
 155
 156 sub _cmp { "$_[0]" cmp "$_[1]" }
 157
 158 sub to_string {
 159     my $self = shift;
 160     my $msg = "$self->{trace}[0]";
 161     $msg .= '.' if $msg !~ /[\.\!\?]$/;
 162     if ($ENV{DEBUG}) {
 163         require Data::Dumper;
 164         local $Data::Dumper::Indent = 1;
 165         local $Data::Dumper::Quotekeys = 0;
 166         local $Data::Dumper::Sortkeys = 1;
 167         local $Data::Dumper::Terse = 1;
 168         local $Data::Dumper::Trailingcomma = 1;
 169         local $Data::Dumper::Useqq = 1;
 170         $msg .= "\n" . Data::Dumper::Dumper $self;
 171     }
 172     $msg .= "\n" if $msg !~ /\n$/;
 173     return $msg;
 174 }
 175
 176 =method throw
 177
 178     File::KDBX::Error::throw($message, %details);
 179     $error->throw;
 180
 181 Throw an error.
 182
 183 =cut
 184
 185 sub throw {
 186     my $self = error(@_);
 187     die $self;
 188 }
 189
 190 =method warn
 191
 192     File::KDBX::Error::warn($message, %details);
 193     $error->warn;
 194
 195 Log a warning.
 196
 197 =cut
 198
 199 sub warn {
 200     return if !($File::KDBX::WARNINGS // 1);
 201
 202     my $self = error(@_);
 203
 204     # Use die and warn directly instead of warnings::warnif because the latter only provides the stringified
 205     # error to the warning signal handler (perl 5.34). Maybe that's a warnings.pm bug?
 206
 207     if (my $fatal = warnings->can('fatal_enabled_at_level')) {
 208         my $blame = _find_blame_frame();
 209         die $self if $fatal->($WARNINGS_CATEGORY, $blame);
 210     }
 211
 212     if (my $enabled = warnings->can('enabled_at_level')) {
 213         my $blame = _find_blame_frame();
 214         warn $self if $enabled->($WARNINGS_CATEGORY, $blame);
 215     }
 216     elsif ($enabled = warnings->can('enabled')) {
 217         warn $self if $enabled->($WARNINGS_CATEGORY);
 218     }
 219     else {
 220         warn $self;
 221     }
 222     return $self;
 223 }
 224
 225 =method alert
 226
 227     alert $error;
 228
 229 Importable alias for L</warn>.
 230
 231 =cut
 232
 233 sub alert { goto &warn }
 234
 235 sub _find_blame_frame {
 236     my $frame = 1;
 237     while (1) {
 238         my ($package) = caller($frame);
 239         last if !$package;
 240         return $frame - 1 if $package !~ /^\Q$WARNINGS_CATEGORY\E/;
 241         $frame++;
 242     }
 243     return 0;
 244 }
 245
 246 1;