# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit autotools eutils games

DESCRIPTION="Alien-smashing action game"
HOMEPAGE="http://www.dogcows.com/yoink/"
SRC_URI="http://www.dogcows.com/yoink/${P}.tar.bz2
	http://eng.utah.edu/~mcgarvey/yoink/${P}.tar.bz2"

LICENSE="BSD-2 BSD LGPL-2.1 ZLIB"
SLOT="0"
KEYWORDS="amd64 ~ppc x86"
IUSE="debug double-precision gtk qt4 threads"

RDEPEND="dev-lang/lua
	media-libs/libpng
	media-libs/libsdl[opengl]
	media-libs/libvorbis
	media-libs/openal
	virtual/glu
	virtual/opengl"
DEPEND="${RDEPEND}
	dev-libs/boost
	dev-util/pkgconfig"

src_prepare() {
	sed -i \
		-e "/apps/d" \
		-e "/pixmap/d" \
		data/Makefile.am \
		|| die "sed failed"
	sed -i \
		-e "/man/d" \
		doc/Makefile.am \
		|| die "sed failed"

	eautoreconf
}

src_configure() {
	egamesconf \
		--disable-dependency-tracking \
		$(use_enable debug) \
		$(use_enable double-precision) \
		$(use_enable gtk) \
		$(use_enable qt4) \
		$(use_enable threads)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS COPYING README TODO
	doman doc/yoink.6
	doicon data/yoink.png
	make_desktop_entry ${PN} Yoink
	prepgamesdirs
}