Dogcows Code - chaz/openbox/blob - configure.in

   1 dnl configure.in for Openbox
   2 dnl Initialize autoconf and automake
   3 AC_INIT(src/blackbox.cc)
   4 AM_INIT_AUTOMAKE(openbox,2.0.0,no-define)
   5
   6 dnl Determine default prefix
   7 test x$prefix = "xNONE" && prefix="$ac_default_prefix"
   8
   9 dnl Check for various flavors of UNIX(r)
  10 dnl AC_AIX
  11 dnl AC_ISC_POSIX
  12
  13 dnl Locate required external software
  14 AC_PROG_CC
  15 AC_PROG_CXX
  16 AC_PROG_INSTALL
  17
  18 AC_CHECK_PROGS(regex_cmd, sed)
  19 if test x$regex_cmd = "x"; then
  20   AC_MSG_ERROR([error. sed is required to build the default menu file.])
  21 fi
  22
  23 dnl Check for system header files
  24 AC_CHECK_HEADERS(ctype.h dirent.h fcntl.h libgen.h locale.h nl_types.h process.h signal.h stdarg.h stdio.h string.h stdlib.h time.h unistd.h sys/param.h sys/select.h sys/signal.h sys/stat.h sys/time.h sys/types.h sys/wait.h)
  25 AC_HEADER_TIME
  26
  27 dnl Check for existance of basename(), setlocale() and strftime()
  28 AC_CHECK_FUNCS(basename, , AC_CHECK_LIB(gen, basename,
  29                           AC_DEFINE(HAVE_BASENAME) LIBS="$LIBS -lgen"))
  30 AC_CHECK_FUNCS(getpid setlocale sigaction strftime strcasestr snprintf vsnprintf catopen catgets catclose)
  31 AC_CHECK_LIB(nsl, t_open, LIBS="$LIBS -lnsl")
  32 AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
  33
  34 dnl Check for X headers and libraries
  35 AC_PATH_X
  36 AC_PATH_XTRA
  37
  38 test x$no_x = "xyes" && AC_MSG_ERROR([Openbox requires the X Window System libraries and headers.])
  39
  40 test x$x_includes = "x" && x_includes="/usr/include"
  41 test x$x_libraries = "x" && x_libraries="/usr/lib"
  42
  43 CFLAGS="$CFLAGS $X_CFLAGS"
  44 CXXFLAGS="$CXXFLAGS $X_CFLAGS"
  45 LIBS="$LIBS $X_LIBS"
  46 LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
  47
  48 dnl Check for required functions in -lX11
  49 AC_CHECK_LIB(X11, XOpenDisplay,
  50   LIBS="$LIBS -lX11",
  51   AC_MSG_ERROR([Could not find XOpenDisplay in -lX11.])
  52 )
  53
  54 LIBS="$LIBS $X_EXTRA_LIBS"
  55
  56 dnl Check for XShape extension support and proper library files.
  57 SHAPE=""
  58 AC_MSG_CHECKING([whether to build support for the XShape extension])
  59 AC_ARG_ENABLE(
  60   shape, [  --enable-shape          enable support of the XShape extension [default=yes]])
  61
  62 : ${enableval="yes"}
  63 if test x$enableval = "xyes"; then
  64   AC_MSG_RESULT([yes])
  65   AC_CHECK_LIB(Xext, XShapeCombineShape,
  66         AC_MSG_CHECKING([for X11/extensions/shape.h])
  67         AC_TRY_LINK(
  68 #include <X11/Xlib.h>
  69 #include <X11/Xutil.h>
  70 #include <X11/extensions/shape.h>
  71 , long foo = ShapeSet,
  72           AC_MSG_RESULT([yes])
  73           SHAPE="yes",
  74           AC_MSG_RESULT([no])
  75         )
  76   )
  77 else
  78   AC_MSG_RESULT([no])
  79 fi
  80 if test x$SHAPE = "xyes"; then
  81   LIBS="$LIBS -lXext"
  82   AC_DEFINE(SHAPE,1,Enable support of the XShape extension)
  83 fi
  84
  85 dnl Check for Xinerama extension support and proper library files.
  86 XINERAMA=""
  87 AC_MSG_CHECKING([whether to build support for the Xinerama extension])
  88 AC_ARG_ENABLE(
  89   xinerama, [  --enable-xinerama       enable support of the Xinerama extension [default=no]],
  90   if test x$enableval = "xyes"; then
  91         AC_MSG_RESULT([yes])
  92
  93         AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
  94           AC_MSG_CHECKING([for X11/extensions/Xinerama.h])
  95           AC_TRY_LINK(
  96 #include <X11/Xlib.h>
  97 #include <X11/extensions/Xinerama.h>
  98 , XineramaScreenInfo foo,
  99                 AC_MSG_RESULT([yes])
 100                 XINERAMA="yes"
 101                 LIBS="$LIBS -lXinerama",
 102                 AC_MSG_RESULT([no])
 103           )
 104         )
 105
 106   else
 107         AC_MSG_RESULT([no])
 108   fi,
 109   AC_MSG_RESULT([no])
 110 )
 111 if test x$XINERAMA = "xyes"; then
 112   AC_DEFINE(XINERAMA,1,Enable support of the Xinerama extension)
 113 fi
 114
 115 dnl Check for Xft extension support and proper library files.
 116 XFT=""
 117 AC_MSG_CHECKING([whether to build support for the Xft extension])
 118 AC_ARG_ENABLE(
 119   xft, [  --enable-xft            enable support of the Xft extension [default=no]],
 120   if test x$enableval = "xyes"; then
 121         AC_MSG_RESULT([yes])
 122
 123         AC_CHECK_LIB(Xft, XftFontOpenXlfd,
 124           AC_MSG_CHECKING([for X11/Xft/Xft.h])
 125           AC_TRY_LINK(
 126 #include <X11/Xlib.h>
 127 #include <X11/Xft/Xft.h>
 128 , XftFont foo,
 129         AC_MSG_RESULT([yes])
 130             XFT="yes"
 131                 LIBS="$LIBS -lXft",
 132         AC_MSG_RESULT([no])
 133           )
 134     )
 135
 136   else
 137         AC_MSG_RESULT([no])
 138   fi,
 139   AC_MSG_RESULT([no])
 140 )
 141 if test x$XFT = "xyes"; then
 142   AC_DEFINE(XFT,1,Enable support of the Xft extension)
 143 fi
 144
 145 dnl Check for ordered 8bpp dithering
 146 ORDEREDPSEUDO=""
 147 AC_MSG_CHECKING([whether to include Pseudocolor ordered dithering code])
 148 AC_ARG_ENABLE(ordered-pseudo,
 149 [  --enable-ordered-pseudo include code for ordered pseudocolor (8bpp)
 150                           dithering [default=no]],
 151   if test x$enableval = "xyes"; then
 152     AC_MSG_RESULT([yes])
 153     ORDEREDPSEUDO="yes"
 154   else
 155     AC_MSG_RESULT([no])
 156   fi,
 157   AC_MSG_RESULT([no])
 158 )
 159 if test x$ORDEREDPSEUDO = "xyes"; then
 160   AC_DEFINE(ORDEREDPSEUDO,1,Enable pseudocolor ordered dithering)
 161 fi
 162
 163 dnl Check whether to include debugging code
 164 DEBUG=""
 165 AC_MSG_CHECKING([whether to include verbose debugging code])
 166 AC_ARG_ENABLE(debug,
 167   [  --enable-debug          include verbose debugging code [default=no]],
 168   if test x$enableval = "xyes"; then
 169     AC_MSG_RESULT([yes])
 170     DEBUG="-DDEBUG -Wall -W -fno-inline"
 171   else
 172     AC_MSG_RESULT([no])
 173     DEBUG="-DNDEBUG"
 174   fi,
 175   AC_MSG_RESULT([no])
 176   DEBUG="-DNDEBUG"
 177 )
 178 AC_SUBST(DEBUG)
 179
 180 dnl Check whether to include natural language support (i18n)
 181 NLS=""
 182 AC_MSG_CHECKING([whether to include NLS support])
 183 AC_ARG_ENABLE(nls,
 184   [  --enable-nls            include natural language support [default=yes]],
 185   if test x$enableval = "xyes"; then
 186     AC_MSG_RESULT([yes])
 187     NLS="yes"
 188   else
 189     AC_MSG_RESULT([no])
 190   fi,
 191   AC_MSG_RESULT([yes])
 192   NLS="yes"
 193 )
 194
 195 AC_CHECK_LIB(xpg4, setlocale, LIBS="$LIBS -lxpg4")
 196
 197 AC_CHECK_PROGS(gencat_cmd, gencat)
 198 if test x$gencat_cmd = "x"; then
 199   NLS=""
 200 fi
 201
 202 if test x$NLS = "xyes"; then
 203   AC_DEFINE(NLS,1,Include natural language support)
 204   AC_SUBST(NLS)
 205 fi
 206
 207 dnl Check for new timed pixmap cache
 208 TIMEDCACHE=""
 209 AC_MSG_CHECKING([whether to use the timed pixmap cache])
 210 AC_ARG_ENABLE(
 211   timed-cache,
 212 [  --enable-timed-cache    use timed pixmap cache [default=yes]],
 213   if test x$enableval = "xyes"; then
 214     AC_MSG_RESULT([yes])
 215     TIMEDCACHE="yes"
 216   else
 217     AC_MSG_RESULT([no])
 218   fi,
 219   AC_MSG_RESULT([yes])
 220   TIMEDCACHE="yes"
 221 )
 222 if test x$TIMEDCACHE = "xyes"; then
 223   AC_DEFINE(TIMEDCACHE,1,Use timed pixmap cache)
 224 fi
 225
 226 dnl Determine the return type of signal handlers
 227 AC_TYPE_SIGNAL
 228
 229 dnl Determine if maintainer portions of the Makefiles should be included.
 230 AM_MAINTAINER_MODE
 231
 232 dnl Print results
 233 AC_MSG_RESULT([])
 234 AC_MSG_RESULT([ $PACKAGE version $VERSION configured successfully.])
 235 AC_MSG_RESULT([])
 236 AC_MSG_RESULT([Using '$prefix' for installation.])
 237 AC_MSG_RESULT([Using '$CXX' for C++ compiler.])
 238 AC_MSG_RESULT([Building with '$CXXFLAGS' for C++ compiler flags.])
 239 AC_MSG_RESULT([Building with '$LIBS' for linker flags.])
 240 AC_MSG_RESULT([])
 241
 242 dnl Output files
 243 AM_CONFIG_HEADER(config.h)
 244 AC_OUTPUT(Makefile
 245 src/Makefile
 246 util/Makefile
 247 util/epist/Makefile
 248 data/Makefile
 249 data/styles/Makefile
 250 doc/Makefile
 251 nls/Makefile
 252 nls/C/Makefile
 253 nls/da_DK/Makefile
 254 nls/de_DE/Makefile
 255 nls/es_ES/Makefile
 256 nls/et_EE/Makefile
 257 nls/fr_FR/Makefile
 258 nls/hu_HU/Makefile
 259 nls/it_IT/Makefile
 260 nls/ja_JP/Makefile
 261 nls/ko_KR/Makefile
 262 nls/no_NO/Makefile
 263 nls/nl_NL/Makefile
 264 nls/pt_BR/Makefile
 265 nls/ro_RO/Makefile
 266 nls/ru_RU/Makefile
 267 nls/sl_SI/Makefile
 268 nls/sv_SE/Makefile
 269 nls/tr_TR/Makefile
 270 nls/uk_UA/Makefile
 271 nls/zh_CN/Makefile
 272 nls/zh_TW/Makefile
 273 version.h)