f4730c18b1a4fc6b73dd7cb43b8c3f5fbbf1e9da
[chaz/yoink] / extra / yoink.ebuild
1 # Copyright 1999-2009 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: $
4
5 EAPI=2
6
7 inherit autotools eutils games
8
9 DESCRIPTION="Alien-smashing action game"
10 HOMEPAGE="http://www.dogcows.com/"
11 SRC_URI="http://www.dogcows.com/yoink/${P}.tar.bz2
12 http://eng.utah.edu/~mcgarvey/yoink/${P}.tar.bz2"
13
14 LICENSE="BSD-2"
15 SLOT="0"
16 KEYWORDS="amd64 ~ppc x86"
17 IUSE="debug profile"
18
19 RDEPEND="media-libs/freealut
20 media-libs/libsdl[opengl]
21 media-libs/libvorbis
22 media-libs/openal
23 media-libs/sdl-image[png]
24 virtual/opengl"
25 DEPEND="${RDEPEND}
26 dev-libs/boost
27 dev-util/pkgconfig"
28
29 src_prepare() {
30 sed -i \
31 -e "s/-Werror//g" \
32 configure.ac \
33 || die "sed failed"
34 sed -i \
35 -e "/apps/d" \
36 -e "/pixmap/d" \
37 data/Makefile.am \
38 || die "sed failed"
39 sed -i \
40 -e "/man/d" \
41 doc/Makefile.am \
42 || die "sed failed"
43
44 eautoreconf
45 }
46
47 src_configure() {
48 egamesconf \
49 --disable-dependency-tracking \
50 --with-assetdir="${GAMES_DATADIR}/${PN}" \
51 $(use_enable debug) \
52 $(use_enable profile)
53 }
54
55 src_install() {
56 emake DESTDIR="${D}" install || die "emake install failed"
57 dodoc AUTHORS ChangeLog README TODO
58 doman doc/yoink.6
59 doicon data/yoink.png
60 make_desktop_entry ${PN} Yoink
61 prepgamesdirs
62 }
This page took 0.033996 seconds and 3 git commands to generate.