Dogcows Code - chaz/yoink/blob - extra/yoink.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6
   7 inherit autotools eutils games
   8
   9 DESCRIPTION="Alien-smashing action game"
  10 HOMEPAGE="http://www.dogcows.com/yoink/"
  11 SRC_URI="http://www.dogcows.com/yoink/${P}.tar.bz2
  12         http://eng.utah.edu/~mcgarvey/yoink/${P}.tar.bz2"
  13
  14 LICENSE="BSD-2 BSD LGPL-2.1 ZLIB"
  15 SLOT="0"
  16 KEYWORDS="amd64 ~ppc x86"
  17 IUSE="debug double-precision gtk qt4 threads"
  18
  19 RDEPEND="dev-lang/lua
  20         media-libs/libsdl[opengl]
  21         media-libs/libvorbis
  22         media-libs/openal
  23         media-libs/sdl-image[png]
  24         virtual/opengl"
  25 DEPEND="${RDEPEND}
  26         dev-libs/boost
  27         dev-util/pkgconfig"
  28
  29 src_prepare() {
  30         sed -i \
  31                 -e "/apps/d" \
  32                 -e "/pixmap/d" \
  33                 data/Makefile.am \
  34                 || die "sed failed"
  35         sed -i \
  36                 -e "/man/d" \
  37                 doc/Makefile.am \
  38                 || die "sed failed"
  39
  40         eautoreconf
  41 }
  42
  43 src_configure() {
  44         egamesconf \
  45                 --disable-dependency-tracking \
  46                 $(use_enable debug) \
  47                 $(use_enable double-precision) \
  48                 $(use_enable gtk) \
  49                 $(use_enable qt4) \
  50                 $(use_enable threads)
  51 }
  52
  53 src_install() {
  54         emake DESTDIR="${D}" install || die "emake install failed"
  55         dodoc AUTHORS ChangeLog COPYING README TODO
  56         doman doc/yoink.6
  57         doicon data/yoink.png
  58         make_desktop_entry ${PN} Yoink
  59         prepgamesdirs
  60 }