Dogcows Code - chaz/tar/blob - configure.ac

   1 # Configure template for GNU tar.  -*- autoconf -*-
   2
   3 # Copyright 1991, 1994-2010, 2013-2015 Free Software Foundation, Inc.
   4
   5 # This file is part of GNU tar.
   6
   7 # GNU tar is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11
  12 # GNU tar is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_INIT([GNU tar], [1.28.90], [bug-tar@gnu.org])
  21 AC_CONFIG_SRCDIR([src/tar.c])
  22 AC_CONFIG_AUX_DIR([build-aux])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_PREREQ([2.63])
  25 AM_INIT_AUTOMAKE([1.11 gnits tar-ustar dist-bzip2 dist-xz std-options silent-rules])
  26
  27 # Enable silent rules by default:
  28 AM_SILENT_RULES([yes])
  29
  30 AC_PROG_CC_STDC
  31 AC_EXEEXT
  32 AC_PROG_RANLIB
  33 AC_PROG_YACC
  34 gl_EARLY
  35 AC_CHECK_TOOLS([AR], [ar])
  36
  37 AC_SYS_LARGEFILE
  38 AC_C_INLINE
  39
  40 AC_CHECK_HEADERS_ONCE(fcntl.h linux/fd.h memory.h net/errno.h \
  41   sgtty.h string.h \
  42   sys/param.h sys/device.h sys/gentape.h \
  43   sys/inet.h sys/io/trioctl.h \
  44   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  45   unistd.h locale.h)
  46
  47 AC_CHECK_HEADERS([sys/buf.h], [], [],
  48 [#if HAVE_SYS_PARAM_H
  49 #include <sys/param.h>
  50 #endif])
  51
  52 AC_HEADER_MAJOR
  53
  54 AC_MSG_CHECKING([for st_fstype string in struct stat])
  55 AC_CACHE_VAL(diff_cv_st_fstype_string,
  56   [AC_TRY_COMPILE([#include <sys/types.h>
  57 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  58    diff_cv_st_fstype_string=yes,
  59    diff_cv_st_fstype_string=no)])
  60 AC_MSG_RESULT($diff_cv_st_fstype_string)
  61 if test $diff_cv_st_fstype_string = yes; then
  62   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  63     [Define if struct stat has a char st_fstype[] member.])
  64 fi
  65
  66 # even if we use gnulib's acl.h with integrated m4 file later on (used because
  67 # of very useful file_has_acl() function) we need following checks that restrict
  68 # tar to use POSIX.1e ACLs only.
  69 AC_ARG_WITH([posix-acls],
  70     AS_HELP_STRING([--without-posix-acls],
  71                    [do not use POSIX.1e access control lists]),
  72     [],
  73     [with_posix_acls=yes])
  74 if test "x$with_posix_acls" != "xno"; then
  75   AC_CHECK_HEADERS(sys/acl.h,, [with_posix_acls=no])
  76   for tar_acl_func in acl_get_file acl_get_fd acl_set_file acl_set_fd \
  77                       acl_to_text acl_from_text acl_delete_def_file \
  78                       acl_free; do \
  79     test "x$with_posix_acls" = xno && break
  80     AC_SEARCH_LIBS([$tar_acl_func], [acl pacl], [], [with_posix_acls=no])
  81   done
  82   if test "x$with_posix_acls" != xno; then
  83     AC_DEFINE(HAVE_POSIX_ACLS,,[Define when we have working POSIX acls])
  84   fi
  85 else
  86   # disable acls in gnulib's checks
  87   export enable_acl=no
  88 fi
  89
  90 AC_TYPE_MODE_T
  91 AC_TYPE_PID_T
  92 AC_TYPE_OFF_T
  93 AC_TYPE_UID_T
  94 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  95                                    [Type of major device numbers.]))
  96 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  97                                    [Type of minor device numbers.]))
  98 AC_CHECK_TYPE(dev_t, unsigned)
  99 AC_CHECK_TYPE(ino_t, unsigned)
 100
 101 gt_TYPE_SSIZE_T
 102
 103 # gnulib modules
 104 gl_INIT
 105 # paxutils modules
 106 tar_PAXUTILS
 107
 108 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 109 # ------------------------------------------------
 110 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 111 # Otherwise, run RUN-IF-NOT-FOUND.
 112 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 113   [AC_PREPROC_IFELSE(
 114     [AC_LANG_PROGRAM(
 115       [[
 116 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 117 /* ok */
 118 #else
 119 # error "your version of gcc is older than $1.$2"
 120 #endif
 121       ]]),
 122     ], [$3], [$4])
 123   ]
 124 )
 125
 126 AC_ARG_ENABLE([gcc-warnings],
 127   [AS_HELP_STRING([--enable-gcc-warnings],
 128      [turn on many GCC warnings (for developers; best with GNU make)])],
 129   [case $enableval in
 130      yes|no) ;;
 131      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 132    esac
 133    gl_gcc_warnings=$enableval],
 134   [gl_gcc_warnings=no
 135    if test -d "$srcdir"/.git; then
 136      gl_GCC_VERSION_IFELSE([4], [6], [gl_gcc_warnings=yes])
 137    fi]
 138 )
 139
 140 if test "$gl_gcc_warnings" = yes; then
 141   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 142   AC_SUBST([WERROR_CFLAGS])
 143
 144   nw=
 145   # This, $nw, is the list of warnings we disable.
 146   nw="$nw -Wformat-nonliteral"      # warnings in Fedora 17 stdio.h
 147   nw="$nw -Wvla"                    # warnings in gettext.h
 148   nw="$nw -Wswitch-default"         # Too many warnings for now
 149   nw="$nw -Wunsafe-loop-optimizations" # It's OK to omit unsafe optimizations.
 150   nw="$nw -Winline"                 # It's OK to not inline.
 151   nw="$nw -Wstrict-overflow"        # It's OK to optimize strictly.
 152   nw="$nw -Wsuggest-attribute=pure" # Too many warnings for now.
 153
 154   gl_MANYWARN_ALL_GCC([ws])
 155   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 156   for w in $ws; do
 157     gl_WARN_ADD([$w])
 158   done
 159   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 160   gl_WARN_ADD([-Wno-type-limits])      # It's OK to optimize based on types.
 161   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 162   gl_WARN_ADD([-Wno-format-nonliteral])
 163
 164   gl_WARN_ADD([-fdiagnostics-show-option])
 165   gl_WARN_ADD([-funit-at-a-time])
 166
 167   AC_SUBST([WARN_CFLAGS])
 168
 169   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 170   AH_VERBATIM([FORTIFY_SOURCE],
 171   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 172       without upsetting glibc 2.15+. */
 173    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 174    # define _FORTIFY_SOURCE 2
 175    #endif
 176   ])
 177   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 178
 179   # Use a slightly smaller set of warning options for lib/.
 180   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 181   nw=
 182   nw="$nw -Wmissing-prototypes"
 183   nw="$nw -Wunused-macros"
 184   #
 185   # These are for argp.
 186   nw="$nw -Wmissing-field-initializers"
 187   nw="$nw -Wshadow"
 188   #
 189   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 190
 191   # This is also for argp.
 192   gl_WARN_ADD([-Wno-missing-field-initializers], [GNULIB_WARN_CFLAGS])
 193
 194   AC_SUBST([GNULIB_WARN_CFLAGS])
 195
 196   # For gnulib-tests, the set is slightly smaller still.
 197   nw=
 198   # It's not worth being this picky about test programs.
 199   nw="$nw -Wsuggest-attribute=const"
 200   gl_MANYWARN_COMPLEMENT([GNULIB_TEST_WARN_CFLAGS],
 201                          [$GNULIB_WARN_CFLAGS], [$nw])
 202   AC_SUBST([GNULIB_TEST_WARN_CFLAGS])
 203 fi
 204
 205 TAR_HEADERS_ATTR_XATTR_H
 206
 207 AC_CHECK_FUNCS_ONCE([fchmod fchown fsync lstat mkfifo readlink symlink grantpt])
 208 AM_CONDITIONAL([TAR_COND_GRANTPT], [test $ac_cv_func_grantpt = yes])
 209
 210 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 211 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 212 AC_CHECK_DECLS([time],,, [#include <time.h>])
 213
 214 AC_REPLACE_FUNCS(waitpid)
 215
 216 AC_ARG_VAR([RSH], [Configure absolute path to default remote shell binary])
 217 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 218   [if test -n "$RSH"; then
 219     tar_cv_path_RSH=$RSH
 220   else
 221     tar_cv_path_RSH=no
 222     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 223         /usr/bin/nsh /usr/bin/rcmd
 224     do
 225       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 226       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 227       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 228       if test -f $ac_file; then
 229         if (test -h $ac_file) 2>/dev/null; then
 230           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 231         else
 232           tar_cv_path_RSH=$ac_file
 233           break
 234         fi
 235       fi
 236     done
 237   fi])
 238 if test $tar_cv_path_RSH = no; then
 239   AC_CHECK_HEADERS(netdb.h)
 240 else
 241   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 242     [Define to the full path of your rsh, if any.])
 243 fi
 244
 245 TAR_COMPR_PROGRAM(compress)
 246 TAR_COMPR_PROGRAM(gzip)
 247 TAR_COMPR_PROGRAM(bzip2)
 248 TAR_COMPR_PROGRAM(lzip)
 249 TAR_COMPR_PROGRAM(lzma)
 250 TAR_COMPR_PROGRAM(lzop)
 251 TAR_COMPR_PROGRAM(xz)
 252
 253 AC_MSG_CHECKING(for default archive format)
 254
 255 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 256            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 257
 258 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 259   DEFAULT_ARCHIVE_FORMAT="GNU"
 260 fi
 261 case $DEFAULT_ARCHIVE_FORMAT in
 262   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 263   *) AC_MSG_ERROR(Invalid format name);;
 264 esac
 265 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 266   [By default produce archives of this format])
 267 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 268
 269 AC_MSG_CHECKING(for default archive)
 270
 271 AC_ARG_VAR([DEFAULT_ARCHIVE],
 272            [Set the name of the default archive (default: -)])
 273 if test -z "$DEFAULT_ARCHIVE"; then
 274   DEFAULT_ARCHIVE=-
 275 else
 276   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 277     AC_MSG_WARN(DEFAULT_ARCHIVE '$DEFAULT_ARCHIVE' not found on this system)
 278   fi
 279   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 280   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 281   # FIXME: Rearrange, here.
 282   case $DEFAULT_ARCHIVE in
 283     *[[0-7][lmh]])
 284       AC_DEFINE(DENSITY_LETTER, 1,
 285         [Define to 1 if density may be indicated by [lmh] at end of device.])
 286       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 287       ;;
 288     *[[0-7]])
 289       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 290       ;;
 291     *)
 292       device_prefix=
 293       ;;
 294   esac
 295   case "$device_prefix" in
 296     ?*)
 297       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 298         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 299       ;;
 300   esac
 301 fi
 302 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 303   [Define to a string giving the full name of the default archive file.])
 304 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 305
 306 AC_ARG_VAR([DEFAULT_BLOCKING],
 307            [Define default blocking factor (default: 20)])
 308 AC_MSG_CHECKING(for default blocking)
 309 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 310 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 311   [Define to a number giving the default blocking size for archives.])
 312 AC_MSG_RESULT($DEFAULT_BLOCKING)
 313
 314 AC_MSG_CHECKING(for default quoting style)
 315
 316 m4_define([QUOTING_STYLES],dnl
 317           [literal|shell|shell-always|c|escape|locale|clocale])
 318 DEFAULT_QUOTING_STYLE="escape"
 319 AC_ARG_VAR([DEFAULT_QUOTING_STYLE],
 320            [Set the default quoting style. Allowed values are: ] m4_bpatsubst(QUOTING_STYLES,[|], [[, ]]) [. Default is "escape".])
 321
 322 case $DEFAULT_QUOTING_STYLE in
 323 QUOTING_STYLES) ;;
 324 *)  AC_MSG_ERROR(Invalid quoting style);;
 325 esac
 326 AC_MSG_RESULT($DEFAULT_QUOTING_STYLE)
 327 DEFAULT_QUOTING_STYLE=`echo ${DEFAULT_QUOTING_STYLE}|sed 's/-/_/g'`_quoting_style
 328 AC_DEFINE_UNQUOTED(DEFAULT_QUOTING_STYLE, $DEFAULT_QUOTING_STYLE,
 329   [Define to a default quoting style (see lib/quoteargs.c for the list)])
 330
 331 # Iconv
 332 AM_ICONV
 333 AC_CHECK_HEADERS(iconv.h)
 334 AC_CHECK_TYPE(iconv_t,:,
 335               AC_DEFINE(iconv_t, int,
 336                         [Conversion descriptor type]),
 337               [
 338 #ifdef HAVE_ICONV_H
 339 # include <iconv.h>
 340 #endif
 341 ])
 342
 343 # Gettext.
 344 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 345 AM_GNU_GETTEXT_VERSION([0.16])
 346
 347 # Initialize the test suite.
 348 AC_CONFIG_TESTDIR(tests)
 349 AC_CONFIG_FILES([tests/Makefile tests/atlocal]) # FIXME: tests/preset?
 350 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 351
 352 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 353 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 354 AC_ARG_ENABLE(backup-scripts,
 355               AC_HELP_STRING([--enable-backup-scripts],
 356                              [Create and install backup and restore scripts]),
 357               [case $enableval in
 358                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 359                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 360                     ;;
 361                esac])
 362
 363 AC_SUBST(BACKUP_SED_COND)
 364 if date +%Y-%m-%d 2>/dev/null >&2; then
 365         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 366 else
 367         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 368 fi
 369
 370 AC_OUTPUT([Makefile\
 371            doc/Makefile\
 372            gnu/Makefile\
 373            lib/Makefile\
 374            po/Makefile.in\
 375            scripts/Makefile\
 376            rmt/Makefile\
 377            src/Makefile])