Dogcows Code - chaz/p5-DBIx-Class-ResultSet-RecursiveUpdate/blob - lib/DBIx/Class/ResultSet/RecursiveUpdate.pm

   1 package DBIx::Class::ResultSet::RecursiveUpdate;
   2
   3 use version; $VERSION = qv('0.001');
   4
   5 use warnings;
   6 use strict;
   7 use Carp;
   8 use Scalar::Util qw( blessed );
   9
  10 use base qw(DBIx::Class::ResultSet);
  11
  12 sub recursive_update {
  13     my ( $self, $updates, $fixed_fields ) = @_;
  14
  15     # warn 'entering: ' . $self->result_source->from();
  16     if ( blessed($updates) && $updates->isa('DBIx::Class::Row') ) {
  17         return $updates;
  18     }
  19
  20     carp 'fixed fields needs to be a hash ref' if $fixed_fields && ref($fixed_fields) ne 'HASH';
  21
  22     # direct column accessors
  23     my %columns;
  24
  25     # relations that that should be done before the row is inserted into the database
  26     # like belongs_to
  27     my %pre_updates;
  28
  29     # relations that that should be done after the row is inserted into the database
  30     # like has_many and might_have
  31     my %post_updates;
  32     my %columns_by_accessor = $self->_get_columns_by_accessor;
  33
  34     #    warn 'columns_by_accessor: ' . Dumper( \%columns_by_accessor ); use Data::Dumper;
  35     for my $name ( keys %$updates ) {
  36         my $source = $self->result_source;
  37         if ( $columns_by_accessor{$name}
  38             && !( $source->has_relationship($name) && ref( $updates->{$name} ) )
  39           )
  40         {
  41             $columns{$name} = $updates->{$name};
  42             next;
  43         }
  44         next if !$source->has_relationship($name);
  45         my $info = $source->relationship_info($name);
  46         if (
  47             _master_relation_cond(
  48                 $source, $info->{cond}, $self->_get_pk_for_related($name)
  49             )
  50           )
  51         {
  52             $pre_updates{$name} = $updates->{$name};
  53         }
  54         else {
  55             $post_updates{$name} = $updates->{$name};
  56         }
  57     }
  58
  59     # warn 'columns: ' . Dumper( \%columns ); use Data::Dumper;
  60
  61     my $object;
  62     my @missing =
  63       grep { !exists $columns{$_} && !exists $fixed_fields->{$_} } $self->result_source->primary_columns;
  64     if ( !scalar @missing ) {
  65         $object = $self->find( \%columns, { key => 'primary' } );
  66     }
  67     $object ||= $self->new( {} );
  68
  69 # first update columns and other accessors - so that later related records can be found
  70     for my $name ( keys %columns ) {
  71         $object->$name( $updates->{$name} );
  72     }
  73     for my $name ( keys %pre_updates ) {
  74         my $info = $object->result_source->relationship_info($name);
  75         $self->_update_relation( $name, $updates, $object, $info );
  76     }
  77     $self->_delete_empty_auto_increment($object);
  78
  79 # don't allow insert to recurse to related objects - we do the recursion ourselves
  80 #    $object->{_rel_in_storage} = 1;
  81     $object->update_or_insert;
  82
  83     # updating many_to_many
  84     for my $name ( keys %$updates ) {
  85         next if exists $columns{$name};
  86         my $value = $updates->{$name};
  87
  88         # many to many case
  89         if ( $self->is_m2m($name) ) {
  90             my ($pk) = $self->_get_pk_for_related($name);
  91             my @rows;
  92             my $result_source = $object->$name->result_source;
  93             for my $elem ( @{ $updates->{$name} } ) {
  94                 if ( ref $elem ) {
  95                     push @rows, $result_source->resultset->find($elem);
  96                 }
  97                 else {
  98                     push @rows,
  99                       $result_source->resultset->find( { $pk => $elem } );
 100                 }
 101             }
 102             my $set_meth = 'set_' . $name;
 103             $object->$set_meth( \@rows );
 104         }
 105     }
 106     for my $name ( keys %post_updates ) {
 107         my $info = $object->result_source->relationship_info($name);
 108         $self->_update_relation( $name, $updates, $object, $info );
 109     }
 110     return $object;
 111 }
 112
 113 sub _get_columns_by_accessor {
 114     my $self   = shift;
 115     my $source = $self->result_source;
 116     my %columns;
 117     for my $name ( $source->columns ) {
 118         my $info = $source->column_info($name);
 119         $info->{name} = $name;
 120         $columns{ $info->{accessor} || $name } = $info;
 121     }
 122     return %columns;
 123 }
 124
 125 sub _update_relation {
 126     my ( $self, $name, $updates, $object, $info ) = @_;
 127
 128     my $related_result =
 129       $self->related_resultset($name)->result_source->resultset;
 130     my $resolved =
 131       $self->result_source->resolve_condition( $info->{cond}, $name, $object );
 132
 133  #                    warn 'resolved: ' . Dumper( $resolved ); use Data::Dumper;
 134     $resolved = undef
 135       if $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION == $resolved;
 136     if ( ref $updates->{$name} eq 'ARRAY' ) {
 137         for my $sub_updates ( @{ $updates->{$name} } ) {
 138             $sub_updates = { %$sub_updates, %$resolved } if $resolved;
 139             my $sub_object =
 140               $related_result->recursive_update( $sub_updates, $resolved );
 141         }
 142     }
 143     else {
 144         my $sub_updates = $updates->{$name};
 145         $sub_updates = { %$sub_updates, %$resolved } if $resolved;
 146         my $sub_object =
 147           $related_result->recursive_update( $sub_updates, $resolved );
 148         $object->set_from_related( $name, $sub_object );
 149     }
 150 }
 151
 152 sub is_m2m {
 153     my ( $self, $relation ) = @_;
 154     my $rclass = $self->result_class;
 155
 156     # DBIx::Class::IntrospectableM2M
 157     if ( $rclass->can('_m2m_metadata') ) {
 158         return $rclass->_m2m_metadata->{$relation};
 159     }
 160     my $object = $self->new( {} );
 161     if (    $object->can($relation)
 162         and !$self->result_source->has_relationship($relation)
 163         and $object->can( 'set_' . $relation ) )
 164     {
 165         return 1;
 166     }
 167     return;
 168 }
 169
 170 sub get_m2m_source {
 171     my ( $self, $relation ) = @_;
 172     my $rclass = $self->result_class;
 173
 174     # DBIx::Class::IntrospectableM2M
 175     if ( $rclass->can('_m2m_metadata') ) {
 176         return $self->result_source->related_source(
 177             $rclass->_m2m_metadata->{$relation}{relation} )
 178           ->related_source(
 179             $rclass->_m2m_metadata->{$relation}{foreign_relation} );
 180     }
 181     my $object = $self->new( {} );
 182     my $r = $object->$relation;
 183     return $r->result_source;
 184 }
 185
 186 sub _delete_empty_auto_increment {
 187     my ( $self, $object ) = @_;
 188     for my $col ( keys %{ $object->{_column_data} } ) {
 189         if (
 190             $object->result_source->column_info($col)->{is_auto_increment}
 191             and ( !defined $object->{_column_data}{$col}
 192                 or $object->{_column_data}{$col} eq '' )
 193           )
 194         {
 195             delete $object->{_column_data}{$col};
 196         }
 197     }
 198 }
 199
 200 sub _get_pk_for_related {
 201     my ( $self, $relation ) = @_;
 202     my $result_source;
 203     if ( $self->result_source->has_relationship($relation) ) {
 204         $result_source = $self->result_source->related_source($relation);
 205     }
 206
 207     # many to many case
 208     if ( $self->is_m2m($relation) ) {
 209         $result_source = $self->get_m2m_source($relation);
 210     }
 211     return $result_source->primary_columns;
 212 }
 213
 214 sub _master_relation_cond {
 215     my ( $source, $cond, @foreign_ids ) = @_;
 216     my $foreign_ids_re = join '|', @foreign_ids;
 217     if ( ref $cond eq 'HASH' ) {
 218         for my $f_key ( keys %{$cond} ) {
 219
 220             # might_have is not master
 221             my $col = $cond->{$f_key};
 222             $col =~ s/self\.//;
 223             if ( $source->column_info($col)->{is_auto_increment} ) {
 224                 return 0;
 225             }
 226             if ( $f_key =~ /^foreign\.$foreign_ids_re/ ) {
 227                 return 1;
 228             }
 229         }
 230     }
 231     elsif ( ref $cond eq 'ARRAY' ) {
 232         for my $new_cond (@$cond) {
 233             return 1
 234               if _master_relation_cond( $source, $new_cond, @foreign_ids );
 235         }
 236     }
 237     return;
 238 }
 239
 240 1;    # Magic true value required at end of module
 241 __END__
 242
 243 =head1 NAME
 244
 245 DBIx::Class::ResultSet::RecursiveUpdate - like update_or_create - but recursive
 246
 247
 248 =head1 VERSION
 249
 250 This document describes DBIx::Class::ResultSet::RecursiveUpdate version 0.001
 251
 252
 253 =head1 SYNOPSIS
 254
 255     __PACKAGE__->load_namespaces( default_resultset_class => '+DBIx::Class::ResultSet::RecursiveUpdate' );
 256
 257 in the Schema file (see t/lib/DBSchema.pm).  Or appriopriate 'use base' in the ResultSet classes.
 258
 259 Then:
 260
 261     my $user = $user_rs->recursive_update( {
 262         id => 1,
 263         owned_dvds => [
 264         {
 265           title => 'One Flew Over the Cuckoo's Nest'
 266         }
 267         ]
 268       }
 269     );
 270
 271
 272 =head1 DESCRIPTION
 273
 274 You can feed the ->create method with a recursive datastructure and have the related records
 275 created.  Unfortunately you cannot do a similar thing with update_or_create - this module
 276 tries to fill that void.
 277
 278 It is a base class for ResultSets providing just one method: recursive_update
 279 which works just like update_or_create but can recursively update or create
 280 data objects composed of multiple rows. All rows need to be identified by primary keys
 281 - so you need to provide them in the update structure (unless they can be deduced from
 282 the parent row - for example when you have a belongs_to relationship).
 283 If not all colums comprising the primary key are specified - then a new row will be created,
 284 with the expectation that the missing columns will be filled by it (as in the case of auto_increment
 285 primary keys).
 286
 287
 288 If the resultset itself stores an assignement for the primary key,
 289 like in the case of:
 290
 291     my $restricted_rs = $user_rs->search( { id => 1 } );
 292
 293 then you need to specify that additional predicate as a second argument to the recursive_update
 294 method:
 295
 296     my $user = $restricted_rs->recursive_update( {
 297         owned_dvds => [
 298         {
 299           title => 'One Flew Over the Cuckoo's Nest'
 300         }
 301         ]
 302       },
 303       { id => 1 }
 304     );
 305
 306
 307 For a many_to_many (pseudo) relation you can supply a list of primary keys
 308 from the other table - and it will link the record at hand to those and
 309 only those records identified by them.  This is convenient for handling web
 310 forms with check boxes (or a SELECT box with multiple choice) that let you
 311 update such (pseudo) relations.
 312
 313 For a description how to set up base classes for ResultSets see load_namespaces
 314 in DBIx::Class::Schema.
 315
 316 =head1 DESIGN CHOICES
 317
 318 =head2 Treatment of many to many pseudo relations
 319
 320 The function gets the information about m2m relations from DBIx::Class::IntrospectableM2M.
 321 If it is not loaded in the ResultSource classes - then the code relies on the fact that:
 322     if($object->can($name) and
 323              !$object->result_source->has_relationship($name) and
 324              $object->can( 'set_' . $name )
 325          )
 326
 327 then $name must be a many to many pseudo relation.  And that in a
 328 similarly ugly was I find out what is the ResultSource of objects from
 329 that many to many pseudo relation.
 330
 331
 332 =head1 INTERFACE
 333
 334 =head1 METHODS
 335
 336 =head2 recursive_update
 337
 338 The method that does the work here.
 339
 340 =head2 is_m2m
 341
 342 $self->is_m2m( 'name ' ) - answers the question if 'name' is a many to many
 343 (pseudo) relation on $self.
 344
 345 =head2 get_m2m_source
 346
 347 $self->get_m2m_source( 'name' ) - returns the ResultSource linked to by the many
 348 to many (pseudo) relation 'name' from $self.
 349
 350
 351 =head1 DIAGNOSTICS
 352
 353
 354 =head1 CONFIGURATION AND ENVIRONMENT
 355
 356 DBIx::Class::RecursiveUpdate requires no configuration files or environment variables.
 357
 358 =head1 DEPENDENCIES
 359
 360     DBIx::Class
 361
 362 =head1 INCOMPATIBILITIES
 363
 364 =for author to fill in:
 365
 366 None reported.
 367
 368
 369 =head1 BUGS AND LIMITATIONS
 370
 371 =for author to fill in:
 372
 373 No bugs have been reported.
 374
 375 Please report any bugs or feature requests to
 376 C<bug-dbix-class-recursiveput@rt.cpan.org>, or through the web interface at
 377 L<http://rt.cpan.org>.
 378
 379
 380 =head1 AUTHOR
 381
 382 Zbigniew Lukasiak  C<< <zby@cpan.org> >>
 383 Influenced by code by Pedro Melo.
 384
 385 =head1 LICENCE AND COPYRIGHT
 386
 387 Copyright (c) 2008, Zbigniew Lukasiak C<< <zby@cpan.org> >>. All rights reserved.
 388
 389 This module is free software; you can redistribute it and/or
 390 modify it under the same terms as Perl itself. See L<perlartistic>.
 391
 392
 393 =head1 DISCLAIMER OF WARRANTY
 394
 395 BECAUSE THIS SOFTWARE IS LICENSED FREE OF CHARGE, THERE IS NO WARRANTY
 396 FOR THE SOFTWARE, TO THE EXTENT PERMITTED BY APPLICABLE LAW. EXCEPT WHEN
 397 OTHERWISE STATED IN WRITING THE COPYRIGHT HOLDERS AND/OR OTHER PARTIES
 398 PROVIDE THE SOFTWARE "AS IS" WITHOUT WARRANTY OF ANY KIND, EITHER
 399 EXPRESSED OR IMPLIED, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
 400 WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE. THE
 401 ENTIRE RISK AS TO THE QUALITY AND PERFORMANCE OF THE SOFTWARE IS WITH
 402 YOU. SHOULD THE SOFTWARE PROVE DEFECTIVE, YOU ASSUME THE COST OF ALL
 403 NECESSARY SERVICING, REPAIR, OR CORRECTION.
 404
 405 IN NO EVENT UNLESS REQUIRED BY APPLICABLE LAW OR AGREED TO IN WRITING
 406 WILL ANY COPYRIGHT HOLDER, OR ANY OTHER PARTY WHO MAY MODIFY AND/OR
 407 REDISTRIBUTE THE SOFTWARE AS PERMITTED BY THE ABOVE LICENCE, BE
 408 LIABLE TO YOU FOR DAMAGES, INCLUDING ANY GENERAL, SPECIAL, INCIDENTAL,
 409 OR CONSEQUENTIAL DAMAGES ARISING OUT OF THE USE OR INABILITY TO USE
 410 THE SOFTWARE (INCLUDING BUT NOT LIMITED TO LOSS OF DATA OR DATA BEING
 411 RENDERED INACCURATE OR LOSSES SUSTAINED BY YOU OR THIRD PARTIES OR A
 412 FAILURE OF THE SOFTWARE TO OPERATE WITH ANY OTHER SOFTWARE), EVEN IF
 413 SUCH HOLDER OR OTHER PARTY HAS BEEN ADVISED OF THE POSSIBILITY OF
 414 SUCH DAMAGES.