+=func extends
+
+ extends $class;
+
+Set up the current module to inheret from another module.
+
+=cut
+
+sub extends {
+ my $parent = shift;
+ my $caller = caller;
+ load $parent;
+ no strict 'refs'; ## no critic (ProhibitNoStrict)
+ @{"${caller}::ISA"} = $parent;
+}
+
+=func has
+
+ has $name => %options;
+
+Create an attribute getter/setter. Possible options:
+
+=for :list
+* C<is> - Either "rw" (default) or "ro"
+* C<default> - Default value
+* C<coerce> - Coercive function
+
+=cut
+
+sub has {
+ my $name = shift;
+ my %args = @_ % 2 == 1 ? (default => shift, @_) : @_;
+
+ my $d = $args{default};
+ my $default = is_arrayref($d) ? sub { [%$d] } : is_hashref($d) ? sub { +{%$d} } : $d;
+ my $coerce = $args{coerce};
+ my $is = $args{is} || 'rw';
+
+ my $has_default = is_coderef $default;
+ my $has_coerce = is_coderef $coerce;
+
+ my $caller = caller;
+ no strict 'refs'; ## no critic (ProhibitNoStrict)
+ if (my $store = $args{store}) {
+ *{"${caller}::${name}"} = $is eq 'ro' && $has_default ? sub {
+ $_[0]->$store->{$name} //= scalar $default->($_[0]);
+ } : $is eq 'ro' ? sub {
+ $_[0]->$store->{$name} //= $default;
+ } : $has_default && $has_coerce ? sub {
+ $#_ ? $_[0]->$store->{$name} = scalar $coerce->($_[1])
+ : $_[0]->$store->{$name} //= scalar $default->($_[0]);
+ } : $has_default ? sub {
+ $#_ ? $_[0]->$store->{$name} = $_[1]
+ : $_[0]->$store->{$name} //= scalar $default->($_[0]);
+ } : $has_coerce ? sub {
+ $#_ ? $_[0]->$store->{$name} = scalar $coerce->($_[1])
+ : $_[0]->$store->{$name} //= $default;
+ } : sub {
+ $#_ ? $_[0]->$store->{$name} = $_[1]
+ : $_[0]->$store->{$name} //= $default;
+ };
+ }
+ else {
+ *{"${caller}::${name}"} = $is eq 'ro' && $has_default ? sub {
+ $_[0]->{$name} //= scalar $default->($_[0]);
+ } : $is eq 'ro' ? sub {
+ $_[0]->{$name} //= $default;
+ } : $has_default && $has_coerce ? sub {
+ $#_ ? $_[0]->{$name} = scalar $coerce->($_[1])
+ : $_[0]->{$name} //= scalar $default->($_[0]);
+ } : $has_default ? sub {
+ $#_ ? $_[0]->{$name} = $_[1]
+ : $_[0]->{$name} //= scalar $default->($_[0]);
+ } : $has_coerce ? sub {
+ $#_ ? $_[0]->{$name} = scalar $coerce->($_[1])
+ : $_[0]->{$name} //= $default;
+ } : sub {
+ $#_ ? $_[0]->{$name} = $_[1]
+ : ($_[0]->{$name} //= $default);
+ };
+ }
+}
+