Dogcows Code - chaz/yoink/blob - extra/yoink.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6 inherit autotools eutils games
   7
   8 DESCRIPTION="Alien-smashing action game"
   9 HOMEPAGE="http://www.dogcows.com/"
  10 SRC_URI="http://www.dogcows.com/yoink/${P}.tar.bz2"
  11
  12 LICENSE="BSD-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~ppc ~x86"
  15 IUSE="debug profile"
  16
  17 RDEPEND="media-libs/libsdl[opengl]
  18         media-libs/sdl-image[png]
  19         virtual/opengl"
  20 DEPEND="${RDEPEND}
  21         dev-util/pkgconfig"
  22
  23 src_prepare() {
  24         sed -i \
  25                 -e "s/-Werror//g" \
  26                 configure.ac \
  27                 || die "sed failed"
  28         sed -i \
  29                 -e "/apps/d" \
  30                 -e "/pixmap/d" \
  31                 data/Makefile.am \
  32                 || die "sed failed"
  33         sed -i \
  34                 -e "/man/d" \
  35                 doc/Makefile.am \
  36                 || die "sed failed"
  37         eautoreconf
  38 }
  39
  40 src_configure() {
  41         egamesconf \
  42                 --disable-dependency-tracking \
  43                 --with-assetdir="${GAMES_DATADIR}/${PN}" \
  44                 $(use_enable debug) \
  45                 $(use_enable profile)
  46 }
  47
  48 src_install() {
  49         emake DESTDIR="${D}" install || die "emake install failed"
  50         dodoc AUTHORS ChangeLog README TODO
  51         doman doc/yoink.6
  52         doicon data/yoink.png
  53         make_desktop_entry ${PN} Yoink
  54         prepgamesdirs
  55 }