Dogcows Code - chaz/openbox/blob - configure.ac

   1 AC_INIT([src/main.cc])
   2 AM_CONFIG_HEADER(config.h)
   3 AM_INIT_AUTOMAKE([openbox], [2.90.0cvs])
   4
   5 AC_PREREQ([2.50])
   6
   7 AC_PATH_PROG([regex_cmd], [sed])
   8 test -z $regex_cmd && AC_MSG_ERROR([sed not found])
   9
  10 AC_PROG_CC
  11 AC_PROG_CXX
  12 AC_PROG_LIBTOOL
  13 LIBTOOL="$LIBTOOL --silent"
  14 AC_PROG_INSTALL
  15
  16 ALL_LINGUAS=""
  17 AM_GNU_GETTEXT
  18
  19 AC_LANG(C++)
  20
  21 dnl Check what compiler we are using
  22 AC_MSG_CHECKING([for GCC])
  23 if test "$GCC" = "yes"; then
  24   AC_MSG_RESULT([yes])
  25   CPPFLAGS="$CPPFLAGS -Wall -W -pedantic"
  26 else
  27   AC_MSG_RESULT([no, trying other compilers])
  28   AC_MSG_CHECKING(for MIPSpro)
  29   mips_pro_ver=`$CXX -version 2>&1 | grep -i mipspro | cut -f4 -d ' '`
  30   if test -z "$mips_pro_ver"; then
  31     AC_MSG_RESULT([no])
  32   else
  33     AC_MSG_RESULT([yes, version $mips_pro_ver.])
  34     AC_MSG_CHECKING(for -LANG:std in CPPFLAGS)
  35     lang_std_not_set=`echo $CPPFLAGS | grep "\-LANG:std"`
  36     if test "x$lang_std_not_set" = "x"; then
  37       AC_MSG_RESULT([not set, setting.])
  38       CPPFLAGS="${CPPFLAGS} -LANG:std"
  39     else
  40       AC_MSG_RESULT([already set.])
  41     fi
  42   fi
  43 fi
  44
  45 dnl Determine if maintainer portions of the Makefiles should be included.
  46 AM_MAINTAINER_MODE
  47
  48 dnl Check for system header files
  49 AC_CHECK_HEADERS(ctype.h dirent.h fcntl.h libgen.h locale.h nl_types.h process.h signal.h stdarg.h stdio.h stdlib.h string.h time.h unistd.h sys/param.h sys/select.h sys/signal.h sys/stat.h sys/time.h sys/types.h sys/wait.h)
  50 AC_HEADER_TIME
  51
  52 dnl Determine the return type of signal handlers
  53 AC_TYPE_SIGNAL
  54
  55 dnl Check whether to include debugging code
  56 DEBUG=""
  57 AC_MSG_CHECKING([whether to include verbose debugging code])
  58 AC_ARG_ENABLE([debug],
  59   [  --enable-debug          include verbose debugging code @<:@default=no@:>@],
  60   if test "$enableval" = "yes"; then
  61     AC_MSG_RESULT([yes])
  62     if test "$GCC" = "yes"; then
  63        DEBUG="-DDEBUG -fno-inline -g"
  64     else
  65        DEBUG="-DDEBUG"
  66     fi
  67   else
  68     AC_MSG_RESULT([no])
  69     DEBUG="-DNDEBUG"
  70   fi,
  71   AC_MSG_RESULT([no])
  72   DEBUG="-DNDEBUG"
  73 )
  74 CPPFLAGS="$CPPFLAGS $DEBUG"
  75
  76 dnl Check for X headers and libraries
  77 AC_PATH_X
  78 AC_PATH_XTRA
  79 test "$no_x" = "yes" && AC_MSG_ERROR([No Xlibs found.])
  80 test -z "$x_includes" && x_includes="/usr/include"
  81 test -z "$x_libraries" && x_libraries="/usr/lib"
  82
  83 CPPFLAGS="$CPPFLAGS $X_CPPFLAGS"
  84 LIBS="$LIBS $X_LIBS $X_EXTRA_LIBS"
  85 LDFLAGS="$LDFLAGS $X_PRE_LIBS $LIBS $X_EXTRA_LIBS"
  86
  87 dnl Check for required functions in -lX11
  88 AC_CHECK_LIB([X11], [XOpenDisplay],
  89   ,
  90   AC_MSG_ERROR([Could not find XOpenDisplay in -lX11.])
  91 )
  92
  93
  94 dnl Check for Xft2
  95 AC_MSG_CHECKING([for Xft version 2])
  96 dnl Store these
  97 OLDLIBS=$LIBS
  98 OLDCPPFLAGS=$CPPFLAGS
  99 XFT2=""
 100 XFT_CFLAGS=""
 101 XFT_LIBS=""
 102 if pkg-config xft; then
 103   AC_MSG_RESULT([yes])
 104   XFT_CFLAGS="`pkg-config --cflags xft`"
 105   XFT_LIBS="`pkg-config --libs xft`"
 106
 107   dnl Set these for checking with the tests below. They'll be restored after
 108   LIBS="$LIBS $XFT_LIBS"
 109   CPPFLAGS="$XFT_CFLAGS $CPPFLAGS"
 110 else
 111   dnl This is for Xft version 1
 112   XFT_LIBS="-lXft"
 113   AC_MSG_RESULT([no])
 114 fi
 115
 116 AC_CHECK_LIB([Xft], [XftFontOpenXlfd],
 117   AC_MSG_CHECKING([for X11/Xft/Xft.h])
 118   AC_TRY_LINK(
 119     [
 120       #include <X11/Xlib.h>
 121       #include <X11/Xft/Xft.h>
 122     ],
 123     [
 124       XftFont foo
 125     ],
 126     [
 127       AC_MSG_RESULT([yes])
 128     ],
 129     [
 130       AC_MSG_RESULT([no])
 131       AC_MSG_ERROR([Openbox requires the Xft font library.
 132 See http://www.fontconfig.org/
 133 ])
 134     ]
 135   )
 136 )
 137 dnl Restore the old values. Use XFT_CFLAGS and XFT_LIBS in the Makefile.am's
 138 LIBS=$OLDLIBS
 139 CPPFLAGS=$OLDCPPFLAGS
 140
 141 AC_SUBST([XFT_CFLAGS])
 142 AC_SUBST([XFT_LIBS])
 143
 144 dnl Check for XShape extension support
 145 AC_CHECK_LIB([Xext], [XShapeCombineShape],
 146   AC_MSG_CHECKING([for X11/extensions/shape.h])
 147   AC_TRY_LINK(
 148     [
 149       #include <X11/Xlib.h>
 150       #include <X11/Xutil.h>
 151       #include <X11/extensions/shape.h>
 152     ],
 153     [
 154       long foo = ShapeSet
 155     ],
 156     [
 157       AC_MSG_RESULT([yes])
 158       SHAPE="yes"
 159       AC_DEFINE([SHAPE], [1], [Found the XShape extension])
 160       LIBS="$LIBS -lXext"
 161     ],
 162     [
 163       AC_MSG_RESULT([no])
 164       SHAPE="no"
 165     ]
 166   )
 167 )
 168 AC_MSG_CHECKING([for the XShape extension])
 169 if test "$SHAPE" = "yes"; then
 170   AC_MSG_RESULT([yes])
 171 else
 172   AC_MSG_RESULT([no])
 173 fi
 174
 175 dnl Check for Xinerama extension support
 176 AC_MSG_CHECKING([whether to build support for the Xinerama extension])
 177 XINERAMA="no"
 178 AC_ARG_ENABLE([xinerama],
 179 [  --enable-xinerama       enable support of the Xinerama extension @<:@default=no@:>@],
 180   if test "$enableval" = "yes"; then
 181         AC_MSG_RESULT([yes])
 182
 183         AC_CHECK_LIB([Xinerama], [XineramaQueryExtension],
 184           [
 185             AC_MSG_CHECKING([for X11/extensions/Xinerama.h])
 186             AC_TRY_LINK(
 187               [
 188                 #include <X11/Xlib.h>
 189                 #include <X11/extensions/Xinerama.h>
 190               ],
 191               [
 192                 XineramaScreenInfo foo
 193               ],
 194               [
 195                 AC_MSG_RESULT([yes])
 196                 XINERAMA="yes"
 197                 AC_DEFINE([XINERAMA], [1],
 198                           [Enable support of the Xinerama extension])
 199                 LIBS="$LIBS -lXinerama"
 200               ],
 201               [
 202                 AC_MSG_RESULT([no])
 203               ]
 204             )
 205           ]
 206         )
 207
 208     AC_MSG_CHECKING([for the Xinerama extension])
 209     if test "$XINRERAMA" = "yes"; then
 210       AC_MSG_RESULT([yes])
 211     else
 212       AC_MSG_RESULT([no])
 213     fi
 214   else
 215         AC_MSG_RESULT([no])
 216   fi,
 217   AC_MSG_RESULT([no])
 218 )
 219
 220
 221
 222 AC_CONFIG_FILES([Makefile
 223                 m4/Makefile
 224                 po/Makefile.in
 225                 intl/Makefile
 226                 otk/Makefile
 227                 src/Makefile
 228                 util/Makefile
 229                 util/epist/Makefile
 230                 doc/Makefile
 231                 doc/doxygen/Makefile
 232                 data/Makefile
 233                 data/styles/Makefile
 234                 version.h
 235                 ])
 236 AC_OUTPUT
 237
 238 AC_MSG_RESULT
 239 AC_MSG_RESULT([$PACKAGE version $VERSION configured successfully.])
 240
 241 AC_MSG_RESULT
 242 AC_MSG_RESULT([Using '$prefix' for installation.])
 243 AC_MSG_RESULT([Using '$CXX' for C++ compiler.])
 244 AC_MSG_RESULT([Building with '$CPPFLAGS' for C++ compiler flags.])
 245 AC_MSG_RESULT([Building with '$LIBS' for linker flags.])
 246 AC_MSG_RESULT
 247 AC_MSG_RESULT([configure complete, now type \"make\"])
 248 AC_MSG_RESULT