Dogcows Code - chaz/openbox/blob - configure.ac

   1 AC_PREREQ([2.54])
   2 AC_INIT([openbox], [3.4.0], [http://bugzilla.icculus.org])
   3 AM_INIT_AUTOMAKE
   4 AC_CONFIG_SRCDIR([openbox/openbox.c])
   5
   6 dnl Making releases:
   7 dnl   OB_MICRO_VERSION += 1;
   8 dnl   OB_INTERFACE_AGE += 1;
   9 dnl   OB_BINARY_AGE += 1;
  10 dnl if any functions have been added, set OB_INTERFACE_AGE to 0.
  11 dnl if backwards compatibility has been broken,
  12 dnl set OB_BINARY_AGE and OB_INTERFACE_AGE to 0.
  13 dnl
  14 dnl if MAJOR or MINOR version changes, be sure to change AC_INIT above to match
  15 dnl
  16 OB_MAJOR_VERSION=3
  17 OB_MINOR_VERSION=4
  18 OB_MICRO_VERSION=6
  19 OB_INTERFACE_AGE=0
  20 OB_BINARY_AGE=0
  21 OB_VERSION=$OB_MAJOR_VERSION.$OB_MINOR_VERSION
  22
  23 AC_SUBST(OB_MAJOR_VERSION)
  24 AC_SUBST(OB_MINOR_VERSION)
  25 AC_SUBST(OB_MICRO_VERSION)
  26 AC_SUBST(OB_INTERFACE_AGE)
  27 AC_SUBST(OB_BINARY_AGE)
  28 AC_SUBST(OB_VERSION)
  29
  30 dnl Libtool versioning
  31 LT_RELEASE=$OB_MAJOR_VERSION.$OB_MINOR_VERSION
  32 LT_CURRENT=`expr $OB_MICRO_VERSION - $OB_INTERFACE_AGE`
  33 LT_REVISION=$OB_INTERFACE_AGE
  34 LT_AGE=`expr $OB_BINARY_AGE - $OB_INTERFACE_AGE`
  35 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  36
  37 AC_SUBST(LT_RELEASE)
  38 AC_SUBST(LT_CURRENT)
  39 AC_SUBST(LT_REVISION)
  40 AC_SUBST(LT_AGE)
  41 AC_SUBST(LT_CURRENT_MINUS_AGE)
  42
  43 AC_PREFIX_DEFAULT([/usr/local])
  44 test "$prefix" = "NONE" && prefix=$ac_default_prefix
  45
  46 dnl Determine build target
  47 OB_DEBUG
  48 dnl Pick compiler specific/build target flags, and set $CVS
  49 AM_PROG_CC_C_O
  50 OB_COMPILER_FLAGS
  51 AC_C_CONST
  52 AC_C_INLINE
  53
  54 AC_PROG_LIBTOOL
  55 AC_SUBST(LIBTOOL_DEPS)
  56 LIBTOOL="$LIBTOOL --silent"
  57
  58 AC_PROG_INSTALL
  59
  60 AM_GNU_GETTEXT_VERSION(0.12.1)
  61 AM_GNU_GETTEXT([external])
  62
  63 AC_CHECK_HEADERS(ctype.h fcntl.h locale.h signal.h string.h stdio.h stdlib.h)
  64 AC_CHECK_HEADERS(unistd.h sys/stat.h sys/select.h sys/time.h sys/wait.h)
  65 # AC_HEADER_TIME
  66 # AC_TYPE_SIGNAL
  67
  68 AC_PATH_PROG([SED], [sed], [no])
  69 if test "$SED" = "no"; then
  70   AC_MSG_ERROR([The program "sed" is not available. This program is required to build Openbox.])
  71 fi
  72
  73 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.6.0])
  74 AC_SUBST(GLIB_CFLAGS)
  75 AC_SUBST(GLIB_LIBS)
  76
  77 PKG_CHECK_MODULES(PANGO, [pango >= 1.8.0 pangoxft >= 1.8.0])
  78 AC_SUBST(PANGO_CFLAGS)
  79 AC_SUBST(PANGO_LIBS)
  80
  81 PKG_CHECK_MODULES(XML, [libxml-2.0])
  82 AC_SUBST(XML_CFLAGS)
  83 AC_SUBST(XML_LIBS)
  84
  85 AC_ARG_ENABLE(startup-notification,
  86   AC_HELP_STRING(
  87     [--enable-startup-notification],
  88     [enable the startup notification library. [[default=enabled]]]
  89   ),
  90   [enable_sn=$enableval],
  91   [enable_sn=yes]
  92 )
  93
  94 if test "$enable_sn" = yes; then
  95 PKG_CHECK_MODULES(LIBSN, [libstartup-notification-1.0],
  96   [
  97     AC_DEFINE(USE_LIBSN, [1], [Use startup-notification])
  98     AC_SUBST(LIBSN_CFLAGS)
  99     AC_SUBST(LIBSN_LIBS)
 100     sn_found=yes
 101   ],
 102   [
 103     sn_found=no
 104   ]
 105 )
 106 else
 107   sn_found=no
 108 fi
 109
 110 PKG_CHECK_MODULES(XCURSOR, [xcursor],
 111   [
 112     AC_DEFINE(USE_XCURSOR, [1], [Use X Cursor library])
 113     AC_SUBST(XCURSOR_CFLAGS)
 114     AC_SUBST(XCURSOR_LIBS)
 115     xcursor_found=yes
 116   ],
 117   [
 118     xcursor_found=no
 119   ]
 120 )
 121
 122 dnl Check for session management
 123 X11_SM
 124
 125 #EFENCE_LIBS=-lefence
 126 EFENCE_LIBS=""
 127 AC_SUBST(EFENCE_LIBS)
 128
 129 dnl Check for X11 extensions
 130 X11_EXT_XKB
 131 X11_EXT_XRANDR
 132 X11_EXT_SHAPE
 133 X11_EXT_XINERAMA
 134
 135 AC_CONFIG_FILES([
 136   Makefile
 137   m4/Makefile
 138   po/Makefile.in
 139   render/obrender-3.0.pc
 140   parser/obparser-3.0.pc
 141   version.h
 142 ])
 143 AC_OUTPUT
 144
 145 AC_MSG_RESULT
 146 AC_MSG_RESULT([Compiling with these options:
 147                Startup Notification... $sn_found
 148                X Cursor Library... $xcursor_found
 149                Session Management... $SM
 150                ])
 151 AC_MSG_RESULT([configure complete, now type "make"])