# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit autotools eutils games

DESCRIPTION="Alien-smashing action game"
HOMEPAGE="http://www.dogcows.com/"
SRC_URI="http://www.dogcows.com/yoink/${P}.tar.bz2
	http://eng.utah.edu/~mcgarvey/yoink/${P}.tar.bz2"

LICENSE="BSD-2"
SLOT="0"
KEYWORDS="amd64 ~ppc x86"
IUSE="debug profile"

RDEPEND="media-libs/freealut
	media-libs/libsdl[opengl]
	media-libs/sdl-image[png]
	media-libs/sdl-sound[vorbis]
	media-libs/openal
	virtual/opengl"
DEPEND="${RDEPEND}
	dev-libs/boost
	dev-util/pkgconfig"

RESTRICT="mirror"

src_prepare() {
	sed -i \
		-e "s/-Werror//g" \
		configure.ac \
		|| die "sed failed"
	sed -i \
		-e "/apps/d" \
		-e "/pixmap/d" \
		data/Makefile.am \
		|| die "sed failed"
	sed -i \
		-e "/man/d" \
		doc/Makefile.am \
		|| die "sed failed"

	eautoreconf
}

src_configure() {
	egamesconf \
		--disable-dependency-tracking \
		--with-assetdir="${GAMES_DATADIR}/${PN}" \
		$(use_enable debug) \
		$(use_enable profile)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog README TODO
	doman doc/yoink.6
	doicon data/yoink.png
	make_desktop_entry ${PN} Yoink
	prepgamesdirs
}