# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=3
inherit eutils games

DESCRIPTION="Alien-smashing action game"
HOMEPAGE="http://www.dogcows.com/yoink"
SRC_URI="ftp://ftp.dogcows.com/yoink/${P}.tar.bz2"

LICENSE="BSD-2 BSD LGPL-2.1 ZLIB"
SLOT="0"
KEYWORDS="amd64 ~ppc x86"
IUSE="debug double-precision gtk hotload qt4 threads"

RDEPEND="dev-lang/lua
	media-libs/libpng
	media-libs/libsdl[opengl]
	media-libs/libvorbis
	media-libs/openal
	virtual/glu
	virtual/opengl
	gtk? ( x11-libs/gtk+:2 )
	qt4? ( !gtk? ( x11-libs/qt-core:4 ) )"
DEPEND="${RDEPEND}
	dev-libs/boost
	dev-util/pkgconfig"

src_configure() {
	egamesconf --disable-dependency-tracking \
		--install-icon=no --print-instructions=no \
		$(use_enable debug) \
		$(use_enable double-precision) \
		$(use_enable hotload) \
		$(use_enable pch) \
		$(use_enable threads) \
		$(use_with gtk) \
		$(use_with qt4)
}

src_install() {
	emake DESTDIR="${D}" install || die "Install failed"
	dodoc AUTHORS COPYING README TODO || die "Install docs failed"
	doicon data/yoink.png || die "Install icon failed"
	make_desktop_entry yoink Yoink || die "Install destop entry failed"
	prepgamesdirs
}