Dogcows Code - chaz/yoink/blob - extra/yoink.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6 inherit autotools eutils games
   7
   8 DESCRIPTION="Alien-smashing action game"
   9 HOMEPAGE="http://www.dogcows.com/"
  10 SRC_URI="http://www.dogcows.com/yoink/${P}.tar.bz2"
  11
  12 LICENSE="BSD-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~ppc ~x86"
  15 IUSE="debug"
  16
  17 RDEPEND="media-libs/libsdl[joystick,video]
  18         media-libs/sdl-image[png]"
  19 DEPEND="${RDEPEND}
  20         dev-util/pkgconfig"
  21
  22 src_prepare() {
  23         sed -i \
  24                 -e "s/-Werror//g" \
  25                 configure.ac \
  26                 || die "sed failed"
  27         sed -i \
  28                 -e "/apps/d" \
  29                 -e "/pixmap/d" \
  30                 data/Makefile.am \
  31                 || die "sed failed"
  32         sed -i \
  33                 -e "/man/d" \
  34                 doc/Makefile.am \
  35                 || die "sed failed"
  36         eautoreconf
  37 }
  38
  39 src_configure() {
  40         egamesconf \
  41                 --disable-dependency-tracking \
  42                 --with-assetdir="${GAMES_DATADIR}/${PN}" \
  43                 $(use_enable debug)
  44 }
  45
  46 src_install() {
  47         emake DESTDIR="${D}" install || die "emake install failed"
  48         dodoc AUTHORS ChangeLog README TODO
  49         doman doc/yoink.6
  50         doicon data/yoink.png
  51         make_desktop_entry ${PN} Yoink
  52         prepgamesdirs
  53 }