Dogcows Code - chaz/yoink/blob - extra/yoink.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6
   7 inherit autotools eutils games
   8
   9 DESCRIPTION="Alien-smashing action game"
  10 HOMEPAGE="http://www.dogcows.com/"
  11 SRC_URI="http://www.dogcows.com/yoink/${P}.tar.bz2
  12         http://eng.utah.edu/~mcgarvey/yoink/${P}.tar.bz2"
  13
  14 LICENSE="BSD-2"
  15 SLOT="0"
  16 KEYWORDS="amd64 ~ppc x86"
  17 IUSE="debug profile"
  18
  19 RDEPEND="media-libs/libsdl[opengl]
  20         media-libs/sdl-image[png]
  21         virtual/opengl
  22         media-libs/sdl-sound[mikmod,vorbis]
  23         media-libs/openal
  24         media-libs/freealut"
  25 DEPEND="${RDEPEND}
  26         dev-libs/boost
  27         dev-util/pkgconfig"
  28
  29 RESTRICT="mirror"
  30
  31 src_prepare() {
  32         sed -i \
  33                 -e "s/-Werror//g" \
  34                 configure.ac \
  35                 || die "sed failed"
  36         sed -i \
  37                 -e "/apps/d" \
  38                 -e "/pixmap/d" \
  39                 data/Makefile.am \
  40                 || die "sed failed"
  41         sed -i \
  42                 -e "/man/d" \
  43                 doc/Makefile.am \
  44                 || die "sed failed"
  45
  46         eautoreconf
  47 }
  48
  49 src_configure() {
  50         egamesconf \
  51                 --disable-dependency-tracking \
  52                 --with-assetdir="${GAMES_DATADIR}/${PN}" \
  53                 $(use_enable debug) \
  54                 $(use_enable profile)
  55 }
  56
  57 src_install() {
  58         emake DESTDIR="${D}" install || die "emake install failed"
  59         dodoc AUTHORS ChangeLog README TODO
  60         doman doc/yoink.6
  61         doicon data/yoink.png
  62         make_desktop_entry ${PN} Yoink
  63         prepgamesdirs
  64 }