# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit eutils games

DESCRIPTION="Alien-smashing action game"
HOMEPAGE="http://www.dogcows.com/yoink/"
SRC_URI="http://www.dogcows.com/yoink/chrome/site/${P}.tar.bz2
	http://eng.utah.edu/~mcgarvey/yoink/${P}.tar.bz2"

LICENSE="BSD-2 BSD LGPL-2.1 ZLIB"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="debug double-precision gtk hotload qt4 threads"

RDEPEND="dev-lang/lua
	media-libs/libpng
	media-libs/libsdl[opengl]
	media-libs/libvorbis
	media-libs/openal
	virtual/glu
	virtual/opengl
	gtk? ( x11-libs/gtk+:2 )
	qt4? ( !gtk? ( x11-libs/qt-core:4 ) )"
DEPEND="${RDEPEND}
	dev-libs/boost
	dev-util/pkgconfig"

src_configure() {
	egamesconf \
		--disable-dependency-tracking \
		$(use_enable debug) \
		$(use_enable double-precision) \
		$(use_enable hotload) \
		$(use_enable threads) \
		$(use_with gtk) \
		$(use_with qt4)
}

src_install() {
	emake DESTDIR="${D}" install_man=no install || die "emake failed"
	dodoc AUTHORS COPYING README TODO
	doman doc/yoink.6
	doicon data/yoink.png
	make_desktop_entry ${PN} Yoink
	prepgamesdirs
}