X-Git-Url: https://git.dogcows.com/gitweb?p=chaz%2Fyoink;a=blobdiff_plain;f=extra%2Fyoink.ebuild;fp=extra%2Fyoink.ebuild;h=69fa2f04a9fe3eea29a6982f3c1e6cf2b656e066;hp=0000000000000000000000000000000000000000;hb=7d15b919681bb9ec0088b4b27c6abf62d6dfb9b1;hpb=0fffd0097d7b496454413e57b398c903ecc252e4

diff --git a/extra/yoink.ebuild b/extra/yoink.ebuild
new file mode 100644
index 0000000..69fa2f0
--- /dev/null
+++ b/extra/yoink.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=2
+inherit autotools eutils games
+
+DESCRIPTION="Alien-smashing action game"
+HOMEPAGE="http://www.dogcows.com/"
+SRC_URI="http://www.dogcows.com/yoink/${P}.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug"
+
+RDEPEND="media-libs/libsdl[joystick,video]
+	media-libs/sdl-image[png]"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+src_prepare() {
+	sed -i \
+		-e "s/-Werror//g" \
+		configure.ac \
+		|| die "sed failed"
+	sed -i \
+		-e "/apps/d" \
+		-e "/pixmap/d" \
+		data/Makefile.am \
+		|| die "sed failed"
+	sed -i \
+		-e "/man/d" \
+		doc/Makefile.am \
+		|| die "sed failed"
+	eautoreconf
+}
+
+src_configure() {
+	egamesconf \
+		--disable-dependency-tracking \
+		--datadir="${GAMES_DATADIR}/${PN}" \
+		$(use_enable debug)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS ChangeLog README TODO
+	doman doc/yoink.6
+	doicon data/yoink.png
+	make_desktop_entry ${PN} Yoink
+	prepgamesdirs
+}