Dogcows Code - chaz/git-codeowners/blob - lib/App/Codeowners/Options.pm

   1 package App::Codeowners::Options;
   2 # ABSTRACT: Getopt and shell completion for App::Codeowners
   3
   4 use v5.10.1;
   5 use warnings;
   6 use strict;
   7
   8 use Encode qw(decode);
   9 use Getopt::Long 2.39 ();
  10 use Path::Tiny;
  11
  12 our $VERSION = '0.49'; # VERSION
  13
  14 sub pod2usage {
  15     eval { require Pod::Usage };
  16     if ($@) {
  17         my $ref  = $VERSION eq '9999.999' ? 'master' : "v$VERSION";
  18         my $exit = (@_ == 1 && $_[0] =~ /^\d+$/ && $_[0]) //
  19                    (@_ % 2 == 0 && {@_}->{'-exitval'})    // 2;
  20         print STDERR <<END;
  21 Online documentation is available at:
  22
  23   https://github.com/chazmcgarvey/git-codeowners/blob/$ref/README.md
  24
  25 Tip: To enable inline documentation, install the Pod::Usage module.
  26
  27 END
  28         exit $exit;
  29     }
  30     else {
  31         Pod::Usage::pod2usage(@_);
  32     }
  33 }
  34
  35 sub early_options {
  36     return {
  37         'color|colour!'         => (-t STDOUT ? 1 : 0), ## no critic (InputOutput::ProhibitInteractiveTest)
  38         'format|f=s'            => undef,
  39         'help|h|?'              => 0,
  40         'manual|man'            => 0,
  41         'shell-completion:s'    => undef,
  42         'version|v'             => 0,
  43     };
  44 }
  45
  46 sub command_options {
  47     return {
  48         'create'    => {},
  49         'owners'    => {
  50             'pattern=s' => '',
  51         },
  52         'patterns'  => {
  53             'owner=s'   => '',
  54         },
  55         'projects'  => {},
  56         'show'      => {
  57             'owner=s@'      => [],
  58             'pattern=s@'    => [],
  59             'project=s@'    => [],
  60             'patterns!'     => 0,
  61             'projects!'     => undef,
  62         },
  63         'update'    => {},
  64     };
  65 }
  66
  67 sub commands {
  68     my $self = shift;
  69     my @commands = sort keys %{$self->command_options};
  70     return @commands;
  71 }
  72
  73 sub options {
  74     my $self = shift;
  75     my @command_options;
  76     if (my $command = $self->{command}) {
  77         @command_options = keys %{$self->command_options->{$command} || {}};
  78     }
  79     return (keys %{$self->early_options}, @command_options);
  80 }
  81
  82 sub new {
  83     my $class = shift;
  84     my @args  = @_;
  85
  86     # assume UTF-8 args if non-ASCII
  87     @args = map { decode('UTF-8', $_) } @args if grep { /\P{ASCII}/ } @args;
  88
  89     my $self = bless {}, $class;
  90
  91     my @args_copy = @args;
  92
  93     my $opts = $self->get_options(
  94         args    => \@args,
  95         spec    => $self->early_options,
  96         config  => 'pass_through',
  97     ) or pod2usage(2);
  98
  99     if ($ENV{CODEOWNERS_COMPLETIONS}) {
 100         $self->{command} = $args[0] || '';
 101         my $cword = $ENV{CWORD};
 102         my $cur   = $ENV{CUR} || '';
 103         # Adjust cword to remove progname
 104         while (0 < --$cword) {
 105             last if $cur eq ($args_copy[$cword] || '');
 106         }
 107         $self->completions($cword, @args_copy);
 108         exit 0;
 109     }
 110
 111     if ($opts->{version}) {
 112         my $progname = path($0)->basename;
 113         print "${progname} ${VERSION}\n";
 114         exit 0;
 115     }
 116     if ($opts->{help}) {
 117         pod2usage(-exitval => 0, -verbose => 99, -sections => [qw(NAME SYNOPSIS OPTIONS COMMANDS)]);
 118     }
 119     if ($opts->{manual}) {
 120         pod2usage(-exitval => 0, -verbose => 2);
 121     }
 122     if (defined $opts->{shell_completion}) {
 123         $self->shell_completion($opts->{shell_completion});
 124         exit 0;
 125     }
 126
 127     # figure out the command (or default to "show")
 128     my $command = shift @args;
 129     my $command_options = $self->command_options->{$command || ''};
 130     if (!$command_options) {
 131         unshift @args, $command if defined $command;
 132         $command = 'show';
 133         $command_options = $self->command_options->{$command};
 134     }
 135
 136     my $more_opts = $self->get_options(
 137         args    => \@args,
 138         spec    => $command_options,
 139     ) or pod2usage(2);
 140
 141     %$self = (%$opts, %$more_opts, command => $command, args => \@args);
 142     return $self;
 143 }
 144
 145 sub command {
 146     my $self = shift;
 147     my $command = $self->{command};
 148     my @commands = sort keys %{$self->command_options};
 149     return if not grep { $_ eq $command } @commands;
 150     $command =~ s/[^a-z]/_/g;
 151     return $command;
 152 }
 153
 154 sub args {
 155     my $self = shift;
 156     return @{$self->{args} || []};
 157 }
 158
 159
 160 sub get_options {
 161     my $self = shift;
 162     my $args = {@_ == 1 && ref $_[0] eq 'HASH' ? %{$_[0]} : @_};
 163
 164     my %options;
 165     my %results;
 166     while (my ($opt, $default_value) = each %{$args->{spec}}) {
 167         my ($name) = $opt =~ /^([^=:!|]+)/;
 168         $name =~ s/-/_/g;
 169         $results{$name} = $default_value;
 170         $options{$opt}  = \$results{$name};
 171     }
 172
 173     if (my $fn = $args->{callback}) {
 174         $options{'<>'} = sub {
 175             my $arg = shift;
 176             $fn->($arg, \%results);
 177         };
 178     }
 179
 180     my $p = Getopt::Long::Parser->new;
 181     $p->configure($args->{config} || 'default');
 182     return if !$p->getoptionsfromarray($args->{args}, %options);
 183
 184     return \%results;
 185 }
 186
 187
 188 sub shell_completion {
 189     my $self = shift;
 190     my $type = lc(shift || 'bash');
 191
 192     if ($type eq 'bash') {
 193     print <<'END';
 194 # git-codeowners - Bash completion
 195 # To use, eval this code:
 196 #   eval "$(git-codeowners --shell-completion)"
 197 # This will work without the bash-completion package, but handling of colons
 198 # in the completion word will work better with bash-completion installed and
 199 # enabled.
 200 _git_codeowners() {
 201     local cur words cword
 202     if declare -f _get_comp_words_by_ref >/dev/null
 203     then
 204         _get_comp_words_by_ref -n : cur cword words
 205     else
 206         words=("${COMP_WORDS[@]}")
 207         cword=${COMP_CWORD}
 208         cur=${words[cword]}
 209     fi
 210     local IFS=$'\n'
 211     COMPREPLY=($(CODEOWNERS_COMPLETIONS=1 CWORD="$cword" CUR="$cur" ${words[@]}))
 212     # COMPREPLY=($(${words[0]} --completions "$cword" "${words[@]}"))
 213     if [[ "$?" -eq 9 ]]
 214     then
 215         COMPREPLY=($(compgen -A "${COMPREPLY[0]}" -- "$cur"))
 216     fi
 217     declare -f __ltrim_colon_completions >/dev/null && \
 218         __ltrim_colon_completions "$cur"
 219     return 0
 220 }
 221 complete -F _git_codeowners git-codeowners
 222 END
 223     }
 224     else {
 225         # TODO - Would be nice to support Zsh
 226         warn "No such shell completion: $type\n";
 227     }
 228 }
 229
 230
 231 sub completions {
 232     my $self    = shift;
 233     my $cword   = shift;
 234     my @words   = @_;
 235
 236     my $current = $words[$cword]     || '';
 237     my $prev    = $words[$cword - 1] || '';
 238
 239     my $reply;
 240
 241     if ($prev eq '--format' || $prev eq '-f') {
 242         $reply = $self->_completion_formats;
 243     }
 244     elsif ($current =~ /^-/) {
 245         $reply = $self->_completion_options;
 246     }
 247     else {
 248         if (!$self->command) {
 249             $reply = [$self->commands, @{$self->_completion_options([keys %{$self->early_options}])}];
 250         }
 251         else {
 252             print 'file';
 253             exit 9;
 254         }
 255     }
 256
 257     local $, = "\n";
 258     print grep { /^\Q$current\E/ } @$reply;
 259     exit 0;
 260 }
 261
 262 sub _completion_options {
 263     my $self = shift;
 264     my $opts = shift || [$self->options];
 265
 266     my @options;
 267
 268     for my $option (@$opts) {
 269         my ($names, $op, $vtype) = $option =~ /^([^=:!]+)([=:!]?)(.*)$/;
 270         my @names = split(/\|/, $names);
 271
 272         for my $name (@names) {
 273             if ($op eq '!') {
 274                 push @options, "--$name", "--no-$name";
 275             }
 276             else {
 277                 if (length($name) > 1) {
 278                     push @options, "--$name";
 279                 }
 280                 else {
 281                     push @options, "-$name";
 282                 }
 283             }
 284         }
 285     }
 286
 287     return [sort @options];
 288 }
 289
 290 sub _completion_formats { [qw(csv json json:pretty tsv yaml)] }
 291
 292 1;
 293
 294 __END__
 295
 296 =pod
 297
 298 =encoding UTF-8
 299
 300 =head1 NAME
 301
 302 App::Codeowners::Options - Getopt and shell completion for App::Codeowners
 303
 304 =head1 VERSION
 305
 306 version 0.49
 307
 308 =head1 METHODS
 309
 310 =head2 get_options
 311
 312     $options = $options->get_options(
 313         args     => \@ARGV,
 314         spec     => \@expected_options,
 315         callback => sub { my ($arg, $results) = @_; ... },
 316     );
 317
 318 Convert command-line arguments to options, based on specified rules.
 319
 320 Returns a hashref of options or C<undef> if an error occurred.
 321
 322 =over 4
 323
 324 =item *
 325
 326 C<args> - Arguments from the caller (e.g. C<@ARGV>).
 327
 328 =item *
 329
 330 C<spec> - List of L<Getopt::Long> compatible option strings.
 331
 332 =item *
 333
 334 C<callback> - Optional coderef to call for non-option arguments.
 335
 336 =item *
 337
 338 C<config> - Optional L<Getopt::Long> configuration string.
 339
 340 =back
 341
 342 =head2 shell_completion
 343
 344     $options->shell_completion($shell_type);
 345
 346 Print shell code to C<STDOUT> for the given type of shell. When eval'd, the shell code enables
 347 completion for the F<git-codeowners> command.
 348
 349 =head2 completions
 350
 351     $options->completions($current_arg_index, @args);
 352
 353 Print completions to C<STDOUT> for the given argument list and cursor position, and exit.
 354
 355 May also exit with status 9 and a compgen action printed to C<STDOUT> to indicate that the shell
 356 should generate its own completions.
 357
 358 Doesn't return.
 359
 360 =head1 BUGS
 361
 362 Please report any bugs or feature requests on the bugtracker website
 363 L<https://github.com/chazmcgarvey/git-codeowners/issues>
 364
 365 When submitting a bug or request, please include a test-file or a
 366 patch to an existing test-file that illustrates the bug or desired
 367 feature.
 368
 369 =head1 AUTHOR
 370
 371 Charles McGarvey <chazmcgarvey@brokenzipper.com>
 372
 373 =head1 COPYRIGHT AND LICENSE
 374
 375 This software is copyright (c) 2019 by Charles McGarvey.
 376
 377 This is free software; you can redistribute it and/or modify it under
 378 the same terms as the Perl 5 programming language system itself.
 379
 380 =cut